WOLFRAM

Wolfram Language & System Documentation Center

InverseSurvivalFunction[dist,q]

gives the inverse of the survival function for the distribution dist as a function of the variable q.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Parametric Distributions  
Derived Distributions  
Nonparametric Distributions  
Random Processes  
Generalizations & Extensions  
Applications  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

InverseSurvivalFunction

InverseSurvivalFunction[dist,q]

gives the inverse of the survival function for the distribution dist as a function of the variable q.

Details

  • The inverse survival function at q is equivalent to the (1-q)^(th) quantile of a distribution.
  • For a continuous distribution dist, the inverse survival function at q is the value x such that SurvivalFunction[dist,x]q.
  • For a discrete distribution dist, the inverse survival function at q is the smallest integer x such that SurvivalFunction[dist,x]≤q.
  • The value q can be symbolic or any number between 0 and 1.

Examples

open all close all

Basic Examples  (2)

Inverse survival function for a continuous univariate distribution:

Wolfram Language code: Plot[Table[InverseSurvivalFunction[BetaDistribution[1 / 2, β], q], {β, {1 / 4, 1 / 2, 1}}]//Evaluate, {q, 0, 1}, Filling -> Axis]
Wolfram Language code: InverseSurvivalFunction[BetaDistribution[α, β], q]

Inverse survival function for a discrete univariate distribution:

Wolfram Language code: 𝒟 = PoissonDistribution[5];
Wolfram Language code: DiscretePlot[InverseSurvivalFunction[𝒟, p], {p, SurvivalFunction[𝒟, Range[0, 10]]}, ExtentSize -> Right, ExtentMarkers -> {"Empty", "Filled"}]

Scope  (11)

Parametric Distributions  (4)

Obtain exact numeric results:

Wolfram Language code: InverseSurvivalFunction[ExponentialDistribution[2], 1 / 4]
Wolfram Language code: InverseSurvivalFunction[NegativeBinomialDistribution[20, 1 / 3], 1 / 5]

Obtain a machine-precision result:

Wolfram Language code: InverseSurvivalFunction[WeibullDistribution[2, 5], 0.4]

Obtain a result at any precision for a continuous distribution:

Wolfram Language code: InverseSurvivalFunction[WeibullDistribution[2, 5], N[1 / 14, 25]]

Obtain a symbolic expression for the inverse survival function:

Wolfram Language code: InverseSurvivalFunction[ChiSquareDistribution[ν], x]

Derived Distributions  (3)

Quadratic transformation of an exponential distribution:

Wolfram Language code: InverseSurvivalFunction[TransformedDistribution[x ^ 2, xExponentialDistribution[2]], y]
Wolfram Language code: Plot[%, {y, 0, 1}, Filling -> Axis]

Truncated distribution:

Wolfram Language code: isf = InverseSurvivalFunction[TruncatedDistribution[{2, 3}, TriangularDistribution[{1, 4}]], x]
Wolfram Language code: Plot[isf, {x, 0, 1}, Filling -> Axis, Exclusions -> None]

InverseSurvivalFunction for distributions with quantities:

Wolfram Language code: InverseSurvivalFunction[MaxwellDistribution[Quantity[45.3, "Meters"/"Seconds"]], Quantity[96, "Percent"]]

For a data distribution:

Wolfram Language code: sample = QuantityArray[RandomVariate[NormalDistribution[2, 5], 1000], "Grams"]
Wolfram Language code: InverseSurvivalFunction[SmoothKernelDistribution[sample], 0.7]

Nonparametric Distributions  (2)

Inverse survival function for nonparametric distributions:

Wolfram Language code: r = RandomVariate[NormalDistribution[], 10 ^ 3];
Wolfram Language code: InverseSurvivalFunction[HistogramDistribution[r], 0.2]
Wolfram Language code: InverseSurvivalFunction[SmoothKernelDistribution[r], 0.2]
Wolfram Language code: InverseSurvivalFunction[KernelMixtureDistribution[r], 0.2]
Wolfram Language code: InverseSurvivalFunction[SurvivalDistribution[r], 0.2]
Wolfram Language code: InverseSurvivalFunction[EmpiricalDistribution[r], 0.2]

Compare with the value for the underlying parametric distribution:

Wolfram Language code: InverseSurvivalFunction[NormalDistribution[], 0.2]

Plot the survival function for a histogram distribution:

Wolfram Language code: Plot[InverseSurvivalFunction[HistogramDistribution[RandomVariate[NormalDistribution[], 10 ^ 3]], x]//Evaluate, {x, 0, 1}, Filling -> Axis, Exclusions -> None]

Random Processes  (2)

InverseSurvivalFunction for the SliceDistribution of a random process:

Wolfram Language code: InverseSurvivalFunction[WienerProcess[μ, σ][t], q]
Wolfram Language code: Plot[Evaluate[% /. {μ -> 3, σ -> 1, q -> 1 / 20}], {t, 0, 1}]

Find the InverseSurvivalFunction of TemporalData at some time t=0.5:

Wolfram Language code: td = RandomFunction[WienerProcess[1, 1], {0, 10, 0.05}, 100]
Wolfram Language code: InverseSurvivalFunction[td[0.5], 0.4]

Find the InverseSurvivalFunction for a range of times together with all the simulations:

Wolfram Language code: Show[ListLinePlot[td, PlotStyle -> Directive[Opacity[0.2], Thin]], Plot[InverseSurvivalFunction[td[t], 0.4], {t, 0, 10}, PlotStyle -> Thick]]

Generalizations & Extensions  (1)

InverseSurvivalFunction threads element-wise over lists:

Wolfram Language code: InverseSurvivalFunction[NormalDistribution[], {0.2, 0.3}]
Wolfram Language code: {InverseSurvivalFunction[NormalDistribution[], 0.2], InverseSurvivalFunction[NormalDistribution[], 0.3]}

Applications  (3)

Plot the inverse survival function for a standard normal distribution:

Wolfram Language code: Plot[InverseSurvivalFunction[NormalDistribution[0, 1], q], {q, 0, 1}]

Plot the inverse survival function for a binomial distribution:

Wolfram Language code: Plot[InverseSurvivalFunction[BinomialDistribution[20, .5], q], {q, 0, 1}, PlotRange -> {0, 20}]

Generate a random number from a distribution:

Wolfram Language code: InverseSurvivalFunction[StudentTDistribution[20], RandomReal[]]

Properties & Relations  (3)

InverseSurvivalFunction and SurvivalFunction are inverses for continuous distributions:

Wolfram Language code: dist = ExponentialDistribution[λ];
Wolfram Language code: Assuming[y > 0 && λ > 0, Simplify[InverseSurvivalFunction[dist, SurvivalFunction[dist, y]] == y]]
Wolfram Language code: Assuming[1 > q > 0 && λ > 0, Simplify[SurvivalFunction[dist, InverseSurvivalFunction[dist, q]] == q]]

Compositions of InverseSurvivalFunction and SurvivalFunction give step functions for a discrete distribution:

Wolfram Language code: dist = PoissonDistribution[2];
Wolfram Language code: Plot[SurvivalFunction[dist, InverseSurvivalFunction[dist, q]], {q, 0, 1}, Exclusions -> None]
Wolfram Language code: Plot[InverseSurvivalFunction[dist, SurvivalFunction[dist, y]], {y, 0, 10}, Exclusions -> None]

InverseSurvivalFunction is equivalent to InverseCDF for distributions:

Wolfram Language code: InverseSurvivalFunction [CauchyDistribution[a, b], q]
Wolfram Language code: InverseCDF[CauchyDistribution[a, b], 1 - q]
Wolfram Language code: Simplify[% - %%, 0 < q < 1]

Possible Issues  (2)

Symbolic closed forms do not exist for some distributions:

Wolfram Language code: InverseSurvivalFunction[BinomialDistribution[50, .5], q]

Numerical evaluation works:

Wolfram Language code: InverseSurvivalFunction[BinomialDistribution[50, .5], .75]

When giving the input as an argument, complete checking is done and invalid input will not evaluate:

Wolfram Language code: InverseSurvivalFunction[CauchyDistribution[2, 3], 1. + I]
Wolfram Research (2010), InverseSurvivalFunction, Wolfram Language function, https://reference.wolfram.com/language/ref/InverseSurvivalFunction.html.

Text

Wolfram Research (2010), InverseSurvivalFunction, Wolfram Language function, https://reference.wolfram.com/language/ref/InverseSurvivalFunction.html.

CMS

Wolfram Language. 2010. "InverseSurvivalFunction." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/InverseSurvivalFunction.html.

APA

Wolfram Language. (2010). InverseSurvivalFunction. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/InverseSurvivalFunction.html

BibTeX

@misc{reference.wolfram_2026_inversesurvivalfunction, author="Wolfram Research", title="{InverseSurvivalFunction}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/InverseSurvivalFunction.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_inversesurvivalfunction, organization={Wolfram Research}, title={InverseSurvivalFunction}, year={2010}, url={https://reference.wolfram.com/language/ref/InverseSurvivalFunction.html}, note=[Accessed: 12-June-2026]}