Wolfram Language & System Documentation Center

ExpIntegralE

ExpIntegralE[n,z]

gives the exponential integral function .

Details

Mathematical function, suitable for both symbolic and numerical manipulation.
$TemplateBox[{n, z}, ExpIntegralE]=int_1^inftye^(-z t)/t^ndt$ where the integral converges.
ExpIntegralE[n,z] has a branch cut discontinuity in the complex z plane running from to 0.
For certain special arguments, ExpIntegralE automatically evaluates to exact values.
ExpIntegralE can be evaluated to arbitrary numerical precision.
ExpIntegralE automatically threads over lists.
ExpIntegralE can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples (5)

Evaluate numerically:

Wolfram Language code: ExpIntegralE[3, 5.5]

Plot over a subset of the reals for integer values of the parameter :

Wolfram Language code: Plot[Table[ExpIntegralE[n, x], {n, 6}]//Evaluate, {x, 0, 1}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[ExpIntegralE[2, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series for generic and logarithmic cases at the origin:

Wolfram Language code: Series[ExpIntegralE[n, x], {x, 0, 4}]

Wolfram Language code: Series[ExpIntegralE[1, x], {x, 0, 4}]

Series expansion at Infinity:

Wolfram Language code: Series[ExpIntegralE[n, x], {x, ∞, 4}]//Normal

Scope (42)

Numerical Evaluation (5)

Evaluate numerically to high precision:

Wolfram Language code: N[ExpIntegralE[3, 22 / 10], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: ExpIntegralE[3, 2.20000000000000000000000]

Complex arguments:

Wolfram Language code: N[ExpIntegralE[1 + I, 2 + 3I]]

Evaluate ExpIntegralE efficiently at high precision:

Wolfram Language code: ExpIntegralE[3, 2.2`500]//Timing

Wolfram Language code: ExpIntegralE[3, 2.2`10000];//Timing

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: ExpIntegralE[2, Interval[{0.1, 0.2}]]

Wolfram Language code: ExpIntegralE[2, CenteredInterval[1, 1 / 100]]

Or compute average-case statistical intervals using Around:

Wolfram Language code: ExpIntegralE[2, Around[2, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: ExpIntegralE[2, {{I π, I π / 2}, {0, -I }}]//FunctionExpand

Or compute the matrix ExpIntegralE function using MatrixFunction:

Wolfram Language code: MatrixFunction[ExpIntegralE[2, #]&, {{I π, I π / 2}, {0, I}}]//FunctionExpand

Specific Values (3)

Values at fixed points:

Wolfram Language code: Table[ExpIntegralE[n, 0], {n, 1, 5}]

Wolfram Language code: ExpIntegralE[0, z]

Limiting value at infinity:

Wolfram Language code: Limit[ExpIntegralE[n, x], x -> Infinity]

Find a real root of the equation :

Wolfram Language code: f[x_] := ExpIntegralE[0, x] - 0.5;

Wolfram Language code: xzero = Solve[f[x] == 0 && 0 < x < 2, x][[1, 1, 2]]//Quiet

Wolfram Language code: Plot[f[x], {x, 0, 6}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

Visualization (3)

Plot the ExpIntegralE function:

Wolfram Language code:

Plot[{ExpIntegralE[-2, x], ExpIntegralE[-3 / 2, x], ExpIntegralE[-1, x], ExpIntegralE[-1 / 2, x], ExpIntegralE[0, x], ExpIntegralE[1 / 2, x], ExpIntegralE[1, x], ExpIntegralE[3 / 2, x], ExpIntegralE[2, x]}, {x, -2, 2}]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[ExpIntegralE[1, z]], {z, -4 - 5I, 4 + 5 I}, Contours -> 20]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[ExpIntegralE[1, z]], {z, -4 - 5I, 4 + 5 I}, Contours -> 20]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[ExpIntegralE[-7 / 2, z]], {z, -4 - 5I, 4 + 5 I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[ExpIntegralE[-7 / 2, z]], {z, -4 - 5I, 4 + 5 I}, IconizedObject[«PlotOptions»]]

Function Properties (9)

Real domain of ExpIntegralE:

Wolfram Language code: FunctionDomain[ExpIntegralE[n, x], x]

Complex domain of ExpIntegralE:

Wolfram Language code: FunctionDomain[ExpIntegralE[n, z], z, Complexes]

achieves all real values for :

Wolfram Language code: Table[Reduce[FunctionRange[ExpIntegralE[n, x], x, y], y, Reals], {n, 4}]

The function range of ExpIntegralE for smaller values of may or may not be more restricted:

Wolfram Language code: FunctionRange[ExpIntegralE[0, x], x, y]

Wolfram Language code: FunctionRange[ExpIntegralE[-3, x], x, y]

ExpIntegralE has the mirror property :

Wolfram Language code: FullSimplify[ExpIntegralE[0, Conjugate[z]] == Conjugate[ExpIntegralE[0, z]]]

ExpIntegralE is not an analytic function:

Wolfram Language code: FunctionAnalytic[ExpIntegralE[n, x], {n, x}]

Nor is it meromorphic:

Wolfram Language code: FunctionMeromorphic[ExpIntegralE[n, x], x]//Reduce

is always nonincreasing for :

Wolfram Language code: FunctionMonotonicity[{ExpIntegralE[n, x], x > 0}, x, Assumptions -> n > 0]

is injective for :

Wolfram Language code: FunctionInjective[ExpIntegralE[n, x], x, Assumptions -> n ≥ 2]

It may or may not be injective for smaller values of :

Wolfram Language code: FunctionInjective[ExpIntegralE[1 / 2, x], x]

Wolfram Language code: FunctionInjective[ExpIntegralE[-1, x], x]

Visualize three examples:

Wolfram Language code: Plot[{ExpIntegralE[2, x], ExpIntegralE[1 / 2, x], ExpIntegralE[-1, x], 1 / 2}, {x, -2, 2}]

is positive on :

Wolfram Language code: FunctionSign[{ExpIntegralE[n, x], x > 0}, x, Assumptions -> n∈Reals, StrictInequalities -> True]

ExpIntegralE has both singularity and discontinuity for x≤0:

Wolfram Language code: FunctionSingularities[ExpIntegralE[2, x], x]

Wolfram Language code: FunctionDiscontinuities[ExpIntegralE[2, x], x]

is convex on :

Wolfram Language code: FunctionConvexity[{ExpIntegralE[n, x], x > 0}, x, Assumptions -> n∈Reals]

Differentiation (3)

First derivative:

Wolfram Language code: D[ExpIntegralE[n, x], x]

Higher derivatives:

Wolfram Language code: derivs = Table[D[ExpIntegralE[n, x], {x, k}], {k, 1, 4}]

Plot higher derivatives for :

Wolfram Language code:

Plot[Evaluate[derivs /. n -> 0], {x, -5, 5}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

Plot higher derivatives for :

Wolfram Language code: Plot[Evaluate[derivs /. n -> 3], {x, -5, 5}]

Formula for the derivative:

Wolfram Language code: D[ExpIntegralE[n, x], {x, k}]

Integration (3)

Indefinite integral of ExpIntegralE:

Wolfram Language code: Integrate[ExpIntegralE[n, x], x]

Definite integral of ExpIntegralE:

Wolfram Language code: Integrate[ExpIntegralE[n, x], {x, 0, Infinity}]

More integrals:

Wolfram Language code: Integrate[x ExpIntegralE[n, x], x]

Wolfram Language code: Integrate[ExpIntegralE[n, x]ExpIntegralE[n + 1, x], x]

Series Expansions (4)

Series expansion for ExpIntegralE:

Wolfram Language code: Series[ExpIntegralE[n, x], {x, 0, 7}]

Plot the first three approximations for around :

Wolfram Language code:

terms = Normal@Table[Series[ExpIntegralE[1, x], {x, 0, m}], {m, 0, 2}];
Plot[{ExpIntegralE[1, x], terms}, {x, 0, 2}]

General term in the series expansion of :

Wolfram Language code: SeriesCoefficient[ExpIntegralE[0, x], {x, 0, n}]

Series expansion at infinity:

Wolfram Language code: Series[ExpIntegralE[n, z], {z, Infinity, 5}]//Normal

Give the result for an arbitrary symbolic direction:

Wolfram Language code: Series[ExpIntegralE[n, z], {z, DirectedInfinity[w], 2}]//Normal

ExpIntegralE can be applied to power series:

Wolfram Language code: ExpIntegralE[2, 1 + x + (x^2/2) + O[x]^4]

Integral Transforms (3)

Compute the Fourier sine transform for using FourierSinTransform:

Wolfram Language code: FourierSinTransform[ExpIntegralE[0, t], t, ω]

LaplaceTransform for :

Wolfram Language code: LaplaceTransform[ExpIntegralE[1, t], t, s]

MellinTransform:

Wolfram Language code: MellinTransform[ExpIntegralE[n, x], x, s ]

Function Identities and Simplifications (4)

Use FullSimplify to simplify exponential integrals:

Wolfram Language code: FullSimplify[ExpIntegralE[3, z] + z / 2ExpIntegralE[2, z]]

Use FunctionExpand to express special cases in simpler functions:

Wolfram Language code: FunctionExpand[{ExpIntegralE[5 / 2, z], ExpIntegralE[4, z], ExpIntegralE[-4, z]}]//Simplify

Recurrence relationship:

Wolfram Language code: ExpIntegralE[n, z] == (1/n - 1)(E^-z - z ExpIntegralE[n - 1, z])//FullSimplify

For , :

Wolfram Language code: FullSimplify[ExpIntegralE[1, x] == -ExpIntegralEi[-x], x > 0]

Function Representations (5)

Primary definition of the exponential integral function:

Wolfram Language code: Integrate[Exp[-z t]t ^ -n, {t, 1, Infinity}, Assumptions -> z > 0 && n < 1]

Relationship to the incomplete gamma function Gamma:

Wolfram Language code: ExpIntegralE[n, z]//FunctionExpand

ExpIntegralE can be represented in terms of MeijerG:

Wolfram Language code: MeijerGReduce[ExpIntegralE[n, x], x]

Wolfram Language code: Activate[%]//FullSimplify

ExpIntegralE can be represented as a DifferentialRoot:

Wolfram Language code: DifferentialRootReduce[ExpIntegralE[n, x], x]

TraditionalForm formatting:

Wolfram Language code: ExpIntegralE[n, z]//TraditionalForm

Generalizations & Extensions (2)

Infinite arguments give exact results:

Wolfram Language code: ExpIntegralE[0, Infinity]

ExpIntegralE threads element-wise over lists and arrays:

Wolfram Language code: ExpIntegralE[0, {2., 3., 5., 7., 11.}]

Applications (5)

Plot over the complex plane:

Wolfram Language code: Plot3D[Im[ExpIntegralE[-3, x + I y]], {x, -1, 1}, {y, -1, 1}]

Solution of the heat equation for piecewise‐constant initial conditions:

Wolfram Language code:

T[x_, t_] := (1/4Sqrt[π]Sqrt[α t])T0((x - x1)ExpIntegralE[(1/2), ((x - x1)^2/4α t)] + (-x + x2)ExpIntegralE[(1/2), ((x - x2)^2/4α t)])

Check that the solution satisfies the heat equation:

Wolfram Language code: D[T[x, t], t] == α D[T[x, t], x, x]//FullSimplify

Plot the solution for different times:

Wolfram Language code: Plot[Evaluate[{T[x, 10 ^ -3], T[x, 0.5], T[x, 1], T[x, 2]} /. {x1 -> -1, x2 -> 1, T0 -> 1, α -> 1}], {x, -4, 4}]//Quiet

Calculate a classical asymptotic series with factorial coefficients:

Wolfram Language code: Series[Exp[1 / z]ExpIntegralE[1, 1 / z], {z, 0, 12}, Assumptions -> z > 0]

Plot the difference of a truncated series and the exponential integral sum:

Wolfram Language code: δ[z_, o_] := -Sum[(-1) ^ n(n - 1)!(z) ^ n, {n, 1, o}] + Exp[1 / z]ExpIntegralEi[-1 / z]

Wolfram Language code: Plot[Evaluate[Table[Log[Abs[δ[z, o]]], {o, 6}]], {z, 0.1, 2}]

Approximate the "leaky aquifer" function (also known as the Hantush–Jacob function or incomplete Bessel function) arising in hydrology and electronic structure calculations, using a series expansion in terms of ExpIntegralE:

Wolfram Language code:

LeakyAquiferApprox[u_, ϵ_, n_Integer : 10] := ExpIntegralE[1, u] + Sum[(-ϵ / u) ^ k / k! ExpIntegralE[k + 1, u], {k, 1, n}]

Compare with quadrature of the defining integral:

Wolfram Language code: LeakyAquiferQuadrature[u_, ϵ_] := NIntegrate[Exp[- - ϵ / ] / , {, u, Infinity}]

Wolfram Language code: {LeakyAquiferApprox[0.001, 0.001], LeakyAquiferQuadrature[0.001, 0.001]}

Wolfram Language code: Plot[{LeakyAquiferApprox[u, 0.001], LeakyAquiferApprox[u, 0.5, 20], LeakyAquiferApprox[u, 1, 100]}, {u, 0.1, 2}]

Compute the expected time value of a death benefit of $1 paid at time , where is drawn from a Gompertz–Makeham distribution:

Wolfram Language code: tv = TimeValue[Cashflow[{{t, 1}}], EffectiveInterest[r, 0], 0]

Wolfram Language code: nsp = Expectation[tv, tGompertzMakehamDistribution[a, b]]

Find the annual premium, which is usually paid at the beginning of a policy year, that is necessary to make the expected time value of that payment stream for periods (where is drawn from a Gompertz–Makeham distribution) equal to the net single premium:

Wolfram Language code: nap = TimeValue[AnnuityDue[premium, t], EffectiveInterest[r, 0], 0]

Wolfram Language code: etv = Expectation[nap, tGompertzMakehamDistribution[a, b]]

The resulting net annual premium:

Wolfram Language code: Solve[etv == nsp, premium]//FullSimplify

Properties & Relations (8)

Use FullSimplify to simplify exponential integrals:

Wolfram Language code: FullSimplify[ExpIntegralE[3, z] + z / 2ExpIntegralE[2, z]]

Use FunctionExpand to express special cases in simpler functions:

Wolfram Language code: FunctionExpand[{ExpIntegralE[5 / 2, z], ExpIntegralE[4, z], ExpIntegralE[-4, z]}]//Simplify

Numerically find a root of a transcendental equation:

Wolfram Language code: FindRoot[ExpIntegralE[1, z] - 2ExpIntegralE[2, z + 2] + z == 2, {z, 1}]

Generate from integrals, sums, and differential equations:

Wolfram Language code: Integrate[Exp[-z t]t ^ -n, {t, 1, Infinity}, Assumptions -> z > 0 && n < 1]

Wolfram Language code: FullSimplify[n!z ^ (-n - 1)Exp[-z]Sum[z ^ k / k!, {k, 0, n}]]

Wolfram Language code: DSolve[x y''[x] + (ν + 1 - x)y'[x] == 0, y[x], x]//FullSimplify

ExpIntegralE appears as a special case of hypergeometric and Meijer G-functions:

Wolfram Language code: {Hypergeometric1F1[1 - ν, 2 - ν, -z], MeijerG[{{ν}, {}}, {{0}, {ν - 1}}, z]}//FunctionExpand//FullSimplify

Integrals:

Wolfram Language code: Integrate[ExpIntegralE[ν, z], z]

ExpIntegralE is a numeric function:

Wolfram Language code: Attributes[ExpIntegralE]

Wolfram Language code: NumericQ[ExpIntegralE[2, 2 + E]]

ExpIntegralE can be represented as a DifferenceRoot:

Wolfram Language code: DifferenceRootReduce[DifferenceRootReduce[ExpIntegralE[k, z], k], k]

Possible Issues (3)

Large arguments can give results too large to be computed explicitly:

Wolfram Language code: ExpIntegralE[2, -10. ^ 16]

Machine-number inputs can give high‐precision results:

Wolfram Language code: ExpIntegralE[2, -10. ^ 3]

Wolfram Language code: MachineNumberQ[%]

In TraditionalForm, is not automatically interpreted as an exponential integral:

Wolfram Language code: Subscript[E, n](z)

Neat Examples (1)

Plot the Riemann surface of :

Wolfram Language code:

With[{p = 1 / 2, ε = 10 ^ -8}, 
	ParametricPlot3D[Table[{r Cos[ϕ], r Sin[ϕ], Re[ExpIntegralE[p, r Exp[I ϕ]] + 2π I((r Exp[I ϕ])^p - 1/Gamma[p])Exp[k p π I]ChebyshevU[k - 1, Cos[p π]]]}, {k, 0, 1}], {r, ε, 2}, {ϕ, -π, π}, PlotRange -> {All, All, {-5, 3}}]]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

ExpIntegralE

Details

Examples

Basic Examples (5)

Scope (42)

Numerical Evaluation (5)

Specific Values (3)

Visualization (3)

Function Properties (9)

Differentiation (3)

Integration (3)

Series Expansions (4)

Integral Transforms (3)

Function Identities and Simplifications (4)

Function Representations (5)

Generalizations & Extensions (2)

Applications (5)

Properties & Relations (8)

Possible Issues (3)

Neat Examples (1)

Text

CMS

APA

BibTeX

BibLaTeX

ExpIntegralE

Details

Examples

Basic Examples (5)

Scope (42)

Numerical Evaluation (5)

Specific Values (3)

Visualization (3)

Function Properties (9)

Differentiation (3)

Integration (3)

Series Expansions (4)

Integral Transforms (3)

Function Identities and Simplifications (4)

Function Representations (5)

Generalizations & Extensions (2)

Applications (5)

Properties & Relations (8)

Possible Issues (3)

Neat Examples (1)

See Also

Tech Notes

Related Guides

Related Links

History

Text

CMS

APA

BibTeX

BibLaTeX