WOLFRAM

Wolfram Language & System Documentation Center

MarcumQ[m,a,b]

gives Marcum's Q function TemplateBox[{m, a, b}, MarcumQ].

MarcumQ[m,a,b0,b1]

gives Marcum's Q function TemplateBox[{m, a, {b, _, 0}}, MarcumQ]-TemplateBox[{m, a, {b, _, 1}}, MarcumQ].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Show More Show More
Function Properties  
Differentiation  
Series Expansions  
Function Identities and Simplifications  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

MarcumQ

MarcumQ[m,a,b]

gives Marcum's Q function TemplateBox[{m, a, b}, MarcumQ].

MarcumQ[m,a,b0,b1]

gives Marcum's Q function TemplateBox[{m, a, {b, _, 0}}, MarcumQ]-TemplateBox[{m, a, {b, _, 1}}, MarcumQ].

Details

  • Mathematical function, suitable for both symbolic and numerical evaluation.
  • TemplateBox[{m, a, b}, MarcumQ]=int_b^inftyx (x/a)^(m-1) TemplateBox[{{m, -, 1}, {a, , x}}, BesselI] exp(-1/2 (a^2+x^2))dx for real positive , , and .
  • MarcumQ[m,a,b] is an entire function of both a and b with no branch cut discontinuities.
  • For certain special arguments, MarcumQ automatically evaluates to exact values.
  • MarcumQ can be evaluated to arbitrary numerical precision.
  • MarcumQ automatically threads over lists. »

Examples

open all close all

Basic Examples  (4)

Evaluate numerically:

Wolfram Language code: MarcumQ[2., 3, 1]

Plot over a subset of the reals:

Wolfram Language code: Plot[MarcumQ[1, 4, b], {b, 0, 10}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[MarcumQ[1, 1, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[MarcumQ[1 / 2, x, 2], {x, 0, 2}]

Scope  (29)

Numerical Evaluation  (6)

Evaluate numerically:

Wolfram Language code: N[MarcumQ[5, 8, 7]]
Wolfram Language code: MarcumQ[2.5, 1.2, 3, 9]

Evaluate to high precision:

Wolfram Language code: N[MarcumQ[2 / 5, 1 / 2, 3, 9], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: MarcumQ[2, 5, 9.21111111111111111111111111111111111]

Complex number input:

Wolfram Language code: N[MarcumQ[2 + I, 1 / 2, 3]]

Evaluate efficiently at high precision:

Wolfram Language code: MarcumQ[2 / 5, 1 / 2, 3`100]//Timing
Wolfram Language code: MarcumQ[1, 1 / 5, 3`1000];//Timing

Compute the elementwise values of an array using automatic threading:

Wolfram Language code: MarcumQ[2, 1 / 2, {{1 / 2, -1}, {0, 1 / 2}}]

Or compute the matrix MarcumQ function using MatrixFunction:

Wolfram Language code: MatrixFunction[MarcumQ[2, 1 / 2, #]&, {{1 / 2, -1}, {0, 1 / 2}}]//FullSimplify

Compute average-case statistical intervals using Around:

Wolfram Language code: MarcumQ[ 2, 0, Around[1 / 2, 0.01]]

Specific Values  (3)

MarcumQ for symbolic a:

Wolfram Language code: MarcumQ[2, a, a ]//FunctionExpand

Find the maximum of MarcumQ[1,2,x]:

Wolfram Language code: xmax = x /. FindRoot[D[MarcumQ[1, 2, x], x] == 0, {x, 0.1}]
Wolfram Language code: Plot[MarcumQ[1, 2, x], {x, -5, 5}, Epilog -> Style[Point[{xmax, MarcumQ[1, 2, xmax]}], PointSize[Large], Red]]

The four-argument form gives the difference:

Wolfram Language code: MarcumQ[m, a, b0, b1]//FunctionExpand

Visualization  (2)

Plot the MarcumQ function for various parameters:

Wolfram Language code: Plot[{MarcumQ[1, 5, x], MarcumQ[1, 4, x], MarcumQ[1, 3, x]}, {x, 0, 10}]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[MarcumQ[1, 3, z]], {z, -4 - 4 I, 4 + 4 I}, Contours -> 20]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[MarcumQ[1, 3, z]], {z, -4 - 4 I, 4 + 4 I}, Contours -> 20]

Function Properties  (9)

Real domain of MarcumQ:

Wolfram Language code: FunctionDomain[MarcumQ[m, a, b], {m, a, b}]
Wolfram Language code: FunctionDomain[MarcumQ[m, a, b1, b2], {m, a, b1, b2}]

Complex domain of MarcumQ:

Wolfram Language code: FunctionDomain[MarcumQ[m, a, b], {m, a, b}, Complexes]
Wolfram Language code: FunctionDomain[MarcumQ[m, a, b1, b2], {m, a, b1, b2}, Complexes]

Approximate function range of :

Wolfram Language code: FunctionRange[MarcumQ[2, 1, x], x, y]//Quiet

TemplateBox[{m, a, x}, MarcumQ] is an even function of :

Wolfram Language code: MarcumQ[m, a, -x]

TemplateBox[{m, a, b}, MarcumQ] is an analytic function of and for positive integer :

Wolfram Language code: FunctionAnalytic[MarcumQ[m, a, b], {a, b}, Assumptions -> m > 0 && m∈ℤ]

It has no singularities or discontinuities:

Wolfram Language code: Simplify[FunctionSingularities[MarcumQ[m, a, b], {a, b}], Assumptions -> m > 0 && m∈ℤ]
Wolfram Language code: Simplify[FunctionDiscontinuities[MarcumQ[m, a, b], {a, b}], Assumptions -> m > 0 && m∈ℤ]

is neither non-increasing nor non-decreasing:

Wolfram Language code: FunctionMonotonicity[MarcumQ[1 / 2, x, 2], x]

is not injective:

Wolfram Language code: FunctionInjective[MarcumQ[1 / 2, x, 2], x]
Wolfram Language code: Plot[{MarcumQ[1 / 2, x, 2], .5}, {x, -10, 10}]

is non-negative:

Wolfram Language code: FunctionSign[MarcumQ[1 / 2, x, 2], x]

is neither convex nor concave:

Wolfram Language code: FunctionConvexity[MarcumQ[1 / 2, x, 2], x]

TraditionalForm formatting:

Wolfram Language code: MarcumQ[m, a, b]//TraditionalForm
Wolfram Language code: MarcumQ[m, a, Subscript[b, 0], Subscript[b, 1]]//TraditionalForm

Differentiation  (2)

First derivative with respect to a:

Wolfram Language code: D[MarcumQ[m, a, b], a]

First derivative with respect to b:

Wolfram Language code: D[MarcumQ[m, a, b], b]

Higher derivatives with respect to a:

Wolfram Language code: Table[D[MarcumQ[m, a, b], {a, k}], {k, 1, 4}]//FullSimplify

Plot the higher derivatives with respect to a when b=3 and m=1:

Wolfram Language code: Plot[Evaluate[% /. { b -> 3, m -> 1}], {a, 0, 10}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

Series Expansions  (2)

Find the Taylor expansion using Series:

Wolfram Language code: Series[MarcumQ[m, a, b], {a, 0, 3}]//Normal//FullSimplify

Plots of the first three approximations around :

Wolfram Language code: terms = Normal@Table[Series[MarcumQ[1, a, 3], {a, 0, k}], {k, 1, 5, 2}]; Plot[{MarcumQ[1, a, 3], terms}, {a, -3, 3}]

Taylor expansion at a generic point:

Wolfram Language code: Series[MarcumQ[m, a, b], {a, a0, 2}]// Normal//FullSimplify

Function Identities and Simplifications  (5)

TemplateBox[{m, a, b}, MarcumQ] can be expressed in terms of simpler functions whenever is a half-integer:

Wolfram Language code: MarcumQ[5 / 2, a, b]//FunctionExpand

For integer and , TemplateBox[{m, a, b}, MarcumQ] can be expressed in terms of modified Bessel functions:

Wolfram Language code: MarcumQ[-4, a, a]//FunctionExpand

For arbitrary and , TemplateBox[{m, a, b}, MarcumQ] can be expressed in terms of hypergeometric functions:

Wolfram Language code: MarcumQ[m, a, a]//FunctionExpand

Ordinary differential equation with respect to satisfied by TemplateBox[{m, a, b}, MarcumQ]:

Wolfram Language code: a^2y'''[a] + a(2a^2 + 2m - 1)y''[a] + (a^4 - a^2(b^2 - 2m) - 2m + 1)y'[a] == 0 /. y -> Function[a, MarcumQ[m, a, b]]//FullSimplify

Ordinary differential equation with respect to satisfied by TemplateBox[{m, a, b}, MarcumQ]:

Wolfram Language code: b^2y'''[b] + b(2b^2 - 2m + 1)y''[b] + (b^4 - b^2(a^2 + 2m - 2) + 2m - 1)y'[b] == 0 /. y -> Function[b, MarcumQ[m, a, b]]//FullSimplify

Recurrence relation with respect to satisfied by TemplateBox[{m, a, b}, MarcumQ]:

Wolfram Language code: (a^2/2)y[m + 2] == ((a^2/2) - m)y[m + 1] + ((b^2/2) + m)y[m] - (b^2/2)y[m - 1] /. y -> Function[m, MarcumQ[m, a, b]]//FullSimplify

Applications  (2)

The amplitude of a signal is modeled by RiceDistribution. Find the probability that the amplitude will exceed its mean value:

Wolfram Language code: 𝒟 = RiceDistribution[3, 2, 5];
Wolfram Language code: Probability[x > Mean[𝒟], x𝒟]

Evaluate numerically:

Wolfram Language code: N[%]

Compare the value of the MarcumQ function for large arguments to its asymptotic formula:

Wolfram Language code: Refine[SurvivalFunction[RiceDistribution[m, a / Sqrt[m], 1], x / Sqrt[m]], m > 0 && x > 0]

Construct an approximation using the central limit theorem:

Wolfram Language code: SurvivalFunction[NormalDistribution[Mean[RiceDistribution[m, a / Sqrt[m], 1]], StandardDeviation[RiceDistribution[m, a / Sqrt[m], 1]]], x / Sqrt[m]]

Evaluate numerically:

Wolfram Language code: {%%, %} /. {m -> 3, a -> 8.2, x -> 9.}

Properties & Relations  (3)

MarcumQ can be used to compute the SurvivalFunction of SkellamDistribution:

Wolfram Language code: k = 3;m1 = 10;m2 = 9; SurvivalFunction[SkellamDistribution[m1, m2], k]//N
Wolfram Language code: MarcumQ[-k, Sqrt[2 m1], Sqrt[2 m2]]//N

MarcumQ computes the SurvivalFunction of NoncentralChiSquareDistribution:

Wolfram Language code: SurvivalFunction[NoncentralChiSquareDistribution[ν, δ], x]

MarcumQ computes the SurvivalFunction of RiceDistribution:

Wolfram Language code: SurvivalFunction[RiceDistribution[α, β], x]
Wolfram Language code: SurvivalFunction[RiceDistribution[m, α, β], x]
Wolfram Research (2010), MarcumQ, Wolfram Language function, https://reference.wolfram.com/language/ref/MarcumQ.html.

Text

Wolfram Research (2010), MarcumQ, Wolfram Language function, https://reference.wolfram.com/language/ref/MarcumQ.html.

CMS

Wolfram Language. 2010. "MarcumQ." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/MarcumQ.html.

APA

Wolfram Language. (2010). MarcumQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MarcumQ.html

BibTeX

@misc{reference.wolfram_2026_marcumq, author="Wolfram Research", title="{MarcumQ}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/MarcumQ.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_marcumq, organization={Wolfram Research}, title={MarcumQ}, year={2010}, url={https://reference.wolfram.com/language/ref/MarcumQ.html}, note=[Accessed: 12-June-2026]}