WOLFRAM

Wolfram Language & System Documentation Center

LogIntegral[z]

is the logarithmic integral function TemplateBox[{z}, LogIntegral].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Show More Show More
Function Properties  
Differentiation  
Integration  
Series Expansions  
Function Identities and Simplifications  
Function Representations  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

LogIntegral

LogIntegral[z]

is the logarithmic integral function TemplateBox[{z}, LogIntegral].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • The logarithmic integral function is defined by TemplateBox[{z}, LogIntegral]=int_0^zdt/log t , where the principal value of the integral is taken.
  • LogIntegral[z] has a branch cut discontinuity in the complex z plane running from to .
  • For certain special arguments, LogIntegral automatically evaluates to exact values.
  • LogIntegral can be evaluated to arbitrary numerical precision.
  • LogIntegral automatically threads over lists.
  • LogIntegral can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples  (5)

Evaluate numerically:

Wolfram Language code: LogIntegral[20.]

Plot over a subset of the reals:

Wolfram Language code: Plot[LogIntegral[x], {x, 0, 10}]

Series expansion at the origin:

Wolfram Language code: Series[LogIntegral[x], {x, 0, 2}, Assumptions -> x > 0]

Series expansions around the branch point at :

Wolfram Language code: Series[LogIntegral[x], {x, 1, 1}, Assumptions -> x > 0]

Series expansion at Infinity:

Wolfram Language code: Series[LogIntegral[x], {x, ∞, 1}, Assumptions -> x > 0]

Scope  (32)

Numerical Evaluation  (5)

Evaluate numerically to high precision:

Wolfram Language code: N[LogIntegral[2], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: LogIntegral[2.0000000000000000000000]

LogIntegral can take complex number inputs:

Wolfram Language code: LogIntegral[2. + I]

Evaluate LogIntegral efficiently at high precision:

Wolfram Language code: LogIntegral[2`500]//Timing
Wolfram Language code: LogIntegral[2`10000];//Timing

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: LogIntegral[Interval[{1.49, 1.51}]]
Wolfram Language code: LogIntegral[CenteredInterval[2, 1 / 10]]

Or compute average-case statistical intervals using Around:

Wolfram Language code: LogIntegral[ Around[2, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: LogIntegral[{{0, 1}, {1.2, 0}}]

Or compute the matrix LogIntegral function using MatrixFunction:

Wolfram Language code: MatrixFunction[LogIntegral, {{0, 1}, {1.2, 0}}]

Specific Values  (4)

Value at the origin:

Wolfram Language code: LogIntegral[0]

Singular point of LogIntegral:

Wolfram Language code: LogIntegral[1]

Values at infinity:

Wolfram Language code: LogIntegral[Infinity]

Find a zero of TemplateBox[{x}, LogIntegral]:

Wolfram Language code: xzero = Solve[LogIntegral[x] == 0 && 1.1 < x < 2, x][[1, 1, 2]]//Quiet
Wolfram Language code: Plot[LogIntegral[x], {x, 0, 5}, Epilog -> Style[Point[{xzero, LogIntegral[xzero]}], PointSize[Large], Red]]

Visualization  (2)

Plot the LogIntegral function:

Wolfram Language code: Plot[LogIntegral[x], {x, 0, 5}]

Plot the real part of TemplateBox[{z}, LogIntegral]:

Wolfram Language code: ComplexContourPlot[Re[LogIntegral[z]], {z, -4 - 4I, 4 + 4 I}, Contours -> 20]

Plot the imaginary part of TemplateBox[{z}, LogIntegral]:

Wolfram Language code: ComplexContourPlot[Im[LogIntegral[z]], {z, -4 - 4I, 4 + 4 I}, Contours -> 20]

Function Properties  (8)

LogIntegral is defined for all real positive values except 1:

Wolfram Language code: FunctionDomain[LogIntegral[x], x]

Complex domain:

Wolfram Language code: FunctionDomain[LogIntegral[z], z, Complexes]

LogIntegral takes all real values:

Wolfram Language code: FunctionRange[LogIntegral[x], x, y]//Quiet

LogIntegral is not an analytic function:

Wolfram Language code: FunctionAnalytic[LogIntegral[x], x]

Has both singularities and discontinuities:

Wolfram Language code: FunctionSingularities[LogIntegral[x], x]
Wolfram Language code: FunctionDiscontinuities[LogIntegral[x], x]

LogIntegral is neither nondecreasing nor nonincreasing:

Wolfram Language code: FunctionMonotonicity[{LogIntegral[x], x ≥ 0 && x ≠ 1}, x]

LogIntegral is not injective:

Wolfram Language code: FunctionInjective[LogIntegral[x], x]
Wolfram Language code: Plot[{LogIntegral[x], -1}, {x, 0, 7}]

LogIntegral is surjective:

Wolfram Language code: FunctionSurjective[LogIntegral[x], x]
Wolfram Language code: Limit[LogIntegral[x], x -> 1, Direction -> "FromAbove"]
Wolfram Language code: Limit[LogIntegral[x], x -> Infinity]
Wolfram Language code: Plot[{LogIntegral[x], 10}, {x, 0, 25}]

LogIntegral is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[{LogIntegral[x], x ≥ 0 && x ≠ 1}, x]

LogIntegral is neither convex nor concave:

Wolfram Language code: FunctionConvexity[{LogIntegral[x], x ≥ 0 && x ≠ 1}, x]

Differentiation  (2)

First derivative:

Wolfram Language code: D[LogIntegral[x], x]

Higher derivatives:

Wolfram Language code: Table[D[LogIntegral[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, 0, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

Integration  (3)

Indefinite integral of LogIntegral:

Wolfram Language code: Integrate[LogIntegral[x], x]

Definite integral of LogIntegral:

Wolfram Language code: Integrate[LogIntegral[x], {x, 0, 1}]

More integrals:

Wolfram Language code: Integrate[LogIntegral[z^β], z]
Wolfram Language code: Integrate[Log[a z] LogIntegral[b z], z]

Series Expansions  (3)

Taylor expansion for LogIntegral:

Wolfram Language code: Series[LogIntegral[x], {x, 2, 3}]

Plot the first three approximations for LogIntegral around :

Wolfram Language code: terms = Normal@Table[Series[LogIntegral[x], {x, 2, m}], {m, 1, 3}]; Plot[{LogIntegral[x], terms}, {x, 1, 3}]

Series expansions on either side of the branch point at :

Wolfram Language code: Series[LogIntegral[x], {x, 1, 5}, Assumptions -> x > 1]
Wolfram Language code: Series[LogIntegral[x], {x, 1, 5}, Assumptions -> x < 1]

LogIntegral can be applied to power series:

Wolfram Language code: LogIntegral[2 + x + (x^2/2) + O[x]^3]

Function Identities and Simplifications  (2)

Primary definition of LogIntegral:

Wolfram Language code: Integrate[1 / Log[t], {t, 0, x}, Assumptions -> 0 ≤ x < 1]

Use FullSimplify to simplify expressions into logarithmic integrals:

Wolfram Language code: CosIntegral[I Log[z]] - I SinIntegral[I Log[z]] - (1/2)(Log[(1/Log[z])] - Log[Log[z]]) - Log[I Log[z]]//FullSimplify
Wolfram Language code: -Gamma[0, -Log[z]] + (1/2)(Log[Log[z]] - Log[(1/Log[z])]) - Log[-Log[z]]//FullSimplify

Function Representations  (3)

Representation through ExpIntegralEi:

Wolfram Language code: FullSimplify[ExpIntegralEi[Log[z]]]

Series representation:

Wolfram Language code: EulerGamma + (1/2)(Log[Log[z]] - Log[(1/Log[z])]) + Underoverscript[∑, k = 1, ∞](Log[z]^k/k k!)//FullSimplify

TraditionalForm formatting:

Wolfram Language code: LogIntegral[x]//TraditionalForm

Applications  (5)

Approximate number of primes less than :

Wolfram Language code: Integrate[1 / Log[t], {t, 2, x}, Assumptions -> x > 2]

Compare with exact counts:

Wolfram Language code: Plot[{%, PrimePi[x]}, {x, 2, 100}]

Plot the real part in the complex plane:

Wolfram Language code: Plot3D[Im[LogIntegral[x + I y]], {x, -5, 5}, {y, -5, 5}]

Plot the absolute value in the complex plane:

Wolfram Language code: ContourPlot[Abs[LogIntegral[x + I y]], {x, -5, 5}, {y, -5, 5}]

Find an approximation to Soldner's constant [more info]:

Wolfram Language code: FindRoot[LogIntegral[x] == 0, {x, 2}, WorkingPrecision -> 50]

TemplateBox[{{TemplateBox[{x}, PrimePi], -, TemplateBox[{x}, LogIntegral]}}, Abs]<(sqrt(x) log(x))/(8 pi) for if the Riemann hypothesis is true. Verify it via LogIntegral:

Wolfram Language code: Plot[{Abs[PrimePi[x] - LogIntegral[x]], Sqrt[x]Log[x] / (8 * Pi)}, {x, 2657, 3000}, PlotLegends -> "Expressions"]

Properties & Relations  (4)

Use FullSimplify to simplify expressions into logarithmic integrals:

Wolfram Language code: FullSimplify[ExpIntegralEi[Log[z]]]

Use FunctionExpand to write expressions in logarithmic integrals when possible:

Wolfram Language code: FunctionExpand[HypergeometricPFQ[{1, 1}, {2, 2}, Log[z]]]

Find the numerical root:

Wolfram Language code: FindRoot[LogIntegral[z] == 1, {z, 2}]

Obtain LogIntegral from integrals and sums:

Wolfram Language code: Integrate[1 / Log[z], z]
Wolfram Language code: Underoverscript[∑, k = 1, ∞](Log[z]^k/k k!)//FunctionExpand

Possible Issues  (1)

In traditional form, parentheses are needed around the argument:

Wolfram Language code: li x
Wolfram Language code: li(x)

Neat Examples  (2)

Nested integrals:

Wolfram Language code: NestList[Integrate[#, x]&, LogIntegral[x], 3]//TraditionalForm

Plot the Riemann surface of LogIntegral:

Wolfram Language code: ParametricPlot3D[Evaluate[Table[{1 + r Cos[ϕ], r Sin[ϕ], Im[LogIntegral[1 + r Exp[I ϕ]] + j 2I π]}, {j, -1, 1}]], {r, 1*^-6, 1}, {ϕ, -π, π}, Mesh -> False, PlotStyle -> Opacity[0.8], BoxRatios -> {1, 1, 1.5}]
Wolfram Research (1988), LogIntegral, Wolfram Language function, https://reference.wolfram.com/language/ref/LogIntegral.html (updated 2022).

Text

Wolfram Research (1988), LogIntegral, Wolfram Language function, https://reference.wolfram.com/language/ref/LogIntegral.html (updated 2022).

CMS

Wolfram Language. 1988. "LogIntegral." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/LogIntegral.html.

APA

Wolfram Language. (1988). LogIntegral. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/LogIntegral.html

BibTeX

@misc{reference.wolfram_2026_logintegral, author="Wolfram Research", title="{LogIntegral}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/LogIntegral.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_logintegral, organization={Wolfram Research}, title={LogIntegral}, year={2022}, url={https://reference.wolfram.com/language/ref/LogIntegral.html}, note=[Accessed: 13-June-2026]}