WOLFRAM

Wolfram Language & System Documentation Center

KroneckerSymbol[n,m]

gives the Kronecker symbol .

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Symbolic Manipulation  
Applications  
Basic Applications  
Number Theory  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

KroneckerSymbol

KroneckerSymbol[n,m]

gives the Kronecker symbol .

Details

  • KroneckerSymbol is also known as the Jacobi symbol or Legendre symbol.
  • Integer mathematical function, suitable for both symbolic and numerical manipulation.
  • KroneckerSymbol[n,1] gives 1.
  • KroneckerSymbol[n,-1] gives 1 whenever n is non-negative and otherwise.
  • For a number with a unit and primes, TemplateBox[{n, m}, KroneckerSymbol] returns TemplateBox[{n, u}, KroneckerSymbol] TemplateBox[{n, {p, _, 1}}, KroneckerSymbol] ...TemplateBox[{n, {p, _, l}}, KroneckerSymbol].

Examples

open all close all

Basic Examples  (2)

Compute Kronecker symbols:

Wolfram Language code: KroneckerSymbol[17, 6]
Wolfram Language code: Table[KroneckerSymbol[n, m], {n, 5}, {m, 5}]

Plot the KroneckerSymbol sequence with respect to the second argument:

Wolfram Language code: DiscretePlot[KroneckerSymbol[7, m], {m, 50}]

Scope  (9)

Numerical Evaluation  (3)

KroneckerSymbol works over integers:

Wolfram Language code: KroneckerSymbol[10, 13]

Compute for large arguments:

Wolfram Language code: KroneckerSymbol[10 ^ 11 + 1, Prime[2000]]

KroneckerSymbol threads elementwise over lists:

Wolfram Language code: KroneckerSymbol[{2, 3, 5, 7, 11}, 6]

Symbolic Manipulation  (6)

TraditionalForm formatting:

Wolfram Language code: KroneckerSymbol[n, m]//TraditionalForm

Reduce expressions:

Wolfram Language code: Reduce[KroneckerSymbol[p, 3] == 2 KroneckerSymbol[p + 1, 3] - 1 && -5 < p < 5, {p}, Integers]

Solve equations:

Wolfram Language code: Solve[KroneckerSymbol[n, 5] == 1 && 0 < n < 5, n, Integers]

Use KroneckerSymbol in a sum:

Wolfram Language code: Sum[KroneckerSymbol[a, 16], a]

Recurrence equation:

Wolfram Language code: DifferenceRootReduce[KroneckerSymbol[n, 7], n]

Generating function:

Wolfram Language code: GeneratingFunction[KroneckerSymbol[n, 7], n, x]

Applications  (11)

Basic Applications  (2)

Table of values of the Kronecker symbol with n, m up to 10:

Wolfram Language code: Grid[Table[If[n m == 0 , If[n + m == 0, " ", Style[n + m, Red, Italic, Bold]], KroneckerSymbol[n, m]], {n, 0, 10}, {m, 0, 10}], ...]

Plot the nontrivial values of the Kronecker symbol:

Wolfram Language code: ArrayPlot[Table[KroneckerSymbol[n, m], {n, 0, 40}, {m, 1, 2n, 2}], ColorRules -> {1 -> Red, -1 -> Blue}]

Number Theory  (9)

For congruent integers m and n modulo p, KroneckerSymbol[m,p]==KroneckerSymbol[n,p]:

Wolfram Language code: Mod[2, 7] == Mod[23, 7]
Wolfram Language code: KroneckerSymbol[2, 7] == KroneckerSymbol[23, 7]

Find Euler–Jacobi pseudoprimes to base : [more info]

Wolfram Language code: pseudoPrimeQ[n_Integer] := GCD[n, 2] === 1 && CompositeQ[n] && KroneckerSymbol[2, n] == Mod[2 ^ ((n - 1) / 2), n];
Wolfram Language code: Select[Range[10000], pseudoPrimeQ]

The law of quadratic reciprocity for distinct primes n and m :

Wolfram Language code: {n, m} = {11, 13};
Wolfram Language code: PrimeQ[{n, m}]
Wolfram Language code: KroneckerSymbol[n, m ]KroneckerSymbol[m, n] == (-1) ^ ((n - 1)(m - 1) / 4)

Construct eigenvectors of the discrete Fourier transform:

Wolfram Language code: With[{p = 13}, Table[KroneckerSymbol[k, p], {k, 0, p - 1}]]//N
Wolfram Language code: Fourier[%]

Evaluate Gauss sums in closed form:

Wolfram Language code: GaussSum[h_, p_] := KroneckerSymbol[h, p] I^((p - 1/2))^2 Sqrt[p] - 1;
Wolfram Language code: GaussSum[4, 11]

The congruence equation has a solution if KroneckerSymbol[a,p] == 1:

Wolfram Language code: KroneckerSymbol[2, 7]
Wolfram Language code: PowerMod[2, 1 / 2, 7]

KroneckerSymbol[n,k] is a real DirichletCharacter modulo k for odd integers k:

Wolfram Language code: Table[KroneckerSymbol[n, 5], {n, 0, 4}]
Wolfram Language code: Table[DirichletCharacter[5, 3, n], {n, 0, 4}]

A real primitive character χ modulo k can be written in terms of KroneckerSymbol[χ[-1]k,n]:

Wolfram Language code: Table[DirichletCharacter[7, 4, n], {n, 0, 6}]
Wolfram Language code: Table[KroneckerSymbol[DirichletCharacter[7, 4, -1] * 7, n], {n, 0, 6}]

Nonprimitive real characters can be written in terms of KroneckerSymbol at integers coprime to k:

Wolfram Language code: DirichletCharacter[12, 3, {1, 5, 7, 11}]
Wolfram Language code: KroneckerSymbol[-4, {1, 5, 7, 11}]

KroneckerSymbol is the generalization of the Jacobi symbol for all integers:

Wolfram Language code: jacobi[n_, m_] := KroneckerSymbol[n, m] /; (OddQ[m] && Positive[m]);
Wolfram Language code: Table[jacobi[2, m], {m, 1, 9}]

Properties & Relations  (5)

KroneckerSymbol gives for non-coprime integers:

Wolfram Language code: CoprimeQ[9, 12]
Wolfram Language code: KroneckerSymbol[9, 12]

KroneckerSymbol is a completely multiplicative function for each argument:

Wolfram Language code: KroneckerSymbol[3 4, 7] == KroneckerSymbol[3, 7]KroneckerSymbol[4, 7]
Wolfram Language code: KroneckerSymbol[3, 9 7] == KroneckerSymbol[3, 9]KroneckerSymbol[3, 7]

The law of quadratic reciprocity for distinct primes n and m :

Wolfram Language code: {n, m} = {11, 13};
Wolfram Language code: PrimeQ[{n, m}]
Wolfram Language code: KroneckerSymbol[n, m] KroneckerSymbol[m, n] == (-1) ^ ((n - 1)(m - 1) / 4)

Use KroneckerSymbol to compute real DirichletCharacter modulo k for odd integers k:

Wolfram Language code: Table[KroneckerSymbol[n, 5], {n, 0, 4}]
Wolfram Language code: Table[DirichletCharacter[5, 3, n], {n, 0, 4}]

Check that the following relation holds for any odd integer:

Wolfram Language code: n = 39; KroneckerSymbol[-1, n] == (-1)^(n - 1/2)

Neat Examples  (4)

The array plot of KroneckerSymbol:

Wolfram Language code: ArrayPlot[Table[KroneckerSymbol[n, m], {n, -50, 50}, {m, -50, 50}], ColorRules -> {-1 -> Black, 0 -> White, 1 -> Blue}]

Plot the arguments of the Fourier transform of KroneckerSymbol:

Wolfram Language code: ArrayPlot[Arg[Fourier[Table[KroneckerSymbol[m, n], {m, 100}, {n, 100}]]], ColorFunction -> Hue]

Successive differences of KroneckerSymbol modulo 2:

Wolfram Language code: ArrayPlot[Mod[NestList[Differences, KroneckerSymbol[Range[100], 77], 100], 2]]

Plot the Ulam spiral of KroneckerSymbol:

Wolfram Language code: ulam[n_] := Partition[Permute[Range[n ^ 2], Accumulate[Take[Flatten[{{n ^ 2 + 1} / 2, Table [(-1) ^ j i, {j, n}, {i, {-1, n}}, {j}]}], n ^ 2]]], n];
Wolfram Language code: ArrayPlot[KroneckerSymbol[70, ulam[125]], ColorFunction -> "BlueGreenYellow"]
Wolfram Research (2007), KroneckerSymbol, Wolfram Language function, https://reference.wolfram.com/language/ref/KroneckerSymbol.html.

Text

Wolfram Research (2007), KroneckerSymbol, Wolfram Language function, https://reference.wolfram.com/language/ref/KroneckerSymbol.html.

CMS

Wolfram Language. 2007. "KroneckerSymbol." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/KroneckerSymbol.html.

APA

Wolfram Language. (2007). KroneckerSymbol. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/KroneckerSymbol.html

BibTeX

@misc{reference.wolfram_2026_kroneckersymbol, author="Wolfram Research", title="{KroneckerSymbol}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/KroneckerSymbol.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_kroneckersymbol, organization={Wolfram Research}, title={KroneckerSymbol}, year={2007}, url={https://reference.wolfram.com/language/ref/KroneckerSymbol.html}, note=[Accessed: 13-June-2026]}