WOLFRAM

Wolfram Language & System Documentation Center

MellinConvolve[f,g,x,y]

gives the Mellin convolution with respect to x of the expressions f and g.

MellinConvolve[f,g,{x1,x2,…},{y1,y2,…}]

gives the multidimensional Mellin convolution.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Univariate Convolution  
Multivariate Convolution  
Options  
Assumptions  
GenerateConditions  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

MellinConvolve

MellinConvolve[f,g,x,y]

gives the Mellin convolution with respect to x of the expressions f and g.

MellinConvolve[f,g,{x1,x2,…},{y1,y2,…}]

gives the multidimensional Mellin convolution.

Details and Options

  • The Mellin convolution of two functions and is given by .
  • The multidimensional Mellin convolution of two functions and is given by .
  • The following options can be given:
  • Assumptions $Assumptionsassumptions to make about parameters
    GenerateConditions Falsewhether to generate conditions on parameters
    MethodAutomaticmethod to use

Examples

open all close all

Basic Examples  (2)

Convolve two functions:

Wolfram Language code: MellinConvolve[UnitBox[x - 3 / 2], 2UnitBox[x - 2], x, y]
Wolfram Language code: Plot[{UnitBox[y - 3 / 2], 2UnitBox[y - 2], %}//Evaluate, {y, 0, 6}, Filling -> Axis, Exclusions -> None, PlotRange -> All]

Perform a multivariate convolution:

Wolfram Language code: MellinConvolve[3UnitBox[s - 3 / 2, t - 7 / 4], 2UnitBox[s - 1, t - 1], {s, t}, {m, n}]
Wolfram Language code: Plot3D[{3UnitBox[m - 3 / 2, n - 7 / 4], 2UnitBox[m - 1, n - 1], %}//Evaluate, {m, 0, 3}, {n, 0, 3}, PlotRange -> All, Filling -> Axis, PlotPoints -> 50, Exclusions -> None, PlotStyle -> Opacity[0.4], Ticks -> None, Mesh -> None]

Scope  (8)

Basic Uses  (3)

Compute a Mellin convolution for a symbolic parameter y:

Wolfram Language code: MellinConvolve[E ^ (-x), 1 / (x + 1), x, y]

Use an exact value for the parameter:

Wolfram Language code: MellinConvolve[E ^ (-x), 1 / (x + 1), x, 1]

Use an inexact value for the parameter:

Wolfram Language code: MellinConvolve[E ^ (-x), 1 / (x + 1), x, 0.3]

Obtain the condition of validity for a Mellin convolution:

Wolfram Language code: MellinConvolve[E ^ (-a x), 1 / (x + 1), x, y, GenerateConditions -> True]

Specify assumptions on a parameter:

Wolfram Language code: MellinConvolve[E ^ (-x), UnitBox[x - a], x, y, Assumptions -> a > 1 / 2]

Specify a different assumption:

Wolfram Language code: MellinConvolve[E ^ (-x), UnitBox[x - a], x, y, Assumptions -> 0 < a < 1 / 2]

Univariate Convolution  (3)

Elementary functions:

Wolfram Language code: MellinConvolve[Sin[x], Cos[x], x, y]
Wolfram Language code: Plot[{Sin[y], Cos[y], %}, {y, 0, 30}, Filling -> Axis]

Special functions:

Wolfram Language code: MellinConvolve[BesselJ[0, x], BesselJ[1, x], x, y]
Wolfram Language code: Plot[{BesselJ[0, y], BesselJ[1, y], %}//Evaluate, {y, 0, 10}, Filling -> Axis, PlotLegends -> "Expressions"]

Piecewise functions:

Wolfram Language code: MellinConvolve[UnitTriangle[x - 2], UnitBox[x - 7 / 4], x, y]
Wolfram Language code: Plot[{UnitTriangle[y - 2], UnitBox[y - 7 / 4], %}//Evaluate, {y, 0, 10}, Filling -> Axis, PlotRange -> All, Exclusions -> None]

Multivariate Convolution  (2)

Elementary functions:

Wolfram Language code: MellinConvolve[3Sin[s + t], 4Sin[s - t], {s, t}, {m, n}]
Wolfram Language code: Plot3D[{3Sin[m + n], 4Sin[m - n], %}//Evaluate, {m, 1, 7}, {n, 1, 7}, PlotRange -> All, Filling -> Axis, PlotPoints -> 50, Exclusions -> None, PlotStyle -> Opacity[0.4], Ticks -> None, Mesh -> None, PlotLegends -> "Expressions"]

Piecewise functions:

Wolfram Language code: MellinConvolve[2UnitTriangle[x - 2], 3UnitBox[x - 1, y - 1], {x, y}, {m, n}]
Wolfram Language code: Plot3D[{2UnitTriangle[m - 2], 3UnitBox[m - 1, n - 1], %}//Evaluate, {m, 0, 3}, {n, 0, 3}, PlotRange -> All, Filling -> Axis, PlotPoints -> 50, Exclusions -> None, PlotStyle -> Opacity[0.3], Ticks -> None, Mesh -> None]

Options  (2)

Assumptions  (1)

Specify assumptions on a parameter:

Wolfram Language code: MellinConvolve[Sin[x], UnitBox[x - a], x, y]
Wolfram Language code: MellinConvolve[Sin[x], UnitBox[x - a], x, y, Assumptions -> a > 1 / 2]

GenerateConditions  (1)

Generate conditions for the validity of a Mellin convolution:

Wolfram Language code: MellinConvolve[1 / (x + 1), E ^ (-a x), x, y, GenerateConditions -> True]

Applications  (2)

Compute the PDF for the product of two random variables:

Wolfram Language code: 𝒟1 = UniformDistribution[];
Wolfram Language code: 𝒟2 = TriangularDistribution[{1 / 2, 2}];
Wolfram Language code: f[x_] = PDF[𝒟1, x]
Wolfram Language code: g[x_] = PDF[𝒟2, x]

MellinConvolve gives the PDF for the product of these random variables:

Wolfram Language code: p1 = MellinConvolve[f[x], g[x], x, t]
Wolfram Language code: Plot[{f[t], g[t], %}//Evaluate, {t, 0, 3}, Filling -> Axis, PlotRange -> All, Exclusions -> None]

Compare with the result from TransformedDistribution:

Wolfram Language code: p2 = PDF[TransformedDistribution[x y, {x𝒟1, y𝒟2}, Assumptions -> t > 0], t]
Wolfram Language code: Simplify[p1 - p2, t > 0]

The integral depends on the parameter α. Find the value of α that lies between 0 and 5 and maximizes the integral. The given integral can be regarded as a Mellin convolution of two functions:

Wolfram Language code: f[x_] := x(2 - x) ^ α UnitBox[(x - 1) / 2]
Wolfram Language code: g[x_] := Sin[x]

Compute the Mellin convolution of f[x] and g[x]:

Wolfram Language code: (mc = MellinConvolve[f[x], g[x], x, α])//TraditionalForm

Compare with the result given by Integrate:

Wolfram Language code: Integrate[(2 - x) ^ α Sin[α / x], {x, 0, 2}, Assumptions -> α > 0]//TraditionalForm

Plot the integral as a function of α:

Wolfram Language code: Plot[mc//Evaluate, {α, 0, 4.99}, PlotStyle -> Red]

Compute the argument that maximizes the integral in 0≤α≤5 using FindArgMax:

Wolfram Language code: N[FindArgMax[mc, {α, 1}, WorkingPrecision -> 100][[1]], 20]

Properties & Relations  (8)

MellinConvolve computes the integral :

Wolfram Language code: f[x_] := UnitBox[x]
Wolfram Language code: g[x_] := E ^ (-x)
Wolfram Language code: MellinConvolve[f[x], g[x], x, y]
Wolfram Language code: Integrate[ f[x]g[y / x] / x, {x, 0, Infinity}, Assumptions -> y ≥ 0]

Scaling:

Wolfram Language code: MellinConvolve[a r[x], s[x], x, y]
Wolfram Language code: MellinConvolve[r[x], a s[x], x, y]

Commutativity:

Wolfram Language code: f[x_] := UnitBox[x]
Wolfram Language code: g[x_] := E ^ (-x)
Wolfram Language code: MellinConvolve[f[x], g[x], x, y]
Wolfram Language code: MellinConvolve[g[x], f[x], x, y]

Distributivity:

Wolfram Language code: MellinConvolve[h[x], i[x] + j[x], x, y]
Wolfram Language code: MellinConvolve[h[x] + i[x], j[x], x, y]

Convolution with DiracDelta:

Wolfram Language code: MellinConvolve[f[x], DiracDelta[x - a], x, y]

Derivatives of DiracDelta:

Wolfram Language code: MellinConvolve[DiracDelta'[x - 1], f[x], x, y]
Wolfram Language code: MellinConvolve[DiracDelta''[x - 1], f[x], x, y]

The Mellin transform of a convolution is the product of the individual Mellin transforms:

Wolfram Language code: MellinTransform[MellinConvolve[f[t], g[t], t, x], x, y]

Derivative of MellinConvolve with respect to y:

Wolfram Language code: D[MellinConvolve[f[x], g[x], x, y], y]

Relation between MellinConvolve, MellinTransform, and InverseMellinTransform:

Wolfram Language code: f[x_] := UnitBox[x]
Wolfram Language code: g[x_] := E ^ (-x)
Wolfram Language code: MellinConvolve[f[x], g[x], x, y] == InverseMellinTransform[MellinTransform[f[x], x, s] MellinTransform[g[x], x, s] , s, y]
Wolfram Research (2016), MellinConvolve, Wolfram Language function, https://reference.wolfram.com/language/ref/MellinConvolve.html.

Text

Wolfram Research (2016), MellinConvolve, Wolfram Language function, https://reference.wolfram.com/language/ref/MellinConvolve.html.

CMS

Wolfram Language. 2016. "MellinConvolve." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/MellinConvolve.html.

APA

Wolfram Language. (2016). MellinConvolve. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MellinConvolve.html

BibTeX

@misc{reference.wolfram_2026_mellinconvolve, author="Wolfram Research", title="{MellinConvolve}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/MellinConvolve.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_mellinconvolve, organization={Wolfram Research}, title={MellinConvolve}, year={2016}, url={https://reference.wolfram.com/language/ref/MellinConvolve.html}, note=[Accessed: 13-June-2026]}