WOLFRAM

Wolfram Language & System Documentation Center

Lighter[color]

represents a lighter version of the specified color.

Lighter[color,f]

represents a version of the specified color lightened by a fraction f.

Lighter[image,…]

gives a lighter version of an image.

Lighter[video,…]

gives a version of a video with lighter frames.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Data  
Parameters  
Applications  
Properties & Relations  
Possible Issues  
Interactive Examples  
Neat Examples  
See Also
Related Guides
History
Cite this Page

Lighter

Lighter[color]

represents a lighter version of the specified color.

Lighter[color,f]

represents a version of the specified color lightened by a fraction f.

Lighter[image,…]

gives a lighter version of an image.

Lighter[video,…]

gives a version of a video with lighter frames.

Details

  • Lighter can be used to create a lighter version of a color or an image.
  • Lighter[color,1] gives white. »
  • Lighter[color,0] gives color. »
  • Lighter[color] is equivalent to Lighter[color,1/3]. »
  • Lighter[color,f] for values of f outside the range 0 to 1 are clipped.
  • Lighter[image] works with 2D as well as 3D images.
  • Lighter[{col1,col2,…},…] gives lighter versions of each of the coli. »
  • When applied to color, Lighter always returns an RGBColor.
  • When applied to color images, Lighter always returns an RGB image.
  • Lighter does not affect the opacity of a color or an image. »

Examples

open all close all

Basic Examples  (3)

Lighter version of colors:

Wolfram Language code: Graphics[{Lighter[Red], Disk[]}]
Wolfram Language code: Graphics3D[{Lighter[Green], Sphere[]}]

Specify how much the color should be lightened by using a fraction:

Wolfram Language code: Graphics[{Lighter[Blue, #], Disk[]}]& /@ {.1, .5, .8}

Lighter version of an image:

Wolfram Language code: Lighter[[image]]

Scope  (9)

Data  (6)

Lighter version of a color:

Wolfram Language code: Lighter[RGBColor[1, 0, 0]]

Lighter version of a 2D grayscale image:

Wolfram Language code: Lighter[[image]]

Lighter version of an image:

Wolfram Language code: Lighter[[image]]

Lighter video:

Wolfram Language code: Lighter[\!\(\*VideoBox["![Video Player: ExampleData/fish.mp4](video://content-83a60)"]\)]

Lighter version of a 3D image:

Wolfram Language code: Lighter[[image]]

Lighter automatically threads over colors:

Wolfram Language code: Lighter[{Red, Green, Blue}, 1 / 2]

Parameters  (3)

The default lightening fraction is :

Wolfram Language code: Lighter[Red] == Lighter[Red, 1 / 3]
Wolfram Language code: {Graphics[{Lighter[Red], Disk[]}], Graphics[{Lighter[Red, 1 / 3], Disk[]}]}

Specify different darkening fractions:

Wolfram Language code: Table[Graphics[{Lighter[Red, i], Disk[]}], {i, {0.2, 0.4, 0.6, 0.8}}]

With a lightening fraction of zero, the color is unchanged:

Wolfram Language code: Lighter[Blue, 0] == Blue
Wolfram Language code: {Graphics[{Lighter[Blue, 0], Disk[]}], Graphics[{Blue, Disk[]}]}

With a lightening fraction of one, the color becomes white:

Wolfram Language code: Lighter[RGBColor[0, 0, 1], 1] == RGBColor[1, 1, 1]
Wolfram Language code: {Graphics[{Lighter[Blue, 1], Disk[]}, Background -> Black], Graphics[{White, Disk[]}, Background -> Black]}

Applications  (4)

Use Lighter to construct ColorFunction for plots:

Wolfram Language code: Plot3D[y Sin[x ^ 2 + y ^ 2], {x, -3, 3}, {y, -3, 3}, ColorFunction -> (Lighter[Orange, #3]&), Mesh -> None, PlotPoints -> 40]
Wolfram Language code: DensityPlot[Sin[x]Sin[y], {x, -4, 4}, {y, -4, 4}, ColorFunction -> (Lighter[Orange, #]&)]

Use Darker and Lighter values of a particular hue as a color function:

Wolfram Language code: ContourPlot[Sin[x]Sin[y], {x, 0, 2Pi}, {y, 0, 2Pi}, ColorFunction -> (If[# < 0, Darker[Blue, Abs[#]], Lighter[Red, #]]&), ColorFunctionScaling -> False]

Make a dark, starry sky brighter:

Wolfram Language code: Lighter[[image], 1]

Enhance a dark region of an image:

Wolfram Language code: i = [image];
Wolfram Language code: mask = ColorNegate@Binarize[i, .1]
Wolfram Language code: ImageCompose[i, SetAlphaChannel[ Lighter[i, 1], mask]]

Properties & Relations  (5)

Lighter of a color is always returned as an RGBColor:

Wolfram Language code: Lighter[CMYKColor[0, 1, 1, 0]]
Wolfram Language code: %//InputForm

The opacity value is unaffected by Lighter:

Wolfram Language code: Lighter[RGBColor[1, 0, 0, .4]]

Lighter is a special case of Blend:

Wolfram Language code: {Lighter[Blue, 1 / 3], Blend[{Blue, White}, 1 / 3]}

Lighter and Darker are not commutative:

Wolfram Language code: Darker[Lighter[Red, .5], .5]
Wolfram Language code: Lighter[Darker[Red, .5], .5]

Lighter for images is a special case of ImageAdjust:

Wolfram Language code: {Lighter[[image], 0.5], ImageAdjust[[image], {0, 0.5}]}

Possible Issues  (3)

Values outside of the 0–1 range will be clipped:

Wolfram Language code: Graphics[Table[{Lighter[Blue, i], EdgeForm[Opacity[.1]], Disk[{5i, 0}]}, {i, 0 - 1 / 4, 1 + 1 / 4, 1 / 4}]]

Some colors may look faded during the lightening:

Wolfram Language code: Graphics[Table[{Lighter[Brown, i], EdgeForm[Opacity[.1]], Disk[{7i, 0}]}, {i, 0, 1, 1 / 6}]]

Lighter behaves differently when applied to a color and an image pixel of the same color:

Wolfram Language code: {Graphics[{RGBColor[1, 0.5, 0], Rectangle[]}, ImageSize -> 100], Image[{{RGBColor[1, 0.5, 0]}}, ImageSize -> 100]}
Wolfram Language code: {Graphics[{Lighter[RGBColor[1, 0.5, 0]], Rectangle[]}, ImageSize -> 100], Lighter[Image[{{RGBColor[1, 0.5, 0]}}, ImageSize -> 100]]}

Interactive Examples  (1)

Observe the changing chromaticity of a color image as the image is made lighter:

Wolfram Language code: Manipulate[ChromaticityPlot3D[Lighter[[image], f]], {f, 0, 1}]

Neat Examples  (1)

Tilted bumpy texture:

Wolfram Language code: ArrayPlot[Table[Evaluate[Sum[Sin[RandomReal[7, 2].{x, y}], {10}]], {x, 0, 10, .05}, {y, 0, 10, .05}], ColorFunction -> (Lighter[Blue, #]&)]
Wolfram Research (2007), Lighter, Wolfram Language function, https://reference.wolfram.com/language/ref/Lighter.html (updated 2021).

Text

Wolfram Research (2007), Lighter, Wolfram Language function, https://reference.wolfram.com/language/ref/Lighter.html (updated 2021).

CMS

Wolfram Language. 2007. "Lighter." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/Lighter.html.

APA

Wolfram Language. (2007). Lighter. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Lighter.html

BibTeX

@misc{reference.wolfram_2026_lighter, author="Wolfram Research", title="{Lighter}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/Lighter.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_lighter, organization={Wolfram Research}, title={Lighter}, year={2021}, url={https://reference.wolfram.com/language/ref/Lighter.html}, note=[Accessed: 12-June-2026]}