WOLFRAM

Wolfram Language & System Documentation Center

InverseZTransform[expr,z,n]

gives the inverse Z transform of expr.

InverseZTransform[expr,{z1,…,zm},{n1,…,nm}]

gives the multiple inverse Z transform of expr.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
Assumptions  
Applications  
Properties & Relations  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

InverseZTransform

InverseZTransform[expr,z,n]

gives the inverse Z transform of expr.

InverseZTransform[expr,{z1,…,zm},{n1,…,nm}]

gives the multiple inverse Z transform of expr.

Details and Options

Examples

open all close all

Basic Examples  (2)

Univariate inverse transforms:

Wolfram Language code: InverseZTransform[z / (z - a), z, n]
Wolfram Language code: InverseZTransform[z / (z ^ 2 - 3z + 1), z, n]

Multivariate inverse transforms:

Wolfram Language code: InverseZTransform[(z1 z2/(z1 - 1)^2(z2 - 1)^2), {z1, z2}, {n1, n2}]
Wolfram Language code: InverseZTransform[E ^ (1 / z1) / z2, {z1, z2}, {n1, n2}]

Scope  (4)

Constants lead to impulse sequences:

Wolfram Language code: InverseZTransform[1, z, n]

Shifted impulse sequence:

Wolfram Language code: InverseZTransform[z ^ -3, z, n]

Rational transforms yield exponential and trigonometric sequences:

Wolfram Language code: InverseZTransform[z / (z - a), z, n]
Wolfram Language code: InverseZTransform[z / (z - a) ^ 2, z, n]
Wolfram Language code: InverseZTransform[1 / ((-3 + z) (-2 + z) (-1 + z) z), z, n]

In some cases, additional simplification and transformations are needed:

Wolfram Language code: InverseZTransform[z Sin[w] / (z ^ 2 - 2z Cos[w] + 1), z, n]
Wolfram Language code: FullSimplify[%, Element[w, Reals] && Element[n, Integers]]
Wolfram Language code: InverseZTransform[(E^I z (4 - 8 E^I z + z^2 + E^2 I (4 + z^2))/(2 z + 2 E^2 I z - E^I (4 + z^2))^2), z, n]//ExpToTrig//FullSimplify

Elementary functions:

Wolfram Language code: InverseZTransform[E ^ (1 / z), z, n]
Wolfram Language code: InverseZTransform[Cos[Sqrt[1 / z]], z, n]
Wolfram Language code: InverseZTransform[Log[z / (z + 1)], z, n]
Wolfram Language code: InverseZTransform[Sqrt[1 + z ^ -2], z, n]

Special functions:

Wolfram Language code: InverseZTransform[PolyLog[-k, c / z], z, n]
Wolfram Language code: InverseZTransform[z ^ 3 BesselI[3, 2 / z], z, n]

Options  (1)

Assumptions  (1)

This transform will not evaluate without any constraints on the range of p:

Wolfram Language code: InverseZTransform[z / (z - a) ^ p, z, n]

Use Assumptions to limit the range of p:

Wolfram Language code: InverseZTransform[z / (z - a) ^ p, z, n, Assumptions -> p∈Integers && p > 0]

Applications  (3)

Solve a linear difference equation:

Wolfram Language code: ZTransform[y[n + 1] + 2y[n] == 1, n, z]

Add an initial value equation and solve the algebraic equation for the transform:

Wolfram Language code: Solve[% /. {y[0] -> 3}, ZTransform[y[n], n, z]]

Get the solution through inverse transformation:

Wolfram Language code: InverseZTransform[ZTransform[y[n], n, z] /. First[%], z, n]

Use RSolve:

Wolfram Language code: RSolve[{y[n + 1] + 2y[n] == 1, y[0] == 3}, y[n], n]

Solve a linear difference-summation equation:

Wolfram Language code: ZTransform[y[n + 1] == 2y[n] - Sum[2 ^ (n - r)y[r], {r, 0, n}], n, z]
Wolfram Language code: Solve[% /. {y[0] -> 1}, ZTransform[y[n], n, z]]

Use the inverse transform to get a solution to the original problem:

Wolfram Language code: InverseZTransform[ZTransform[y[n], n, z] /. First[%], z, n]

Use RSolve:

Wolfram Language code: RSolve[{y[n + 1] == 2y[n] - Sum[2 ^ (n - r)y[r], {r, 0, n}], y[0] == 1}, y[n], n]

A discrete system transfer function:

Wolfram Language code: h = 1 / ((z - 1 / 2)(z - 2))

Impulse response:

Wolfram Language code: u = ZTransform[DiscreteDelta[n], n, z]
Wolfram Language code: InverseZTransform[h u, z, n]

Step response:

Wolfram Language code: u = ZTransform[UnitStep[n], n, z]
Wolfram Language code: InverseZTransform[h u, z, n]

Ramp response:

Wolfram Language code: u = ZTransform[UnitStep[n]n, n, z]
Wolfram Language code: InverseZTransform[h u, z, n]

Properties & Relations  (6)

Use DiscreteAsymptotic to compute an asymptotic approximation:

Wolfram Language code: DiscreteAsymptotic[Inactive[InverseZTransform][1 / (z(-6 + 6 * z ^ 2 + z ^ 3)), z, n], n -> ∞]

ZTransform is the inverse operator:

Wolfram Language code: ZTransform[InverseZTransform[F[z], z, n], n, z]
Wolfram Language code: InverseZTransform[ZTransform[f[n], n, z], z, n]
Wolfram Language code: ZTransform[2 ^ n n, n, z]
Wolfram Language code: InverseZTransform[%, z, n]

Linearity:

Wolfram Language code: InverseZTransform[a F[z] + b G[z], z, n]

Shifting:

Wolfram Language code: InverseZTransform[z ^ (-1) ZTransform[f[n], n, z], z, n]
Wolfram Language code: InverseZTransform[z ^ (-2) ZTransform[f[n], n, z], z, n]

Derivatives:

Wolfram Language code: InverseZTransform[ D[ZTransform[f[n], n, z], z], z, n]
Wolfram Language code: InverseZTransform[ D[ZTransform[f[n], n, z], {z, 2}], z, n]

Initial value property:

Wolfram Language code: InverseZTransform[z / ((z - 1 / 2)(z - 1 / 3)), z, n]
Wolfram Language code: Limit[%, n -> 0] == Limit[z / ((z - 1 / 2)(z - 1 / 3)), z -> Infinity]

Final value property:

Wolfram Language code: InverseZTransform[z / ((z - 1 / 2)(z - 1 / 3)), z, n]
Wolfram Language code: Limit[%, n -> Infinity] == Limit[z / ((z - 1 / 2)(z - 1 / 3)), z -> 0]

InverseZTransform is closely related to SeriesCoefficient:

Wolfram Language code: InverseZTransform[E ^ (1 / z), z, n]
Wolfram Language code: SeriesCoefficient[E ^ z, {z, 0, n}]

Neat Examples  (1)

Inverse transform for a hypergeometric function:

Wolfram Language code: InverseZTransform[HypergeometricPFQ[{}, {2 / 3, 1, 4 / 3}, 1 / z], z, n]
Wolfram Language code: ZTransform[%, n, z]
Wolfram Research (1999), InverseZTransform, Wolfram Language function, https://reference.wolfram.com/language/ref/InverseZTransform.html (updated 2008).

Text

Wolfram Research (1999), InverseZTransform, Wolfram Language function, https://reference.wolfram.com/language/ref/InverseZTransform.html (updated 2008).

CMS

Wolfram Language. 1999. "InverseZTransform." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2008. https://reference.wolfram.com/language/ref/InverseZTransform.html.

APA

Wolfram Language. (1999). InverseZTransform. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/InverseZTransform.html

BibTeX

@misc{reference.wolfram_2026_inverseztransform, author="Wolfram Research", title="{InverseZTransform}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/InverseZTransform.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_inverseztransform, organization={Wolfram Research}, title={InverseZTransform}, year={2008}, url={https://reference.wolfram.com/language/ref/InverseZTransform.html}, note=[Accessed: 13-June-2026]}