WOLFRAM

Wolfram Language & System Documentation Center

InverseWeierstrassP[p,{g2,g3}]

gives a value of u for which the Weierstrass function is equal to p.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Show More Show More
Function Properties  
Differentiation  
Integration  
Series Expansions  
Generalizations & Extensions  
Applications  
Properties & Relations  
Possible Issues  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

InverseWeierstrassP

InverseWeierstrassP[p,{g2,g3}]

gives a value of u for which the Weierstrass function is equal to p.

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • The value of u returned always lies in the fundamental period parallelogram defined by the complex half‐periods and .
  • InverseWeierstrassP[{p,q},{g2,g3}] finds the unique value of u for which and . For such a value to exist, p and q must be related by .
  • InverseWeierstrassP can be evaluated to arbitrary numerical precision.

Examples

open all close all

Basic Examples  (4)

Evaluate numerically:

Wolfram Language code: InverseWeierstrassP[2., {1, 2}]//Chop
Wolfram Language code: WeierstrassP[%, {1, 2}]

Plot over a subset of the reals:

Wolfram Language code: Plot[InverseWeierstrassP[x, {1, 2}], {x, 2, 6}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[InverseWeierstrassP[z, {1, 2}], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[InverseWeierstrassP[x, {1, 2}], {x, 0, 5}]

Scope  (20)

Numerical Evaluation  (4)

Evaluate numerically:

Wolfram Language code: InverseWeierstrassP[7., {1, 2}]
Wolfram Language code: InverseWeierstrassP[11., {3, 2}]

Evaluate to high precision:

Wolfram Language code: N[InverseWeierstrassP[1 / 3, {1, 2}], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: InverseWeierstrassP[3.222222222222222222222, {1, 2}]

Complex number input:

Wolfram Language code: InverseWeierstrassP[3. + I, {I, I + 2}]

Evaluate efficiently at high precision:

Wolfram Language code: InverseWeierstrassP[16`100, {3, 2}]//Timing
Wolfram Language code: InverseWeierstrassP[15`10000, {4, 2}];//Timing//Quiet

Specific Values  (4)

Values at fixed points:

Wolfram Language code: Table[InverseWeierstrassP[x, {0, 0}], {x, {-1, 2}}]

Value at zero:

Wolfram Language code: InverseWeierstrassP[0, {0, 0}]

Find a value of x for which InverseWeierstrassP[x,{1,2}]=2:

Wolfram Language code: xval = x /. FindRoot[InverseWeierstrassP[x, {1, 2} ] == 2, {x, 3}]//Chop
Wolfram Language code: Plot[InverseWeierstrassP[x, {1, 2} ], {x, 1, 5}, Epilog -> Style[Point[{xval, InverseWeierstrassP[xval, {1, 2} ]}], PointSize[Large], Red]]

TraditionalForm formatting:

Wolfram Language code: InverseWeierstrassP[z, {Subscript[g, 2], Subscript[g, 3]}]//TraditionalForm

Visualization  (2)

Plot the InverseWeierstrassP function for various parameters:

Wolfram Language code: Plot[{InverseWeierstrassP[u, {2, 3}], InverseWeierstrassP[u, {4, 3}], InverseWeierstrassP[u, {4, 5}]}, {u, 1, 4}]

Plot the real part of TemplateBox[{z, 7, 1}, InverseWeierstrassP]:

Wolfram Language code: ComplexContourPlot[Re[InverseWeierstrassP[z, {7, 1}]], {z, -3 - 3 I, 3 + 3I}, Contours -> 20]

Plot the imaginary part of TemplateBox[{z, 7, 1}, InverseWeierstrassP]:

Wolfram Language code: ComplexContourPlot[Im[InverseWeierstrassP[z, {7, 1}]], {z, -3 - 3 I, 3 + 3I}, Contours -> 20]

Function Properties  (4)

InverseWeierstrassP has both singularities and discontinuities:

Wolfram Language code: FunctionSingularities[InverseWeierstrassP[x, {1, 2}], x]//Quiet
Wolfram Language code: FunctionDiscontinuities[InverseWeierstrassP[x, {1, 2}], x]//Quiet

TemplateBox[{x, 1, 2}, InverseWeierstrassP] is injective:

Wolfram Language code: FunctionInjective[InverseWeierstrassP[x, {2, 1}], x]
Wolfram Language code: Plot[{InverseWeierstrassP[x, {2, 1}], 2}, {x, 0, 6}]

TemplateBox[{x, 1, 2}, InverseWeierstrassP] is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[InverseWeierstrassP[x, {1, 2}], x]

It is complex-valued over part of the real axis

Wolfram Language code: InverseWeierstrassP[0, {1, 2}]//N

TemplateBox[{x, {1, /, 2}, {1, /, 2}}, InverseWeierstrassP] is neither convex nor concave:

Wolfram Language code: FunctionConvexity[InverseWeierstrassP[x, {1 / 2, 1 / 2}], x]

It is complex-valued over part of the real axis:

Wolfram Language code: InverseWeierstrassP[0, {1 / 2, 1 / 2}]//N

Differentiation  (2)

First derivative with respect to :

Wolfram Language code: D[InverseWeierstrassP[p, {Subscript[g, 2], Subscript[g, 3]}], p]

Higher derivatives with respect to :

Wolfram Language code: Table[D[InverseWeierstrassP[p, {Subscript[``g``, 2], Subscript[``g``, 3]}], {p, k}], {k, 1, 4}]//FullSimplify

Plot the higher derivatives with respect to when and :

Wolfram Language code: Plot[Evaluate[% /. {Subscript[``g``, 2] -> 1, Subscript[``g``, 3] -> 2}], {p, 1, 5}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

Integration  (2)

Compute the indefinite integral using Integrate:

Wolfram Language code: Integrate[InverseWeierstrassP[x, {g2, g3}], x]

Verify the antiderivative:

Wolfram Language code: FullSimplify[D[%, x]]

Definite integral:

Wolfram Language code: Integrate[InverseWeierstrassP[x, {2, 3}], {x, 0, 5}]

Series Expansions  (2)

Find the Taylor expansion using Series:

Wolfram Language code: Series[InverseWeierstrassP[x, {g1, g2}], {x, 0, 2}]//Normal

Plots of the first three approximations around :

Wolfram Language code: terms = Abs@Normal@Table[Series[InverseWeierstrassP[x, {1, 2}], {x, 0, m}], {m, 1, 5, 2}]; Plot[{InverseWeierstrassP[x, {1, 2}], terms}, {x, 0, 7}]

Taylor expansion at a generic point:

Wolfram Language code: Series[InverseWeierstrassP[x, {g1, g2}], {x, x0, 2}]//Normal// FullSimplify

Generalizations & Extensions  (1)

Evaluate the generalized form numerically:

Wolfram Language code: {p, pp} = {2., 2Sqrt[7]};
Wolfram Language code: z = InverseWeierstrassP[{p, pp}, {1, 2}]

These are the inverse relationships with WeierstrassP and WeierstrassPPrime:

Wolfram Language code: p == WeierstrassP[z, {1, 2}]
Wolfram Language code: pp == WeierstrassPPrime[z, {1, 2}]

Applications  (2)

Plot the real and imaginary part of InverseWeierstrassP:

Wolfram Language code: Plot[{Re[InverseWeierstrassP[x, {1, I}]], Im[InverseWeierstrassP[x, {1, I}]]}, {x, -2, 2}]

Form derivatives:

Wolfram Language code: D[InverseWeierstrassP[z, {Subscript[g, 2], Subscript[g, 3]}], {z, 6}]//TraditionalForm

Properties & Relations  (1)

InverseWeierstrassP is closely related to EllipticLog function:

Wolfram Language code: ellipticLog[{x_, y_}, {a_, b_}] := (1/2)InverseWeierstrassP[{(1/4)(x + (a/3)), (y/4)}, {(1/4)((a^2/3) - b), (1/8)(a/3)((b/2) - ((a/3))^2)}]

Evaluate numerically:

Wolfram Language code: a = 3;b = 2; {x, y} = EllipticExp[1.2, {a, b}];
Wolfram Language code: ellipticLog[{x, y}, {a, b}]

Compare with the value of the built-in function:

Wolfram Language code: EllipticLog[{x, y}, {a, b}]

Possible Issues  (2)

If the first argument does not represent a pair of values of Weierstrass functions, InverseWeierstrassP stays unevaluated:

Wolfram Language code: InverseWeierstrassP[{RandomReal[], RandomReal[]}, {1, 2}]

InverseWeierstrassP evaluates to a vector‐valued first argument:

Wolfram Language code: InverseWeierstrassP[WeierstrassP[2, {1, 2}], {1, 2}]
Wolfram Research (1996), InverseWeierstrassP, Wolfram Language function, https://reference.wolfram.com/language/ref/InverseWeierstrassP.html.

Text

Wolfram Research (1996), InverseWeierstrassP, Wolfram Language function, https://reference.wolfram.com/language/ref/InverseWeierstrassP.html.

CMS

Wolfram Language. 1996. "InverseWeierstrassP." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/InverseWeierstrassP.html.

APA

Wolfram Language. (1996). InverseWeierstrassP. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/InverseWeierstrassP.html

BibTeX

@misc{reference.wolfram_2026_inverseweierstrassp, author="Wolfram Research", title="{InverseWeierstrassP}", year="1996", howpublished="\url{https://reference.wolfram.com/language/ref/InverseWeierstrassP.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_inverseweierstrassp, organization={Wolfram Research}, title={InverseWeierstrassP}, year={1996}, url={https://reference.wolfram.com/language/ref/InverseWeierstrassP.html}, note=[Accessed: 13-June-2026]}