WOLFRAM

Wolfram Language & System Documentation Center

LatticeReduce[{v1,v2,…}]

gives a reduced basis for the set of vectors vi.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Applications  
Properties & Relations  
Possible Issues  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

LatticeReduce

LatticeReduce[{v1,v2,…}]

gives a reduced basis for the set of vectors vi.

Details

  • The elements of the vi can be integers, Gaussian integers, or Gaussian rational numbers.

Examples

open all close all

Basic Examples  (1)

Find the reduced norm basis for a lattice:

Wolfram Language code: LatticeReduce[{{1, 0, 0, 1345}, {0, 1, 0, 35}, {0, 0, 1, 154}}]

Applications  (3)

Starting with trivial integer linear relationships, LatticeReduce can produce more interesting ones:

Find integer linear relationships for and of the form :

Wolfram Language code: a = {{1, 0, 0, -1}, {0, 1, 0, -2}, {0, 0, 1, -3}};
Wolfram Language code: a.{1, 2, 3, 1}

LatticeReduce preserves linear relationships, and the third row provides , , and :

Wolfram Language code: b = LatticeReduce[a]
Wolfram Language code: b.{1, 2, 3, 1}

Find polynomial relationships for :

Wolfram Language code: {a0, a1, a2, a3, a4} = Table[Round[10 ^ 7Power[3, 1 / 3] ^ i], {i, 0, 4}]

The trivial initial relationships:

Wolfram Language code: a = {{1, 0, 0, 0, -a0}, {0, 1, 0, 0, -a1}, {0, 0, 1, 0, -a2}, {0, 0, 0, 1, -a3}, {0, 0, 0, 0, -a4}};

The reduced relationships:

Wolfram Language code: b = LatticeReduce[a]

The first relationship:

Wolfram Language code: b[[1]].t^Range[0, 4]
Wolfram Language code: % /. t -> Power[3, 1 / 3]//FullSimplify

Find linear relationships x0+x1 ArcTan[1]+x2 ArcTan[1/5]+x3 ArcTan[1/239]==0:

Wolfram Language code: v = {1, ArcTan[1], ArcTan[1 / 5], ArcTan[1 / 239], 1};
Wolfram Language code: {a0, a1, a2, a3, a4} = Round[10 ^ 20 v]

Initial trivial relationships:

Wolfram Language code: a = {{1, 0, 0, 0, -a0}, {0, 1, 0, 0, -a1}, {0, 0, 1, 0, -a2}, {0, 0, 0, 1, -a3}}

Reduced relationships:

Wolfram Language code: b = LatticeReduce[a]

The first relationship:

Wolfram Language code: b[[1]].v
Wolfram Language code: N[%]

Properties & Relations  (2)

LatticeReduce produces a new reduced basis for the same lattice:

Wolfram Language code: a = RandomInteger[10, {3, 3}]
Wolfram Language code: b = LatticeReduce[a]

The product of the norms will decrease:

Wolfram Language code: Times@@(Norm /@ a) ≥ Times@@(Norm /@ b)

The determinant or volume of the generator cell is preserved:

Wolfram Language code: Abs[Det[a]] == Abs[Det[b]]

The lattice is generated by {v1,v2}, but also by {w1,w2} produced by LatticeReduce:

Wolfram Language code: v1 = {12, 2}; v2 = {13, 4};
Wolfram Language code: {w1, w2} = LatticeReduce[{v1, v2}]

The original cell is pink, and the one produced by LatticeReduce is cyan:

Wolfram Language code: lattice = Select[Flatten[Table[n1 v1 + n2 v2, {n1, -5, 5}, {n2, -5, 5}], 1], 0 <= #[[1]] ≤ 25 && -4 <= #[[2]] ≤ 8&];
Wolfram Language code: Graphics[{{Opacity[0.8], Pink, Tooltip[Polygon[{{0, 0}, v1, v1 + v2, v2}], "v-cell"]}, {Opacity[0.8], Cyan, Tooltip[Polygon[{{0, 0}, w2, w2 + w1, w1}], "w-cell"]}, Point[lattice], {Red, Arrow[{{0, 0}, v1}]}, {Green, Arrow[{{0, 0}, v2}]}, {Blue, Arrow[{{0, 0}, w1}]}, {Yellow, Arrow[{{0, 0}, w2}]}}, Axes -> True]

Possible Issues  (1)

The set of vectors must have rational or Gaussian rational coefficients:

Wolfram Language code: LatticeReduce[{{1, 2}, {3, 4.5}}]
Wolfram Research (1988), LatticeReduce, Wolfram Language function, https://reference.wolfram.com/language/ref/LatticeReduce.html.

Text

Wolfram Research (1988), LatticeReduce, Wolfram Language function, https://reference.wolfram.com/language/ref/LatticeReduce.html.

CMS

Wolfram Language. 1988. "LatticeReduce." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/LatticeReduce.html.

APA

Wolfram Language. (1988). LatticeReduce. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/LatticeReduce.html

BibTeX

@misc{reference.wolfram_2026_latticereduce, author="Wolfram Research", title="{LatticeReduce}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/LatticeReduce.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_latticereduce, organization={Wolfram Research}, title={LatticeReduce}, year={1988}, url={https://reference.wolfram.com/language/ref/LatticeReduce.html}, note=[Accessed: 12-June-2026]}