WOLFRAM

Wolfram Language & System Documentation Center

InverseWishartMatrixDistribution[ν,Σ]

represents an inverse Wishart matrix distribution with ν degrees of freedom and covariance matrix Σ.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

InverseWishartMatrixDistribution

InverseWishartMatrixDistribution[ν,Σ]

represents an inverse Wishart matrix distribution with ν degrees of freedom and covariance matrix Σ.

Details

Examples

open all close all

Basic Examples  (3)

Generate a pseudorandom matrix:

Wolfram Language code: RandomVariate[InverseWishartMatrixDistribution[10, {{1, 1 / 3}, {1 / 3, 1}}]]

Check that it is positive definite:

Wolfram Language code: PositiveDefiniteMatrixQ[%]

Sample eigenvalues of an inverse Wishart random matrix using MatrixPropertyDistribution:

Wolfram Language code: λ𝒟 = MatrixPropertyDistribution[RandomSample[Eigenvalues[x]], xInverseWishartMatrixDistribution[10, {{1, 1 / 3}, {1 / 3, 1}}]];
Wolfram Language code: SmoothHistogram3D[RandomVariate[λ𝒟, 10 ^ 4], PlotRange -> {{-.1, .5}, {-.1, .5}, Automatic}]

Mean and variance:

Wolfram Language code: Mean[InverseWishartMatrixDistribution[8, DiagonalMatrix[{2, 1, 3}]]]//MatrixForm
Wolfram Language code: Variance[InverseWishartMatrixDistribution[8, DiagonalMatrix[{2, 1, 3}]]]//MatrixForm

Scope  (6)

Generate a single pseudorandom matrix:

Wolfram Language code: RandomVariate[InverseWishartMatrixDistribution[10, {{1, 1 / 3}, {1 / 3, 1}}]]

Generate a set of pseudorandom matrices:

Wolfram Language code: MatrixForm /@ RandomVariate[InverseWishartMatrixDistribution[10, {{1, 1 / 3}, {1 / 3, 1}}], 3]

Sample at extended precision:

Wolfram Language code: RandomVariate[InverseWishartMatrixDistribution[10, {{1, 1 / 3}, {1 / 3, 1}}], WorkingPrecision -> 20]

Compute statistical properties numerically:

Wolfram Language code: λmax𝒟 = MatrixPropertyDistribution[Max[Eigenvalues[𝓂]], 𝓂InverseWishartMatrixDistribution[10, {{1, 1 / 3}, {1 / 3, 1}}]];

Numerically approximate expectation of the largest matrix eigenvalue :

Wolfram Language code: NExpectation[λmax, λmaxλmax𝒟]

Distribution parameters estimation:

Wolfram Language code: dist = InverseWishartMatrixDistribution[3, IdentityMatrix[2]]; sample = RandomVariate[dist, 10 ^ 2];

Estimate the distribution parameters from sample data:

Wolfram Language code: edist = EstimatedDistribution[sample, InverseWishartMatrixDistribution[ν, Array[c, {2, 2}]]]

Compare LogLikelihood for both distributions:

Wolfram Language code: LogLikelihood[#, sample]& /@ {edist, dist}

Skewness:

Wolfram Language code: Skewness[InverseWishartMatrixDistribution[8, {{2, 1}, {1, 3}}]]//MatrixForm

Properties & Relations  (3)

, where and are independent Gaussian vector and Wishart matrix follows HotellingTSquareDistribution:

Wolfram Language code: cov = {{1, 2 / 5}, {2 / 5, 1 / 2}}; n = 10; t2dist = HotellingTSquareDistribution[Length[cov], n];

Use MatrixPropertyDistribution to sample expressions :

Wolfram Language code: sample = RandomVariate[MatrixPropertyDistribution[n x.w.x, {wInverseWishartMatrixDistribution[n, Inverse[cov]], xMultinormalDistribution[{0, 0}, cov]}], 10 ^ 4];
Wolfram Language code: DistributionFitTest[sample, t2dist]
Wolfram Language code: Show[Histogram[sample, Automatic, PDF], Plot[PDF[t2dist, x], {x, 0, 12}]]

Any diagonal element of inverse Wishart random matrix follows scaled inverse χ2 distribution:

Wolfram Language code: n = 10; des = RandomVariate[MatrixPropertyDistribution[Diagonal[m], mInverseWishartMatrixDistribution[n, {{1, 4 / 5}, {4 / 5, 1}}]], 10 ^ 4];
Wolfram Language code: DistributionFitTest[des[[All, 1]], InverseChiSquareDistribution[n - 1]]
Wolfram Language code: DistributionFitTest[des[[All, 2]], InverseChiSquareDistribution[n - 1]]

Diagonal elements are not independent:

Wolfram Language code: ListPlot[des, PlotRange -> {{0, 1}, {0, 1}}]
Wolfram Language code: IndependenceTest[des[[All, 1]], des[[All, 2]], "TestConclusion"]

For any nonzero vector and inverse Wishart matrix with scale matrix , is χ2 distributed:

Wolfram Language code: Σ = {{1, 4 / 5}, {4 / 5, 1}}; n = 10.3; y = # / Sqrt[#.Σ.#]&[RandomReal[1, 2]]; data = RandomVariate[MatrixPropertyDistribution[y.Inverse[w].y, wInverseWishartMatrixDistribution[n, Inverse[Σ]]], 10 ^ 4];
Wolfram Language code: DistributionFitTest[data, ChiSquareDistribution[n]]
Wolfram Language code: Show[Histogram[data, Automatic, PDF], Plot[PDF[ChiSquareDistribution[n], x], {x, 0, 30}]]
Wolfram Research (2015), InverseWishartMatrixDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/InverseWishartMatrixDistribution.html (updated 2017).

Text

Wolfram Research (2015), InverseWishartMatrixDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/InverseWishartMatrixDistribution.html (updated 2017).

CMS

Wolfram Language. 2015. "InverseWishartMatrixDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2017. https://reference.wolfram.com/language/ref/InverseWishartMatrixDistribution.html.

APA

Wolfram Language. (2015). InverseWishartMatrixDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/InverseWishartMatrixDistribution.html

BibTeX

@misc{reference.wolfram_2026_inversewishartmatrixdistribution, author="Wolfram Research", title="{InverseWishartMatrixDistribution}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/InverseWishartMatrixDistribution.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_inversewishartmatrixdistribution, organization={Wolfram Research}, title={InverseWishartMatrixDistribution}, year={2017}, url={https://reference.wolfram.com/language/ref/InverseWishartMatrixDistribution.html}, note=[Accessed: 13-June-2026]}