WOLFRAM

Wolfram Language & System Documentation Center

ImageResize[image,width]

gives a resized version of image that is width pixels wide.

ImageResize[image,{size}]

gives a resized version of image with a maximum pixel width or height given by size.

ImageResize[image,{width,height}]

gives a resized version of image that has exactly the specified pixel width and height.

ImageResize[video,…]

gives a video in which every frame is resized.

ImageResize[image,{width,depth,height}]

gives a resized version of a 3D image with the specified dimensions.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Data  
Parameters  
Options  
Padding  
Resampling  
Applications  
Properties & Relations  
Possible Issues  
Interactive Examples  
See Also
Tech Notes
Related Guides
History
Cite this Page

ImageResize

ImageResize[image,width]

gives a resized version of image that is width pixels wide.

ImageResize[image,{size}]

gives a resized version of image with a maximum pixel width or height given by size.

ImageResize[image,{width,height}]

gives a resized version of image that has exactly the specified pixel width and height.

ImageResize[video,…]

gives a video in which every frame is resized.

ImageResize[image,{width,depth,height}]

gives a resized version of a 3D image with the specified dimensions.

Details and Options

  • Image resizing changes the pixel dimensions of an image. This is needed when enlarging an image for viewing purposes or creating thumbnails when previewing a collection of images. It is also used to conform collections of images into a common size when batch processing, training, etc.
  • ImageResize[image,w] and ImageResize[image,{s}] preserve the original aspect ratio of image.
  • Specifications for width, height and depth can be any of the following:
  • dd pixels
    {d}maximum d pixels
    Scaled[s]a multiple s of the original size
    Allpreserve the original dimension
    Automaticdetermine value from aspect ratio
    Tiny,Small,Medium,Largepredefined absolute sizes
  • ImageResize[image,w] is equivalent to ImageResize[image,{w,Automatic}].
  • ImageResize[image,{size}] is equivalent to ImageResize[image,{{size},{size}}].
  • To obtain an image with an aspect ratio r, use ImageResize[image,w{1,r}].
  • The following options can be given:
  • Padding "Reversed"padding method
    Resampling Automaticresampling method

Examples

open all close all

Basic Examples  (1)

Resize an image to be 100 pixels wide:

Wolfram Language code: ImageResize[[image], 100]

Scope  (5)

Data  (3)

Resize a grayscale image:

Wolfram Language code: ImageResize[[image], 70]

Resize frames of a video:

Wolfram Language code: ImageResize[Video["ExampleData/fish.mp4"], 200]

Resize a 3D image:

Wolfram Language code: ImageResize[[image], 32]

Parameters  (2)

Specify the width of the resulting image:

Wolfram Language code: i = [image]; ImageResize[i, 100]

Resize by a factor of :

Wolfram Language code: ImageResize[i, Scaled[1 / 2]]

Use Automatic to explicitly preserve the aspect ratio of the image:

Wolfram Language code: ImageResize[i, {Automatic, 100}]

Resize an image to have the larger dimension no greater than 200 pixels:

Wolfram Language code: ImageResize[i, {200}]

Specify both width and height dimensions:

Wolfram Language code: ImageResize[i, {100, 50}]

Resize in one dimension only:

Wolfram Language code: ImageResize[i, {All, 50}]

Specify a named size:

Wolfram Language code: ImageResize[i, Tiny]

Resize a 3D image:

Wolfram Language code: i = [image];
Wolfram Language code: ImageDimensions[i]

Resize given the new width:

Wolfram Language code: ImageResize[i, 32]
Wolfram Language code: ImageDimensions[%]

Resize given the new height:

Wolfram Language code: ImageResize[i, {Automatic, Automatic, 32}]
Wolfram Language code: ImageDimensions[%]

Options  (4)

Padding  (3)

By default, "Reversed" padding is used:

Wolfram Language code: ImageResize[[image], Scaled[2]] == ImageResize[[image], Scaled[2], Padding -> "Reversed"]

Use constant padding:

Wolfram Language code: ImageResize[[image], Scaled[3], Padding -> 1]

When resampling method is set to "Nearest", all padding methods return the same result:

Wolfram Language code: SameQ[ImageResize[[image], Scaled[2], Resampling -> "Nearest", Padding -> #]& /@ {1, Black, "Fixed", "Periodic", "Reflected"}]

With constant padding, the padding value is converted to the color space of the target image:

Wolfram Language code: ImageResize[[image], {6, 6}, Resampling -> "Linear", Padding -> Red] === ImageResize[[image], {6, 6}, Resampling -> "Linear", Padding -> ColorConvert[Red, "Gray"]]

Resampling  (1)

By default, "Lanczos" resampling method is used when resizing an image:

Wolfram Language code: ImageResize[[image], Scaled[1 / 10]] == ImageResize[[image], Scaled[1 / 10], Resampling -> "Lanczos"]

Use method "Nearest":

Wolfram Language code: Image[ImageResize[[image], Scaled[1 / 10], Resampling -> "Nearest"], Magnification -> 10]

Applications  (3)

Create an image thumbnail:

Wolfram Language code: ImageResize[[image], Small]

Conform and classify a list of day and night images.

Here is an example set containing labeled images of day and night:

Wolfram Language code: examples = <|"Night" -> {[image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image]}, "Day" -> {[image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image]}|>;

Calculate the average dimension of the example images:

Wolfram Language code: dims = Round@Mean[ImageDimensions /@ Flatten[Values[examples]]]
Wolfram Language code: conformed = Map[Image[ImageResize[#, dims], ImageSize -> 40]&, examples, {2}]

Create the classifier:

Wolfram Language code: daynight = Classify[conformed]

Try this classifier on a few test images:

Wolfram Language code: daynight[{[image], [image], [image], [image], [image], [image]}]

Get a list of images from the web and then conform them:

Wolfram Language code: imgs = WebImageSearch["lion", "Images"]; Image[imgs, ImageSize -> 50]

Conform dimensions of the list of images:

Wolfram Language code: Image[ImageResize[#, {50, 50}]& /@ imgs, ImageSize -> 50]

Conform while imposing an aspect ratio that averages over the images:

Wolfram Language code: ars = N[#[[2]] / #[[1]]]& /@ (ImageDimensions /@ imgs); Image[ImageResize[#, 50{1, Mean[ars]}]& /@ imgs, ImageSize -> 50]

Properties & Relations  (4)

Resampling method "Nearest" is used when increasing the size of an image with only a few pixels:

Wolfram Language code: [image]//ImageDimensions
Wolfram Language code: ImageResize[[image], Scaled[3]]

Use "Linear" resampling:

Wolfram Language code: ImageResize[[image], Scaled[3], Resampling -> "Linear"]

Use ImageResize instead of Size argument in ImageTransformation:

Wolfram Language code: i = [image]; ImageTransformation[i, RotationTransform[10°], 100] == ImageResize[ImageTransformation[i, RotationTransform[10 °]], 100, Resampling -> "Linear"]

Thumbnail is equivalent to ImageResize using size specification Small and "Fixed" padding:

Wolfram Language code: i = [image]; Thumbnail[i] == ImageResize[i, Small, Padding -> "Fixed"]

Importing an image with given ImageSize is equivalent to resizing after Import:

Wolfram Language code: Import["ExampleData/rose.gif", ImageSize -> Medium] == ImageResize[Import["ExampleData/rose.gif"], Medium]

Possible Issues  (2)

Downsizing with no interpolation will give poor results for thin objects:

Wolfram Language code: i = [image]; ImageResize[i, 80, Resampling -> "Nearest"]

Use first-order interpolation:

Wolfram Language code: ImageResize[i, 80, Resampling -> "Linear"]

Reducing the size of an image with high-frequency content may result in a moire pattern:

Wolfram Language code: i = [image];
Wolfram Language code: ImageResize[i, Scaled[0.5], Resampling -> "Linear"]

Blur the image to reduce the moire effect:

Wolfram Language code: ImageResize[MeanFilter[i, 1], Scaled[0.5], Resampling -> "Linear"]

Interactive Examples  (1)

Create a pan and zoom application while fixing the displayed image size:

Wolfram Language code: image = ExampleData[{"TestImage", "Volubilis"}]; Manipulate[ImageResize[ImageTrim[image, pt, radius, Padding -> Gray], 300], {{pt, ImageDimensions[image] / 2}, {1, 1}, ImageDimensions[image]}, {{radius, 200}, 50, 400}]
Wolfram Research (2008), ImageResize, Wolfram Language function, https://reference.wolfram.com/language/ref/ImageResize.html (updated 2021).

Text

Wolfram Research (2008), ImageResize, Wolfram Language function, https://reference.wolfram.com/language/ref/ImageResize.html (updated 2021).

CMS

Wolfram Language. 2008. "ImageResize." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/ImageResize.html.

APA

Wolfram Language. (2008). ImageResize. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ImageResize.html

BibTeX

@misc{reference.wolfram_2026_imageresize, author="Wolfram Research", title="{ImageResize}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/ImageResize.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_imageresize, organization={Wolfram Research}, title={ImageResize}, year={2021}, url={https://reference.wolfram.com/language/ref/ImageResize.html}, note=[Accessed: 12-June-2026]}