WOLFRAM

Wolfram Language & System Documentation Center

InverseHankelTransform[expr,s,r]

gives the inverse Hankel transform of order 0 for expr.

InverseHankelTransform[expr,s,r,ν]

gives the inverse Hankel transform of order ν for expr.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Elementary Functions  
Special Functions  
Piecewise Functions and Distributions  
Options  
GenerateConditions  
Assumptions  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

InverseHankelTransform

InverseHankelTransform[expr,s,r]

gives the inverse Hankel transform of order 0 for expr.

InverseHankelTransform[expr,s,r,ν]

gives the inverse Hankel transform of order ν for expr.

Details and Options

Examples

open all close all

Basic Examples  (2)

Compute the inverse Hankel transform of a function:

Wolfram Language code: InverseHankelTransform[Exp[-s], s, r]

Inverse Hankel transform for a product of functions:

Wolfram Language code: InverseHankelTransform[Cos[s] / (1 + s ^ 2), s, r]

Scope  (16)

Basic Uses  (5)

Compute the inverse Hankel transform of order ν for a function:

Wolfram Language code: InverseHankelTransform[1 / s ^ 3, s, r, ν]

Use the default value 0 for the parameter ν:

Wolfram Language code: InverseHankelTransform[1 / s ^ 3, s, r]

Compute the inverse Hankel transform of a function for a symbolic parameter r:

Wolfram Language code: InverseHankelTransform[Sin[s] / s , s, r]

Use an exact value for r:

Wolfram Language code: InverseHankelTransform[Sin[s] / s , s, 1 / 3]

Use a numerical value for r:

Wolfram Language code: InverseHankelTransform[Sin[s] / s, s, 0.23]

Obtain the conditions for the convergence:

Wolfram Language code: InverseHankelTransform[Exp[-m s], s, r, GenerateConditions -> True]

Specify assumptions:

Wolfram Language code: InverseHankelTransform[Exp[-m s] / s, s, r, Assumptions -> m > 0 && r ≥ 0]

Display in TraditionalForm:

Wolfram Language code: InverseHankelTransform[f[r], r, s]//TraditionalForm
Wolfram Language code: InverseHankelTransform[f[r], r, s, 2]//TraditionalForm

Elementary Functions  (4)

Inverse Hankel transforms of rational functions:

Wolfram Language code: InverseHankelTransform[1 / s, s, r, ν]
Wolfram Language code: InverseHankelTransform[1 / (s ^ 2 + a ^ 2), s, r]

Exponential and logarithmic functions:

Wolfram Language code: InverseHankelTransform[E ^ (-s), s, r]
Wolfram Language code: InverseHankelTransform[E ^ (-s) / s, s, r]
Wolfram Language code: InverseHankelTransform[(1 - Exp[-m s]) / s ^ 2, s, r]
Wolfram Language code: InverseHankelTransform[Exp[-a s ^ 2] / s, s, r]
Wolfram Language code: InverseHankelTransform[Log[1 + a ^ 2 / s ^ 2], s, r]

Trigonometric functions:

Wolfram Language code: InverseHankelTransform[Sin[s] / (b ^ 2 + s ^ 2), s, r]
Wolfram Language code: InverseHankelTransform[Cos[s], s, r]

Algebraic functions:

Wolfram Language code: InverseHankelTransform[1 / Sqrt[1 + s ^ 2], s, r]
Wolfram Language code: InverseHankelTransform[1 / (1 + s ^ 2) ^ (3 / 2), s, r]
Wolfram Language code: InverseHankelTransform[1 / (1 + s ^ 2) ^ (n / 2), s, r]//FullSimplify

Special Functions  (5)

Inverse Hankel transforms of Bessel functions:

Wolfram Language code: InverseHankelTransform[(1 - BesselJ[0, a s]) / s ^ 2, s, r, 1]
Wolfram Language code: InverseHankelTransform[BesselK[0, s], s, r]

Airy functions:

Wolfram Language code: InverseHankelTransform[AiryAi[s], s, r]
Wolfram Language code: InverseHankelTransform[AiryBi[s], s, r]

Elliptic functions:

Wolfram Language code: InverseHankelTransform[EllipticK[s], s, r, 1]
Wolfram Language code: InverseHankelTransform[EllipticE[s], s, r]

Error functions:

Wolfram Language code: InverseHankelTransform[Erf[s], s, r]
Wolfram Language code: InverseHankelTransform[Erfc[s] / s , s, r]

Integral functions:

Wolfram Language code: InverseHankelTransform[ExpIntegralE[1, s] / s, s, r]
Wolfram Language code: InverseHankelTransform[SinIntegral[s ^ 2], s, r]

Piecewise Functions and Distributions  (2)

Inverse Hankel transform of a piecewise function:

Wolfram Language code: InverseHankelTransform[UnitStep[a - s], s, r]//FunctionExpand

Inverse Hankel transforms of distributions:

Wolfram Language code: InverseHankelTransform[HeavisideTheta[a - s], s, r]//FunctionExpand
Wolfram Language code: InverseHankelTransform[s ^ 2 DiracDelta[s - 2], s, r]

Options  (2)

GenerateConditions  (1)

Obtain conditions for validity of the result:

Wolfram Language code: InverseHankelTransform[(1/Sqrt[s^2 + a^2]), s, r, GenerateConditions -> True]

Assumptions  (1)

Compute the inverse Hankel transform of a function depending on a parameter a:

Wolfram Language code: InverseHankelTransform[(1/Sqrt[s^2 + a^2]), s, r]

Obtain a simpler result by specifying assumptions on the parameter:

Wolfram Language code: InverseHankelTransform[(1/Sqrt[s^2 + a^2]), s, r, Assumptions -> a > 0 && r ≥ 0]

Applications  (3)

The inverse Fourier transform of a radially symmetric function in the plane can be expressed as an inverse Hankel transform. Verify this relation for the function defined by:

Wolfram Language code: f[x_, y_] := E ^ (-Sqrt[x ^ 2 + y ^ 2])

Plot the function:

Wolfram Language code: Plot3D[f[x, y], {x, -3, 3}, {y, -3, 3}, PlotRange -> All, Mesh -> False]

Compute its inverse Fourier transform:

Wolfram Language code: InverseFourierTransform[f[x, y], {x, y}, {u, v}]

Obtain the same result using InverseHankelTransform:

Wolfram Language code: InverseHankelTransform[f[x, y] /. {x -> r Cos[m], y -> r Sin[m]}//Simplify, r, s] /.  {s -> Sqrt[u^2 + v^2]}

Plot the inverse Fourier transform:

Wolfram Language code: Plot3D[%, {u, -3, 3}, {v, -3, 3}, PlotRange -> All, Mesh -> False]

Generate a gallery of inverse Fourier transforms for a list of radially symmetric functions:

Wolfram Language code: flist = {(1/Sqrt[r^2 + 1]), (Sin[2 π r]/r), (1/r), E^-r, BesselJ[0, r]^2, E^-r^2};

Compute the inverse Hankel transforms for these functions:

Wolfram Language code: tlist = FullSimplify[InverseHankelTransform[flist, r, s], Assumptions -> 0 < s < 2]

Generate the gallery of inverse Fourier transforms as required:

Wolfram Language code: (Grid[#1, Alignment -> {{Right, {Left}}, Center}, Spacings -> 0]&)[Table[{Text[flist[[i]] /.  {r -> Sqrt[x^2 + y^2]}], Plot3D[Evaluate[N[flist[[i]] /.  {r -> Sqrt[x^2 + y^2]}]], {x, -2, 2}, {y, -2, 2}, PlotRange -> All, Exclusions -> None, Axes -> None, Ticks -> None, Boxed -> False], Style["→︀", 24, Bold], Plot3D[Evaluate[N[tlist[[i]]] /.  {s -> Sqrt[u^2 + v^2]}], {u, -2, 2}, {v, -2, 2}, PlotRange -> All, Exclusions -> None, Axes -> None, Ticks -> None, Boxed -> False], Text[tlist[[i]] /.  {s -> Sqrt[u^2 + v^2]}]}, {i, 6}]]

Obtain a particular solution for an inhomogeneous equation involving the radial Laplacian:

Wolfram Language code: eqn = Laplacian[f[r], {r, θ}, "Polar"] == 1 / Sqrt[r];

Apply HankelTransform to the equation:

Wolfram Language code: HankelTransform[eqn, r, s]

Solve for the Hankel transform:

Wolfram Language code: sol = Solve[%, HankelTransform[f[r], r, s, 0]]

Apply InverseHankelTransform to obtain a particular solution:

Wolfram Language code: dsol = InverseHankelTransform[HankelTransform[f[r], r, s, 0] /. sol[[1]], s, r]//FullSimplify

Verify the solution:

Wolfram Language code: eqn /. {f -> Function[{r}, Evaluate[dsol]]}

Properties & Relations  (7)

Use Asymptotic to compute an asymptotic approximation:

Wolfram Language code: Asymptotic[Inactive[InverseHankelTransform][E ^ (-s), s, r], r -> 0]

InverseHankelTransform computes the integral int_0^inftys F(s) TemplateBox[{nu, {s, , r}}, BesselJ]ds:

Wolfram Language code: F[s_] := 1 / s
Wolfram Language code: InverseHankelTransform[F[s], s, r, ν]
Wolfram Language code: Integrate[s F[s] BesselJ[ν, s r], {s, 0, Infinity}, Assumptions -> r > 0 && ν > 0]

InverseHankelTransform is the inverse of HankelTransform:

Wolfram Language code: InverseHankelTransform[HankelTransform[f[r], r, s], s, r]

InverseHankelTransform is its own inverse:

Wolfram Language code: F[s_] := E ^ (-s)
Wolfram Language code: InverseHankelTransform[F[s], s, r]
Wolfram Language code: InverseHankelTransform[%, r, s]

InverseHankelTransform is a linear operator:

Wolfram Language code: InverseHankelTransform[a f[s] + b g[s], s, r, ν]

InverseHankelTransform of derivatives:

Wolfram Language code: InverseHankelTransform[Derivative[1][f][s], s, r, ν]
Wolfram Language code: InverseHankelTransform[Derivative[2][f][s] + 1 / s Derivative[1][f][s] - ν ^ 2 / s ^ 2 f[s], s, r, ν]

Derivative of an inverse Hankel transform with respect to r:

Wolfram Language code: D[InverseHankelTransform[F[s], s, r, ν], r]

Neat Examples  (1)

Create a table of basic inverse Hankel transforms:

Wolfram Language code: flist = {UnitStep[a - s], s ^ (-1), 1 / Sqrt[1 + s ^ 2], Log[1 + a ^ 2 / s ^ 2], Sin[s] / (1 + s ^ 2), E ^ (-(a * s)), E ^ (-s ^ 2), 1 / (E ^ (2 * s ^ 2) * s)};
Wolfram Language code: Grid[Join[{{F[s], InverseHankelTransform[F[s], s, r]}}, Transpose[{flist, Map[HankelTransform[#, s, r]&, flist]}]], IconizedObject[«Grid options»]]//TraditionalForm
Wolfram Research (2017), InverseHankelTransform, Wolfram Language function, https://reference.wolfram.com/language/ref/InverseHankelTransform.html.

Text

Wolfram Research (2017), InverseHankelTransform, Wolfram Language function, https://reference.wolfram.com/language/ref/InverseHankelTransform.html.

CMS

Wolfram Language. 2017. "InverseHankelTransform." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/InverseHankelTransform.html.

APA

Wolfram Language. (2017). InverseHankelTransform. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/InverseHankelTransform.html

BibTeX

@misc{reference.wolfram_2026_inversehankeltransform, author="Wolfram Research", title="{InverseHankelTransform}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/InverseHankelTransform.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_inversehankeltransform, organization={Wolfram Research}, title={InverseHankelTransform}, year={2017}, url={https://reference.wolfram.com/language/ref/InverseHankelTransform.html}, note=[Accessed: 13-June-2026]}