WOLFRAM

Wolfram Language & System Documentation Center

JuliaSetPoints[f,z]

returns a list of coordinates approximating the real and imaginary parts of the complex numbers in the Julia set of the rational function f of the variable z.

JuliaSetPoints[c]

returns a list of coordinates of points approximating the Julia set of the function .

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
"ClosenessTolerance"  
"Bound"  
Properties & Relations  
Possible Issues  
Interactive Examples  
Neat Examples  
See Also
Related Guides
History
Cite this Page

JuliaSetPoints

JuliaSetPoints[f,z]

returns a list of coordinates approximating the real and imaginary parts of the complex numbers in the Julia set of the rational function f of the variable z.

JuliaSetPoints[c]

returns a list of coordinates of points approximating the Julia set of the function .

Details and Options

  • The Julia set of a function f is the closure of the set of all repelling fixed points of f.
  • JuliaSetPoints uses the same "InverseIteration" algorithm as JuliaSetPlot.
  • JuliaSetPoints has the options:
  • "ClosenessTolerance" 0.004minimum distance between points
    "Bound" 6radius around the origin in which to search
  • For polynomial functions, "Bound" is automatically determined to ensure the entire Julia set is captured.

Examples

open all close all

Basic Examples  (2)

Find points of the Julia set of :

Wolfram Language code: JuliaSetPoints[-0.77 + 0.22I]
Wolfram Language code: ListPlot[%]

Find points of the Julia set of :

Wolfram Language code: JuliaSetPoints[(z ^ 2 - 1) / (z ^ 2 + 1), z]
Wolfram Language code: ListPlot[%]

Scope  (2)

JuliaSetPoints[c] generates the Julia set of a function of the form :

Wolfram Language code: JuliaSetPoints[-0.77 + 0.22I]

JuliaSetPoints[f,z] generates the Julia set of polynomials or more general rational functions:

Wolfram Language code: ListPlot@JuliaSetPoints[z ^ 3 - z - 1, z]
Wolfram Language code: ListPlot@JuliaSetPoints[z ^ 2 / (z ^ 2 - 1), z]

Options  (2)

"ClosenessTolerance"  (1)

Increase "ClosenessTolerance" to make a quick, low-resolution picture of a Julia set:

Wolfram Language code: AbsoluteTiming[ListPlot[JuliaSetPoints[0.37 + 0.22I, "ClosenessTolerance" -> .05]]]
Wolfram Language code: AbsoluteTiming[ListPlot@JuliaSetPoints[0.37 + 0.22I]]

Decrease "ClosenessTolerance" to make a high-resolution picture of a small part of a Julia set:

Wolfram Language code: {ListPlot[JuliaSetPoints[-0.77 + 0.22I], PlotRange -> {{0.8, .9}, {.2, .3}}], ListPlot[JuliaSetPoints[-0.77 + 0.22 I, "ClosenessTolerance" -> .001], PlotRange -> {{0.8, .9}, {.2, .3}}]}

"Bound"  (1)

For some rational functions, increasing "Bound" can find more points:

Wolfram Language code: {ListPlot[JuliaSetPoints[(2z ^ 3 + 1) / (3z ^ 2), z], PlotRange -> {{-10, 10}, {-10, 10}}], ListPlot[JuliaSetPoints[(2z ^ 3 + 1) / (3z ^ 2), z, "Bound" -> 13], PlotRange -> {{-10, 10}, {-10, 10}}]}

Properties & Relations  (2)

JuliaSetPlot[c] generates essentially a ListPlot of the result of JuliaSetPoints[c]:

Wolfram Language code: JuliaSetPlot[-0.77 + 0.22I]
Wolfram Language code: ListPlot[JuliaSetPoints[-0.77 + 0.22I]]

JuliaSetPoints[c] is the same as JuliaSetPoints[z^2+c,z]:

Wolfram Language code: JuliaSetPoints[-.6 - .5I] === JuliaSetPoints[z ^ 2 - .6 - .5I, z]

Possible Issues  (1)

If the value of the "Bound" option is too low for a rational function, no points may be returned:

Wolfram Language code: JuliaSetPoints[(500 / z ^ 2 - 1), z]
Wolfram Language code: JuliaSetPoints[(500 / z ^ 2 - 1), z, "Bound" -> 9] //ListPlot

Some very large Julia sets can take a long time to compute with this method:

Wolfram Language code: AbsoluteTiming[JuliaSetPoints[(z ^ 2 - 5 / 19/z ^ 2 + 5 / 19), z]][[1]]

Interactive Examples  (1)

Explore the Julia sets for which the parameter c is on the unit circle:

Wolfram Language code: Animate[ListPlot@JuliaSetPoints[Exp[c Pi I], "ClosenessTolerance" -> .02], {{c, 0, "c"}, 0, 2 Pi, 2 Pi / 180}]

Neat Examples  (3)

Stack successively finer approximations to a Julia set:

Wolfram Language code: Graphics3D[ Table[{Hue[10 δ], Sphere[Append[#, -δ ^ 2 100], δ]& /@ JuliaSetPoints[0.37 + 0.22I, "ClosenessTolerance" -> δ]}, {δ, 0.1, 0.01, -0.01}]]

Add a dimension by varying a parameter:

Wolfram Language code: Graphics3D[{Specularity[White, 30], Orange, Table[Sphere[Append[#, 1.c]& /@ JuliaSetPoints[1 / (z ^ 3 - c z ^ 2 + 1), z, "ClosenessTolerance" -> 0.01], 0.01], {c, 0, 1.3, 1 / 22}]}]

Visualize the Julia sets given by points on part of the unit circle:

Wolfram Language code: Graphics[{Opacity[0.25], PointSize[0.002], Table[{Hue[ξ / 1.6], Point[JuliaSetPoints[Exp[ξ Pi I]]]}, {ξ, 0, 1, 1 / 18}]}]
Wolfram Research (2014), JuliaSetPoints, Wolfram Language function, https://reference.wolfram.com/language/ref/JuliaSetPoints.html.

Text

Wolfram Research (2014), JuliaSetPoints, Wolfram Language function, https://reference.wolfram.com/language/ref/JuliaSetPoints.html.

CMS

Wolfram Language. 2014. "JuliaSetPoints." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/JuliaSetPoints.html.

APA

Wolfram Language. (2014). JuliaSetPoints. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/JuliaSetPoints.html

BibTeX

@misc{reference.wolfram_2026_juliasetpoints, author="Wolfram Research", title="{JuliaSetPoints}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/JuliaSetPoints.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_juliasetpoints, organization={Wolfram Research}, title={JuliaSetPoints}, year={2014}, url={https://reference.wolfram.com/language/ref/JuliaSetPoints.html}, note=[Accessed: 13-June-2026]}