WOLFRAM

Wolfram Language & System Documentation Center

Insphere[{p1,…,pn+1}]

gives the sphere that can be inscribed in the simplex defined by points pi in .

Insphere[poly]

gives the insphere of a polyhedron or polygon poly.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Graphics  
Specification  
Styling  
Regions  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

Insphere

Insphere[{p1,…,pn+1}]

gives the sphere that can be inscribed in the simplex defined by points pi in .

Insphere[poly]

gives the insphere of a polyhedron or polygon poly.

Details

  • Insphere is also known as incircle, inscribed circle, or inscribed disk.
  • Insphere gives the Sphere of largest measure (arc length, area, etc.) that can be inscribed in the simplex (triangle, tetrahedron, etc.) defined by points pi.
  • Insphere evaluates to a Sphere[c,r], where the center c is known as the incenter and radius r is known as the inradius for the related simplex.
  • Insphere is defined for and affinely independent.
  • For polyhedra, Insphere[poly] returns a sphere that is contained within the polyhedron poly and tangent to each of the polyhedron faces.
  • For polygons, Insphere[poly] returns a sphere that is contained within the polygon poly and tangent to each of the polygon edges.
  • Insphere can be used with symbolic points in GeometricScene.

Examples

open all close all

Basic Examples  (2)

An insphere in 2D:

Wolfram Language code: Graphics[Insphere[{{0, 0}, {1, 0}, {0, 1}}]]

And in 3D:

Wolfram Language code: Graphics3D[Insphere[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}]]

The insphere of the regular octahedron:

Wolfram Language code: ℛ = Insphere[Octahedron[]]
Wolfram Language code: Graphics3D[{Opacity[0.5], Octahedron[], Red, ℛ}]

Its surface area:

Wolfram Language code: Area[ℛ]

Scope  (17)

Graphics  (6)

Specification  (2)

Inspheres in different dimensions:

Wolfram Language code: Graphics[Insphere[{{0, 0}, {1, 0}, {0, 1}}]]
Wolfram Language code: Graphics3D[Insphere[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}]]

Insphere evaluates to a Sphere:

Wolfram Language code: Insphere[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}]

Get the center and radius:

Wolfram Language code: {First@%, Last@%}

Styling  (4)

Colored circumspheres:

Wolfram Language code: ℛ = Insphere[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Table[Graphics3D[{c, ℛ}], {c, {Red, Green, Blue, Yellow}}]

Different properties can be specified for the front and back of faces using FaceForm:

Wolfram Language code: ℛ = Insphere[{{-1, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Graphics3D[{FaceForm[Yellow, Blue], ℛ}, PlotRange -> {{-0.2, 0.2}, {0.05, 0.5}, {0.05, 0.5}}]

Inspheres with different specular exponents:

Wolfram Language code: ℛ = Insphere[{{-1, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Table[Graphics3D[{Orange, Specularity[White, n], ℛ}], {n, {5, 20, 100}}]

Black circumsphere that glows red:

Wolfram Language code: Graphics3D[{Glow[Red], Black, ℛ}]

Opacity specifies the face opacity:

Wolfram Language code: ℛ = Insphere[{{-1, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Table[Graphics3D[{Opacity[o], ℛ}], {o, {0.3, 0.5, 0.9}}]

Regions  (11)

Insphere works in any number of dimensions:

Wolfram Language code: Insphere[{{0, 0, 0, 0, 0}, {1, 0, 0, 0, 0}, {0, 1, 0, 0, 0}, {0, 0, 1, 0, 0}, {0, 0, 0, 1, 0}, {0, 0, 0, 0, 1}}]

Get the circumcenter and circumradius:

Wolfram Language code: {First[%], Last[%]}

Embedding dimension is the dimension of the space in which the sphere lives:

Wolfram Language code: ℛ = Insphere[{{0, 0}, {1, 0}, {1, 1}}];
Wolfram Language code: RegionEmbeddingDimension[ℛ]

Geometric dimension is the dimension of the shape itself:

Wolfram Language code: RegionDimension[ℛ]

Membership testing:

Wolfram Language code: ℛ = Insphere[(2 + Sqrt[3]){{1, 0, 0}, {0, 1, 0}, {0, 0, 1}, {-1, 0, 0}}];
Wolfram Language code: {RegionMember[ℛ, {1, 1, 1}], RegionMember[ℛ, {1, 2, 3}]}

Get conditions for membership:

Wolfram Language code: RegionMember[ℛ, {x, y, z}]

Area:

Wolfram Language code: ℛ = Insphere[{{1, 0, 0}, {0, 1, 0}, {0, 0, 1}, {-1, 0, 0}}];
Wolfram Language code: {Area[ℛ], RegionMeasure[ℛ]}

Centroid:

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics3D[{{Opacity[0.5], LightBlue, ℛ}, {PointSize[Large], Red, Point[c]}}]

Distance from a point:

Wolfram Language code: ℛ = Insphere[{{1 + Sqrt[2], -1}, {0, Sqrt[2]}, {-1 - Sqrt[2], -1}}];
Wolfram Language code: RegionDistance[ℛ, {1, 2}]

Plot it:

Wolfram Language code: {Plot3D[RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> Norm[{x, y}] == 1], ContourPlot[RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

Signed distance from a point:

Wolfram Language code: ℛ = Insphere[{{1 + Sqrt[2], -1}, {0, Sqrt[2]}, {-1 - Sqrt[2], -1}}];
Wolfram Language code: {SignedRegionDistance[ℛ, {2, 0}], SignedRegionDistance[ℛ, {1 / 4, 1 / 3}]}

Plot it:

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> Norm[{x, y}] == 1]

Nearest point in the region:

Wolfram Language code: ℛ = Insphere[Sqrt[3] (1 + Sqrt[3]){{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}]
Wolfram Language code: {RegionNearest[ℛ, {2, 2, 2}], RegionNearest[ℛ, {(1/2), (1/2), (1/2)}]}

Nearest points to an enclosing sphere:

Wolfram Language code: spherePoints[{n_, m_}, c_, r_] := Flatten[Table[c + r{Cos[k 2π / n]Sin[l π / m], Sin[k 2π / n]Sin[l π / m], Cos[l π / m]}, {k, 0., n - 1}, {l, 0., m - 1}], 1];
Wolfram Language code: pl = spherePoints[{8, 8}, RegionCentroid[ℛ], 3 / 2]; npl = Table[RegionNearest[ℛ, p], {p, pl}];
Wolfram Language code: Legended[Graphics3D[{ℛ, {Thin, Gray, Line[Transpose[{pl, npl}]]}, {Red, Point[pl]}, {PointSize[Medium], Blue, Point[npl]}}, Lighting -> "Neutral", Boxed -> False], PointLegend[{Red, Blue}, {"start", "nearest"}]]

A sphere is bounded:

Wolfram Language code: ℛ = Insphere[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: BoundedRegionQ[ℛ]

Find its range:

Wolfram Language code: r = RegionBounds[ℛ]
Wolfram Language code: Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[r]}, ℛ}, Boxed -> False]

Integrate over an Insphere:

Wolfram Language code: ℛ = Insphere[{{-1, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Integrate[1, {x, y, z}∈ℛ]
Wolfram Language code: Integrate[x^2y^2z^2, {x, y, z}∈ℛ]

Optimize over it:

Wolfram Language code: ℛ = Insphere[{{-1, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Maximize[{x^2 + y^2 + z^2, {x, y, z}∈ℛ}, {x, y, z}]

Solve equations over an Insphere:

Wolfram Language code: ℛ = Insphere[{{-1, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Reduce[x^2 == y^2 == z^2 && {x, y, z}∈ℛ, {x, y, z}]//FullSimplify

Applications  (3)

Recursively construct inscribed triangles and disks:

Wolfram Language code: intriangle[pts_] := Block[{center = First@Insphere[pts]}, RegionNearest[Line[#], center]& /@ Subsets[pts, {2}]]
Wolfram Language code: initial = {{0, 0}, {0, 2}, {2., 0}};
Wolfram Language code: tpts = NestList[intriangle, initial, 3];
Wolfram Language code: Table[{Gray, Triangle[p], LightOrange, Disk@@Insphere[p]}, {p, tpts}]//Graphics

Use Insphere to generate a circle packing for a triangulated region. First triangulate the region:

Wolfram Language code: ℛ = TriangulateMesh@DiscretizeGraphics[CountryData["UnitedStates", {"Polygon", "Mercator"}]]

Use Insphere to compute a circle for each triangle:

Wolfram Language code: circles = Insphere[First[#]]& /@ MeshPrimitives[ℛ, 2];
Wolfram Language code: Graphics[{Opacity[0.5], Map[{RandomColor[], #}&, circles]}]

Compute the packing density:

Wolfram Language code: packingArea = Total@Map[Area[Disk@@#]&, circles]
Wolfram Language code: regionArea = Area[ℛ]
Wolfram Language code: packingArea / regionArea

Use Insphere to generate a sphere packing for a triangulated region. First discretize and triangulate the region:

Wolfram Language code: ℛ = TriangulateMesh[[image], MeshQualityGoal -> "Minimal"]

Use Insphere to compute spheres for each tetrahedron:

Wolfram Language code: spheres = Insphere[First[#]]& /@ MeshPrimitives[ℛ, 3];
Wolfram Language code: Graphics3D[{Opacity[0.5], Map[{RandomColor[], #}&, spheres]}]

Compute the packing density:

Wolfram Language code: packingVolume = Total@Map[Volume[Ball@@#]&, spheres]
Wolfram Language code: regionVolume = Volume[ℛ]
Wolfram Language code: packingVolume / regionVolume

Properties & Relations  (2)

Insphere is the largest Sphere that can be inscribed in a Simplex:

Wolfram Language code: pts = {{0, 0}, {1, 0}, {0, 1}};
Wolfram Language code: Graphics[{Simplex[pts], Red, Insphere[pts]}]

In 3D:

Wolfram Language code: pts = {{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}};
Wolfram Language code: Graphics3D[{Opacity[0.5], Simplex[pts], Red, Insphere[pts]}]

Use Circumsphere to get a Sphere (blue) that circumscribes a Simplex:

Wolfram Language code: pts = {{0, 0}, {1, 0}, {0, 1}};
Wolfram Language code: Graphics[{Simplex[pts], Blue, Circumsphere[pts], Red, Insphere[pts]}]

In 3D:

Wolfram Language code: pts = {{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}};
Wolfram Language code: Graphics3D[{Opacity[0.2], Simplex[pts], Blue, Circumsphere[pts], Red, Insphere[pts]}, Boxed -> False]

Neat Examples  (1)

Random insphere collections:

Wolfram Language code: Graphics[Table[{Hue[RandomReal[]], Insphere[RandomReal[1, {3, 2}]]}, {80}]]
Wolfram Language code: Graphics3D[Table[{Hue[RandomReal[]], Insphere[RandomReal[1, {4, 3}]]}, {200}]]
Wolfram Research (2015), Insphere, Wolfram Language function, https://reference.wolfram.com/language/ref/Insphere.html (updated 2019).

Text

Wolfram Research (2015), Insphere, Wolfram Language function, https://reference.wolfram.com/language/ref/Insphere.html (updated 2019).

CMS

Wolfram Language. 2015. "Insphere." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/Insphere.html.

APA

Wolfram Language. (2015). Insphere. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Insphere.html

BibTeX

@misc{reference.wolfram_2026_insphere, author="Wolfram Research", title="{Insphere}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/Insphere.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_insphere, organization={Wolfram Research}, title={Insphere}, year={2019}, url={https://reference.wolfram.com/language/ref/Insphere.html}, note=[Accessed: 12-June-2026]}