WOLFRAM

Wolfram Language & System Documentation Center

MatrixNormalDistribution[Σrow,Σcol]

represents a zero mean matrix normal distribution with row covariance matrix Σrow and column covariance matrix Σcol.

MatrixNormalDistribution[μ,Σrow,Σcol]

represents a matrix normal distribution with mean matrix μ.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

MatrixNormalDistribution

MatrixNormalDistribution[Σrow,Σcol]

represents a zero mean matrix normal distribution with row covariance matrix Σrow and column covariance matrix Σcol.

MatrixNormalDistribution[μ,Σrow,Σcol]

represents a matrix normal distribution with mean matrix μ.

Details

Examples

open all close all

Basic Examples  (2)

Sample from a matrix normal distribution:

Wolfram Language code: RandomVariate[MatrixNormalDistribution[{{3, 1, 1}, {1, 2, -1}, {1, -1, 4}}, {{1, -1 / 2}, {-1 / 2, 2}}]]

Mean and variance:

Wolfram Language code: Mean[MatrixNormalDistribution[{{1, 4}, {6, 8}, {10, 2}}, DiagonalMatrix[{2, 1, 3}], {{2, 1}, {1, 3}}]]//MatrixForm
Wolfram Language code: Variance[MatrixNormalDistribution[{{1, 4}, {6, 8}, {10, 2}}, DiagonalMatrix[{2, 1, 3}], {{2, 1}, {1, 3}}]]//MatrixForm

Scope  (7)

Generate a single pseudorandom matrix:

Wolfram Language code: RandomVariate[MatrixNormalDistribution[{{1, 1 / 3}, {1 / 3, 1}}, IdentityMatrix[3]]]

Generate a single pseudorandom matrix with nonzero mean:

Wolfram Language code: RandomVariate[MatrixNormalDistribution[{{1, 2, 3}, {4, 5, 6}}, {{1, 1 / 3}, {1 / 3, 1}}, IdentityMatrix[3]]]

Generate a set of pseudorandom matrices:

Wolfram Language code: RandomVariate[MatrixNormalDistribution[{{1, 1 / 3}, {1 / 3, 1}}, IdentityMatrix[3]], 3]

Sample at extended precision:

Wolfram Language code: RandomVariate[MatrixNormalDistribution[{{1, 1 / 3}, {1 / 3, 1}}, IdentityMatrix[3]], WorkingPrecision -> 20]

Distribution parameters estimation:

Wolfram Language code: dist = MatrixNormalDistribution[{{3, 1}, {1, 2}}, ToeplitzMatrix[{4, 2, 1}]];sample = RandomVariate[dist, 10 ^ 3];

Estimate the distribution parameters from sample data:

Wolfram Language code: edist = EstimatedDistribution[sample, MatrixNormalDistribution[Array[row, {2, 2}], Array[col, {3, 3}]]]

Compare LogLikelihood for both distributions:

Wolfram Language code: LogLikelihood[#, sample]& /@ {edist, dist}

Find the probability that the smallest eigenvalue TemplateBox[{{lambda, _, {(, min, )}}}, Abs]>0.1`:

Wolfram Language code: NProbability[λmin > 0.1, λminMatrixPropertyDistribution[Min[Abs[Eigenvalues[m]]], mMatrixNormalDistribution[IdentityMatrix[10], IdentityMatrix[10]]]]

Probability density function:

Wolfram Language code: dist = MatrixNormalDistribution[IdentityMatrix[2], DiagonalMatrix[{2, 1}]];PDF[dist, {{1., 2.}, {3, 4.}}]

Plot PDF for a diagonal matrices:

Wolfram Language code: Plot3D[PDF[dist, DiagonalMatrix[{a, b}]], {a, -3, 3}, {b, -3, 3}]

Skewness and kurtosis:

Wolfram Language code: Skewness[MatrixNormalDistribution[{{2, 1}, {1, 3}}, IdentityMatrix[3]]]//MatrixForm
Wolfram Language code: Kurtosis[MatrixNormalDistribution[{{2, 1}, {1, 3}}, IdentityMatrix[3]]]//MatrixForm

Applications  (2)

Visualize sample matrices from matrix normal distributions:

Wolfram Language code: sigR = Covariance[ARProcess[{-0.95}, 1][Range[0, 100]]]; sigC = KroneckerProduct[IdentityMatrix[100, SparseArray], {{1, 1 / 2}, {1 / 2, 3}}]; vals = RandomVariate[MatrixNormalDistribution[sigR, sigC]];
Wolfram Language code: MatrixPlot[vals, PlotTheme -> "Minimal"]
Wolfram Language code: sigR = Covariance[ARProcess[{0.95}, 1][Range[0, 100]]]; sigC = KroneckerProduct[IdentityMatrix[100, SparseArray], {{1, 1 / 2}, {1 / 2, 3}}]; vals = RandomVariate[MatrixNormalDistribution[sigR, sigC]];
Wolfram Language code: MatrixPlot[vals, PlotTheme -> "Minimal"]

Use a matrix normal distribution to simulate a vector autoregressive process:

Wolfram Language code: sigR = Covariance[ARProcess[{a}, 1][Range[0, 100]]]; sigC = {{s11, s12}, {s12, s22}};
Wolfram Language code: rules = {a -> 1 / 2, s11 -> 1, s12 -> 1 / 2, s22 -> 3};
Wolfram Language code: dist = MatrixNormalDistribution[sigR, sigC] /. rules;
Wolfram Language code: vals = RandomVariate[dist, 10000];

Construct TemporalData from sampled values:

Wolfram Language code: td = TemporalData[vals, {0, Length[sigR] - 1, 1}, ValueDimensions -> 2];

Estimate the diagonal vector autoregressive process:

Wolfram Language code: proc = ARProcess[{a IdentityMatrix[2]}, {{s11, s12}, {s12, s22}}];
Wolfram Language code: sol = FindProcessParameters[td, proc]

Compare to the original values:

Wolfram Language code: sol[[All, 2]] - rules[[All, 2]]

Properties & Relations  (6)

A matrix normal distribution is defined up to a positive multiplicative constant:

Wolfram Language code: sigr = {{2, 1}, {1, 4}}; sigc = ToeplitzMatrix[{9, 3, 1}]; 𝒟1 = MatrixNormalDistribution[sigr, sigc];

Equivalent distribution with row and column scale matrices multiplied and divided by a positive constant:

Wolfram Language code: c = 2; 𝒟2 = MatrixNormalDistribution[c * sigr, sigc / c];

Compute the PDF of the distributions at a random point:

Wolfram Language code: mat = RandomReal[{-10, 10}, {2, 3}]
Wolfram Language code: PDF[𝒟1, mat] == PDF[𝒟2, mat]

MatrixTDistribution[Σrow,Σcol,ν] is a parameter mixture of MatrixNormalDistribution[Σ,Σcol] with following InverseWishartMatrixDistribution[ν+n-1,Σrow]:

Wolfram Language code: ν = 5; n = 3; Σr = IdentityMatrix[n]; Σc = IdentityMatrix[2]; invW = InverseWishartMatrixDistribution[ν + n - 1, Σr];

Create a sample following the parameter mixture of MatrixNormalDistribution with InverseWishartMatrixDistribution:

Wolfram Language code: sampleSize = 10 ^ 3; sigmas = RandomVariate[invW, 10 ^ 3]; sample = Table[RandomVariate[MatrixNormalDistribution[s, Σc]], {s, sigmas}];

Fit the sample data to MatrixTDistribution:

Wolfram Language code: edist = EstimatedDistribution[sample, MatrixTDistribution[Array[s1, {3, 3}], Array[s2, {2, 2}], nu]]

Compute log-likelihood ratio statistic against the appropriate MatrixTDistribution:

Wolfram Language code: ratio = LogLikelihood[edist, sample] - LogLikelihood[MatrixTDistribution[Σr, Σc, ν], sample]

Log-likelihood ratio follows ChiSquareDistribution with the parameter equal to the number of degrees of freedom:

Wolfram Language code: dof = (Length[Σr] + 1) * Length[Σr] / 2 + (Length[Σc] + 1) * Length[Σc] / 2 + 1

Compute the -value of log-likelihood ratio test:

Wolfram Language code: pval = SurvivalFunction[ChiSquareDistribution[dof], 2ratio]

Sample from a matrix normal distribution with independent rows:

Wolfram Language code: mat = RandomVariate[MatrixNormalDistribution[IdentityMatrix[10 ^ 3, SparseArray], {{1, -1 / 2}, {-1 / 2, 2}}]];

Test the hypothesis that rows follow a multinormal distribution with the column covariance matrix:

Wolfram Language code: BaringhausHenzeTest[mat, MultinormalDistribution[{0, 0}, {{1, -1 / 2}, {-1 / 2, 2}}], "TestConclusion"]

Sample from a matrix normal distribution with independent rows:

Wolfram Language code: mat = RandomVariate[MatrixNormalDistribution[IdentityMatrix[10 ^ 3, SparseArray], {{1, -1 / 2}, {-1 / 2, 2}}]];

Test the hypothesis that rows follow a multinormal distribution with the column covariance matrix:

Wolfram Language code: BaringhausHenzeTest[mat, MultinormalDistribution[{0, 0}, {{1, -1 / 2}, {-1 / 2, 2}}], "TestConclusion"]

Sample from a matrix normal distribution with independent rows:

Wolfram Language code: data = RandomVariate[MatrixNormalDistribution[IdentityMatrix[3], {{1, -1 / 2}, {-1 / 2, 2}}], 10 ^ 5];

Computing sample inter-row covariances shows different rows are pairwise independent:

Wolfram Language code: Round[Table[Covariance[data[[All, i]], data[[All, j]]], {i, 3}, {j, 3}], 0.05]//MatrixForm

Computing sample inter-column covariances shows different columns are dependent:

Wolfram Language code: Round[Table[Covariance[data[[All, All, i]], data[[All, All, j]]], {i, 2}, {j, 2}], 0.05]//MatrixForm

By joining the rows of the matrix-valued random variable together, a matrix normal distribution can be regarded as a multivariate normal distribution:

Wolfram Language code: Subscript[Σ, r] = {{2, 1}, {1, 3}}; Subscript[Σ, c] = {{1, 1 / 2}, {1 / 2, 3}};
Wolfram Language code: mats = RandomVariate[MatrixNormalDistribution[Subscript[Σ, r], Subscript[Σ, c]], 5000];
Wolfram Language code: vecs = Flatten[mats, {{1}, {2, 3}}];

The covariance matrix of the vectorized random matrix is the Kronecker product of and :

Wolfram Language code: DistributionFitTest[vecs, MultinormalDistribution[{0, 0, 0, 0}, KroneckerProduct[Subscript[Σ, r], Subscript[Σ, c]]], {"TestDataTable", All}]

Possible Issues  (1)

A matrix normal distribution is defined up to a multiplicative scaling constant. The estimated parameters may not be close to the ones that specify the underlying distribution:

Wolfram Language code: sigr = ToeplitzMatrix[{4, 2, 1}]; sigc = DiagonalMatrix[{3, 1}]; dist = MatrixNormalDistribution[sigr, sigc];

Sample from the matrix normal distribution:

Wolfram Language code: sample = RandomVariate[dist, 10 ^ 4];

Estimate the distribution:

Wolfram Language code: edist = EstimatedDistribution[sample, MatrixNormalDistribution[Array[s1, {3, 3}], Array[s2, {2, 2}]]];

Compare the estimated scale parameters with the ones of the underlying distribution:

Wolfram Language code: MatrixForm /@ {esigr = First[edist], sigr}
Wolfram Language code: MatrixForm /@ {esigc = edist[[2]], sigc}

Kronecker products of the scale matrices are close to each other:

Wolfram Language code: NumberForm[KroneckerProduct[sigr, sigc] - KroneckerProduct[esigr, esigc]//MatrixForm, 4]

The LogLikelihood of the distribution indicates that the estimate is good:

Wolfram Language code: LogLikelihood[#, sample]& /@ {dist, edist}
Wolfram Research (2015), MatrixNormalDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/MatrixNormalDistribution.html (updated 2017).

Text

Wolfram Research (2015), MatrixNormalDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/MatrixNormalDistribution.html (updated 2017).

CMS

Wolfram Language. 2015. "MatrixNormalDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2017. https://reference.wolfram.com/language/ref/MatrixNormalDistribution.html.

APA

Wolfram Language. (2015). MatrixNormalDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MatrixNormalDistribution.html

BibTeX

@misc{reference.wolfram_2026_matrixnormaldistribution, author="Wolfram Research", title="{MatrixNormalDistribution}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/MatrixNormalDistribution.html}", note=[Accessed: 15-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_matrixnormaldistribution, organization={Wolfram Research}, title={MatrixNormalDistribution}, year={2017}, url={https://reference.wolfram.com/language/ref/MatrixNormalDistribution.html}, note=[Accessed: 15-June-2026]}