WOLFRAM

Wolfram Language & System Documentation Center

LatticeData[lattice,"property"]

gives the specified property for a lattice.

LatticeData[n]

gives a list of named lattices of dimension n.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Names and Classes  
Properties  
Property Values  
Generalizations & Extensions  
Applications  
Possible Issues  
See Also
Related Guides
Related Links
History
Cite this Page

LatticeData

LatticeData[lattice,"property"]

gives the specified property for a lattice.

LatticeData[n]

gives a list of named lattices of dimension n.

Details

  • Lattices can be specified by standard names such as "FaceCenteredCubic" and "CoxeterTodd".
  • LatticeData[] gives a list of classical named lattices.
  • LatticeData[patt] gives a list of all named lattices that match the string pattern patt.
  • LatticeData[{"type",id},…] gives data for the lattice of the specified type with identifier id.
  • Type-related lattices include:
  • {"BarnesWall",n} Barnes–Wall lattice BWn
    {"Bravais",{"system","centering"}}Bravais lattice for the specified crystal system
    {"CoxeterBarnes", {r, n}}Coxeter–Barnes lattice
    {"DualRootLattice",group}dual root lattice for the specified Lie group
    {"IntegerLattice",n}integer lattice
    {"KappaLattice",{m,n}}-lattice
    {"LaminatedLattice",{m,n}}laminated lattice
    {"MordellWeil",n}Mordell–Weil lattice
    {"Niemeier",n}^(th) Niemeier lattice
    {"PerfectLattice",n}perfect lattice
    {"Quebbemann",n}Quebbemann lattice
    {"RootLattice",group}root lattice for the specified Lie group
  • Crystal systems are specified by standard names such as "Trigonal", "Monoclinic", etc. Centering is "FaceCentered", "BodyCentered", or "BaseCentered".
  • Groups can be specified either for example as "A5" or {"A",5}.
  • LatticeData[group,…] is equivalent to LatticeData[{"RootLattice",group},…].
  • LatticeData["Properties"] gives a list of possible properties for lattices.
  • Lattice points properties include:
  • "Basis"basis vectors
    "Determinant"determinant of Gram matrix
    "Dimension"dimension of lattice
    "Dual"dual lattice
    "GeneratorMatrix"matrix of generators
    "Genus"genus of lattice
    "GlueVectors"glue vectors (when applicable)
    "GramMatrix"Gram matrix
    "Image"configuration of points (when applicable)
    "KissingNumber"kissing number
    "MinimalNorm"minimal norm
    "MinimalVectors"minimal vectors
    "ModularNumber"modular number
    "RadialFunction"lattice points as a function of radius ( series coefficients)
    "ThetaSeriesFunction"pure function for the theta series
  • Lattice-packing-related properties include:
  • "CenterDensity"center density
    "CoveringRadius"covering radius
    "CoxeterNumber"Coxeter number
    "Density"average sphere packing density
    "HermiteInvariant"Hermite invariant
    "PackingRadius"packing radius
    "Thickness"thickness
    "Volume"volume of the fundamental region
  • Other properties include:
  • "QuadraticForm"quadratic form
    "AutomorphismGroupOrder"order of the automorphism group
  • Naming-related properties include:
  • "AlternateNames"alternate English names
    "Name"English name
    "Notation"standard notation for display
    "StandardName"Wolfram Language name
  • LatticeData[lattice,"Classes"] gives a list of the classes in which lattice occurs.
  • LatticeData["class"] gives a list of named lattices in the specified class.
  • LatticeData[lattice,"class"] gives True or False depending on whether lattice is in the specified class.
  • Basic classes of lattices include:
  • "Even"even
    "Extremal"extremal
    "Integral"integral
    "Odd"odd lattice
    "Unimodular"unimodular
  • Negative classes of lattices include:
  • "Nonextremal"not extremal
    "Nonintegral"not integral
    "Nonunimodular"not unimodular
  • Using LatticeData may require internet connectivity.

Examples

open all close all

Basic Examples  (3)

The face-centered cubic lattice:

Wolfram Language code: LatticeData["FaceCenteredCubic", "Image"]

A basis for the face-centered cubic lattice:

Wolfram Language code: LatticeData["FaceCenteredCubic", "Basis"]

Delaunay mesh from points corresponding to minimal vectors of the hexagonal close packing lattice:

Wolfram Language code: LatticeData["HexagonalClosePacking", "MinimalVectors"]
Wolfram Language code: DelaunayMesh[%]

Scope  (24)

Names and Classes  (15)

Obtain a list of classical named lattices, including non-lattice packings:

Wolfram Language code: LatticeData[]

A lattice can be specified by its standard Wolfram Language name:

Wolfram Language code: LatticeData["SimpleCubic"]//Normal

A Barnes–Wall lattice is specified by {"BarnesWall",n}:

Wolfram Language code: LatticeData[{"BarnesWall", 32}, "Determinant"]

Bravais lattices can be specified by a crystal system with a lattice centering:

Wolfram Language code: LatticeData[{"Bravais", {"Cubic", "BodyCentered"}}, "Basis"]

The integer lattice :

Wolfram Language code: LatticeData[{"IntegerLattice", 2}, "Basis"]//Normal

Laminated lattices :

Wolfram Language code: LatticeData[{"LaminatedLattice", 31}, "Dimension"]

Mordell–Weil lattice :

Wolfram Language code: LatticeData[{"MordellWeil", 24}, "Determinant"]

The root lattices :

Wolfram Language code: LatticeData[{"RootLattice", {"A", 2}}, "KissingNumber"]

The root lattice :

Wolfram Language code: LatticeData[{"RootLattice", {"D", 4}}, "CoxeterNumber"]

The root lattice :

Wolfram Language code: LatticeData[{"RootLattice", {"E", 6}}, "PackingRadius"]

Short string forms can be used for root lattices:

Wolfram Language code: LatticeData["A2", "KissingNumber"]
Wolfram Language code: LatticeData["D(4)", "CoxeterNumber"]

Find the English name of a lattice:

Wolfram Language code: LatticeData[{"IntegerLattice", 5}, "Name"]

A list of alternate names can also be found:

Wolfram Language code: LatticeData["CoxeterTodd", "AlternateNames"]

Find the list of classes:

Wolfram Language code: LatticeData["Classes"]

Find the list of named lattices belonging to a class:

Wolfram Language code: LatticeData["Integral"]
Wolfram Language code: LatticeData["Even"]

Test whether a lattice belongs to a class:

Wolfram Language code: LatticeData["Leech", "Odd"]

Get a list of classes in which a lattice belongs:

Wolfram Language code: LatticeData["BodyCenteredCubic", "Classes"]

A list of lattices that are even and integral:

Wolfram Language code: LatticeData[{"Even", "Integral"}]

Properties  (4)

Get a list of possible properties:

Wolfram Language code: LatticeData["Properties"]
Wolfram Language code: Length[%]

Get a list of available properties for a particular lattice:

Wolfram Language code: LatticeData["Leech", "Properties"]

Certain 3-dimensional lattices have images:

Wolfram Language code: LatticeData["BodyCenteredCubic", "Image"]

Get notation forms:

Wolfram Language code: LatticeData[{"IntegerLattice", 5}, "Notation"]

Property Values  (5)

A property value can be any valid Wolfram Language expression:

Wolfram Language code: LatticeData["FaceCenteredCubic", "Basis"]
Wolfram Language code: LatticeData["CoxeterTodd", "Notation"]
Wolfram Language code: LatticeData["Leech", "Integral"]

For the property "ThetaSeriesFunction", lattice data is given as pure functions:

Wolfram Language code: LatticeData["CoxeterTodd", "ThetaSeriesFunction"]

A property that is not applicable to a lattice has the value Missing["NotApplicable"]:

Wolfram Language code: LatticeData[{"IntegerLattice", 5}, "Image"]

A property that is not available for a lattice has the value Missing["NotAvailable"]:

Wolfram Language code: LatticeData["KorkineZolotarev", "ThetaSeriesFunction"]

Specify a list of properties for a lattice:

Wolfram Language code: LatticeData["CoxeterTodd", {"Dimension", "Determinant"}]

Generalizations & Extensions  (1)

LatticeData works on nonlattice structures such as tetrahedral packings:

Wolfram Language code: LatticeData["TetrahedralPacking", "Image"]
Wolfram Language code: LatticeData["HexagonalClosePacking", "KissingNumber"]

Applications  (3)

Number of lattice points in the unit sphere:

Wolfram Language code: LatticeData["FaceCenteredCubic", "RadialFunction"][1]

The number of lattice points on the sphere as a function of radius:

Wolfram Language code: ListPlot[LatticeData["FaceCenteredCubic", "RadialFunction"] /@ Range[30], Filling -> Axis]

The number of lattice points in the ball as a function of radius:

Wolfram Language code: ListPlot[Accumulate[LatticeData["FaceCenteredCubic", "RadialFunction"] /@ Range[30]], Filling -> Axis]

Given a 2D lattice basis:

Wolfram Language code: b = Normal@LatticeData["A2", "Basis"]

Generate and display some of the elements in the lattice:

Wolfram Language code: l1 = Flatten[Table[i b[[1]] + j b[[2]], {i, 0, 3}, {j, 0, 3}], 1]
Wolfram Language code: l2 = Tuples[Range[0, 3], 2].b
Wolfram Language code: {Graphics[Point[l1], Frame -> True, AspectRatio -> 1], Graphics[Point[l2], Frame -> True, AspectRatio -> 1]}

Given a 3D lattice basis:

Wolfram Language code: b = Normal@LatticeData["FaceCenteredCubic", "Basis"]

Generate and display some of the elements in the lattice:

Wolfram Language code: l1 = Flatten[Table[i b[[1]] + j b[[2]] + k b[[3]], {i, 0, 5}, {j, 0, 5}, {k, 0, 5}], 2];
Wolfram Language code: l2 = Tuples[Range[0, 5], 3].b;
Wolfram Language code: {Graphics3D[Map[Sphere[#, .2]&, l1], Boxed -> True, Axes -> True], Graphics3D[Map[Sphere[#, .2]&, l2], Boxed -> True, Axes -> True]}

Possible Issues  (2)

The generator matrix of a lattice may be given as a SparseArray:

Wolfram Language code: LatticeData[{"RootLattice", {"D", 4}}, "GeneratorMatrix"]

Use Normal to convert to a matrix expression:

Wolfram Language code: Normal[%]

Extra coordinates may be used to describe an n-dimensional lattice:

Wolfram Language code: Dimensions @ LatticeData[{"RootLattice", {"E", 6}}, "GeneratorMatrix"]
Wolfram Language code: LatticeData[{"RootLattice", {"E", 6}}, "Dimension"]
Wolfram Research (2007), LatticeData, Wolfram Language function, https://reference.wolfram.com/language/ref/LatticeData.html.

Text

Wolfram Research (2007), LatticeData, Wolfram Language function, https://reference.wolfram.com/language/ref/LatticeData.html.

CMS

Wolfram Language. 2007. "LatticeData." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/LatticeData.html.

APA

Wolfram Language. (2007). LatticeData. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/LatticeData.html

BibTeX

@misc{reference.wolfram_2026_latticedata, author="Wolfram Research", title="{LatticeData}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/LatticeData.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_latticedata, organization={Wolfram Research}, title={LatticeData}, year={2007}, url={https://reference.wolfram.com/language/ref/LatticeData.html}, note=[Accessed: 13-June-2026]}