InverseEllipticNomeQ
gives the parameter m corresponding to the nome q in an elliptic function.
Details
- Mathematical function, suitable for both symbolic and numerical manipulation.
- InverseEllipticNomeQ[q] yields the unique value of the parameter m which makes EllipticNomeQ[m] equal to q.
- The nome q must always satisfy
. - InverseEllipticNomeQ can be evaluated to arbitrary numerical precision.
- InverseEllipticNomeQ automatically threads over lists.
Examples
open all close allBasic Examples (4)
InverseEllipticNomeQ[0.1]Plot over a subset of the reals:
Plot[InverseEllipticNomeQ[x], {x, 0, 0.6}]Series expansion at the origin:
Series[InverseEllipticNomeQ[q], {q, 0, 8}]Asymptotic expansion at a singular point:
Series[InverseEllipticNomeQ[x], {x, -1, 2}]//Normal//FullSimplifyScope (26)
Numerical Evaluation (6)
InverseEllipticNomeQ[.2]N[InverseEllipticNomeQ[5 / 6]]N[InverseEllipticNomeQ[5 / 17], 50]The precision of the output tracks the precision of the input:
InverseEllipticNomeQ[0.222222222222222222222]N[InverseEllipticNomeQ[.6 - .5I]]Evaluate efficiently at high precision:
InverseEllipticNomeQ[3 / 7`100]//TimingInverseEllipticNomeQ[7 / 9`10000];//TimingCompute average-case statistical intervals using Around:
InverseEllipticNomeQ[ Around[E^-π, 0.01]]Compute the elementwise values of an array:
InverseEllipticNomeQ[{{E^-π, 0}, {0, E^-π}}]Or compute the matrix InverseEllipticNomeQ function using MatrixFunction:
MatrixFunction[InverseEllipticNomeQ, {{E^-π, 0}, {0, E^-π}}]//FullSimplifySpecific Values (4)
InverseEllipticNomeQ[E^-π]InverseEllipticNomeQ[x]//FunctionExpandInverseEllipticNomeQ[0]Find a value of 
for which InverseEllipticNomeQ[x]=0.9:
xval = x /. FindRoot[InverseEllipticNomeQ[x] == 0.9, {x, 0.1}]Plot[InverseEllipticNomeQ[x], {x, 0, 0.6}, Epilog -> Style[Point[{xval, InverseEllipticNomeQ[xval]}], PointSize[Large], Red]]Visualization (2)
Plot the InverseEllipticNomeQ function for various parameters:
Plot[InverseEllipticNomeQ[u], {u, -.1, .5}]![TemplateBox[{z}, InverseEllipticNomeQ]](Files/InverseEllipticNomeQ.en/3.png "TemplateBox[{z}, InverseEllipticNomeQ]"){kind=small}
ComplexContourPlot[Re[InverseEllipticNomeQ[z]], {z, -.7 - .7I, .7 + .7I}, Contours -> 20]![TemplateBox[{z}, InverseEllipticNomeQ]](Files/InverseEllipticNomeQ.en/4.png "TemplateBox[{z}, InverseEllipticNomeQ]"){kind=small}
ComplexContourPlot[Im[InverseEllipticNomeQ[z]], {z, -.7 - .7I, .7 + .7I}, Contours -> 20]Function Properties (10)
Real domain of InverseEllipticNomeQ:
FunctionDomain[InverseEllipticNomeQ[x], x]Complex domain of InverseEllipticNomeQ:
FunctionDomain[InverseEllipticNomeQ[z], z, Complexes]//FullSimplifyInverseEllipticNomeQ threads element-wise over lists:
InverseEllipticNomeQ[{0.2, 0.3, 0.4}]InverseEllipticNomeQ is an analytic function over its real domain:
FunctionAnalytic[{InverseEllipticNomeQ[x], -1 < x < 1}, x]In general, it has both singularities and discontinuities:
FunctionSingularities[InverseEllipticNomeQ[x], x]//QuietFunctionDiscontinuities[InverseEllipticNomeQ[x], x]//QuietInverseEllipticNomeQ is nondecreasing over its real domain:
FunctionMonotonicity[{InverseEllipticNomeQ[x], -1 < x < 1}, x]InverseEllipticNomeQ is injective:
FunctionInjective[InverseEllipticNomeQ[x], x]Plot[{InverseEllipticNomeQ[x], .4}, {x, -.1, .7}]InverseEllipticNomeQ is not surjective:
FunctionSurjective[InverseEllipticNomeQ[x], x]//QuietPlot[{InverseEllipticNomeQ[x], 2}, {x, -.1, .7}, PlotRange -> All]InverseEllipticNomeQ is neither non-negative nor non-positive:
FunctionSign[{InverseEllipticNomeQ[x], -1 < x < 1}, x]InverseEllipticNomeQ is concave over its real domain:
FunctionConvexity[{InverseEllipticNomeQ[x], -1 < x < 1}, x]TraditionalForm formatting:
InverseEllipticNomeQ[q]//TraditionalFormDifferentiation (2)
First derivative with respect to 
:
D[InverseEllipticNomeQ[q], q]Higher derivatives with respect to 
:
Table[D[InverseEllipticNomeQ[q], {q, k}], {k, 1, 3}]//FullSimplifyPlot the higher derivatives with respect to 
:
Plot[%, {q, .1, .8}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]Series Expansions (2)
Find the Taylor expansion using Series:
Series[InverseEllipticNomeQ[x], {x, 0, 5}]Plots of the first three approximations around 
:
terms = Normal@Table[Series[InverseEllipticNomeQ[x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{InverseEllipticNomeQ[x], terms}, {x, -1, 1}, PlotRange -> {{-.3, .3}, {-10, 10}}]Taylor expansion at a generic point:
Series[InverseEllipticNomeQ[x], {x, x0, 2}]//Normal// FullSimplifyGeneralizations & Extensions (1)
InverseEllipticNomeQ can be applied to power series:
InverseEllipticNomeQ[q + O[q] ^ 6]Applications (4)
Convert between elliptic modulus and nome in elliptic function identities:
(π/2) EllipticTheta[3, 0, q]^2 == EllipticK[InverseEllipticNomeQ[q]];% /. q -> RandomReal[{-3 / 4, 3 / 4}, {20}, WorkingPrecision -> 20]Partition function for a one‐atom monatomic gas in a finite container of unit length:
Subscript[Z, 1][β_] = Sqrt[(1/2 π) EllipticK[InverseEllipticNomeQ[Exp[-β π^2]]]] - (1/2);Form partition functions for n bosonic particles:
Subscript[Z, 0][β_] = 1;Subscript[Z, n_][β_] := Expand[(1/n)Subsuperscript[∑, j = 1, n]Subscript[Z, 1][j β]Subscript[Z, n - j][β]]Subscript[Z, 3][β]//TraditionalFormCalculate and plot mean energies:
Subscript[ℰ, n_][T_] := T^2D[Log[Subscript[Z, n][(1/T)]], T]Plot[Evaluate[Table[Subscript[ℰ, n][T], {n, 1, 4}]], {T, 1, 30}, WorkingPrecision -> 20]InverseEllipticNomeQ is a modular function. Make an ansatz for a modular equation:
(ansatz = With[{u = InverseEllipticNomeQ[z], v = InverseEllipticNomeQ[z^2]}, Sum[Subscript[c, i, j]u ^ i v ^ j, {i, 0, 2}, {j, 0, 2}] /. Subscript[c, 2, 2] -> 1] == 0)//TraditionalFormForm an overdetermined system of equations and solve it:
eqs = Table[N[ansatz /. z -> N[1 / k, 120], 50], {k, 3, 24}];sol = Solve[eqs, Flatten[Table[Subscript[c, i, j], {i, 0, 2}, {j, 0, 2}]]]//Chop//Rationalize
This is the modular equation of order 2:
ansatz /. First[sol]//TraditionalFormVerify using Series:
Series[%, {z, 0, 10}]Find the modulus corresponding to the elliptic curve, specified by Weierstrass invariants:
modulus[{g2_, g3_}] := Module[{e1, e2, e3},
e1 = WeierstrassE1[{g2, g3}];
e2 = WeierstrassE2[{g2, g3}];
e3 = WeierstrassE3[{g2, g3}];
(e2 - e3) / (e1 - e3)]m = modulus[{11., 7}]Compute the modulus alternatively using InverseEllipticNomeQ:
modulus2[{g2_, g3_}] := Module[{q, w1, w3},
w1 = WeierstrassHalfPeriodW1[{g2, g3}];
w3 = WeierstrassHalfPeriodW3[{g2, g3}];
q = Exp[I Pi w3 / w1];
InverseEllipticNomeQ[q]]modulus2[{11., 7}] == mProperties & Relations (5)
Compose with inverse functions:
{InverseEllipticNomeQ[EllipticNomeQ[z]], EllipticNomeQ[InverseEllipticNomeQ[z]]}PowerExpand[%]D[InverseEllipticNomeQ[q], q]Symbolically solve a transcendental equation:
Solve[EllipticNomeQ[z] + EllipticNomeQ[z]^2 == g, z]Numerically find a root of a transcendental equation:
FindRoot[InverseEllipticNomeQ[z] + InverseEllipticNomeQ[z ^ 2] + z == 2, {z, 0.4}]Series[InverseEllipticNomeQ[q] == (16 q QPochhammer[-q^2, q^2]^8/QPochhammer[-q, q^2]^8), {q, 0, 100}]Possible Issues (2)
InverseEllipticNomeQ remains unevaluated outside its domain of analyticity:
InverseEllipticNomeQ[2]N[%]InverseEllipticNomeQ is single valued, and EllipticNomeQ is multivalued:
InverseEllipticNomeQ[EllipticNomeQ[z]]Related Links
MathWorld
The Wolfram Functions SiteText
Wolfram Research (1996), InverseEllipticNomeQ, Wolfram Language function, https://reference.wolfram.com/language/ref/InverseEllipticNomeQ.html.
CMS
Wolfram Language. 1996. "InverseEllipticNomeQ." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/InverseEllipticNomeQ.html.
APA
Wolfram Language. (1996). InverseEllipticNomeQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/InverseEllipticNomeQ.html