InverseMellinTransform
InverseMellinTransform[expr,s,x]
gives the inverse Mellin transform of expr.
Details and Options
- The inverse Mellin transform of a function
is defined to be 
, lying in a strip 
in which the function 
is holomorphic. In some cases, the strip of holomorphy may extend to a half-plane. - ConditionalExpression[expr,α<Re[s]<β] can be used to indicate the strip of holomorphy. »
- The following options can be given:
-
Assumptions $Assumptions assumptions on parameters GenerateConditions False whether to generate results that involve conditions on parameters Method Automatic what method to use - GenerateConditions can be used to obtain the strip of holomorphy. »
- Assumptions can be used to specify a strip of holomorphy. »
- If both Assumptions and ConditionalExpression are used to constrain the strip of holomorphy, then the intersection of the strips is used.
- In TraditionalForm, InverseMellinTransform is output using
![TemplateBox[{{F, (, s, )}, s, x}, InverseMellinTransform1]](Files/InverseMellinTransform.en/7.png "TemplateBox[{{F, (, s, )}, s, x}, InverseMellinTransform1]")
.
Examples
open all close allBasic Examples (2)
Compute the InverseMellinTransform of a function:
InverseMellinTransform[Gamma[s], s, x]InverseMellinTransform for a product of functions:
InverseMellinTransform[(2^-1 + s a^-s Gamma[(1/2) + (s/2)]/Gamma[(3/2) - (s/2)]), s, x]Plot[Evaluate[Table[%, {a, 1, 4}]], {x, 0, 7}]Scope (10)
Basic Uses (4)
Compute the inverse Mellin transform of a function for a symbolic parameter x:
InverseMellinTransform[Gamma[s], s, x]Use an exact value for the parameter:
InverseMellinTransform[Gamma[s], s, -2]Use an inexact value for the parameter:
InverseMellinTransform[Gamma[s], s, -2.3]Obtain the strip of holomorphy assumed by InverseMellinTransform:
InverseMellinTransform[Gamma[s], s, x, GenerateConditions -> True]InverseMellinTransform[Gamma[s], s, x, Assumptions -> -1 < Re[s] < 0]InverseMellinTransform[Gamma[s], s, x, Assumptions -> s > 1]TraditionalForm formatting:
TraditionalForm[InverseMellinTransform[f[x], x, s]]Elementary Functions (3)
Inverse Mellin transforms of rational functions:
InverseMellinTransform[(1/s + a), s, x]InverseMellinTransform[(1/s^2 + a^2), s, x]InverseMellinTransform[a^s - 1, s, x]Rational-exponential function:
InverseMellinTransform[(a^s/s + b), s, x]InverseMellinTransform[π Csc[π s], s, x]//TogetherInverseMellinTransform[π Cot[π s], s, x]//TogetherSpecial Functions (3)
Inverse transforms of Gamma expressed in terms of exponential functions:
InverseMellinTransform[Gamma[2s], s, x]InverseMellinTransform[Gamma[(s/2)], s, x]InverseMellinTransform[(2^-1 + s Gamma[(s/2)]/Gamma[1 - (s/2)]), s, x]InverseMellinTransform[2^-2 + s Gamma[(s/2)]^2, s, x]InverseMellinTransform[Gamma[(s/a)]^2, s, x]Other elementary and special functions:
InverseMellinTransform[(Gamma[(s/2)]Gamma[1 - s]/Gamma[1 - (s/2)]), s, x]InverseMellinTransform[(Gamma[(s/2)]/1 - s), s, x]Inverse transforms of expressions involving Bessel functions:
InverseMellinTransform[BesselK[s, a], s, x]InverseMellinTransform[Sqrt[s] BesselI[(m/2), (s/2)] BesselK[(m/2) + (1/2), (s/2)], s, x]Inverse transform of an expression involving Zeta:
InverseMellinTransform[Gamma[s] Zeta[s], s, x]InverseMellinTransform[PolyGamma[2, s], s, x]Options (2)
Assumptions (1)
The answer returned by InverseMellinTransform in this example is valid for Re[s]>0:
expr = (Gamma[(1/2) + (s/2)]/s);InverseMellinTransform[expr, s, x, GenerateConditions -> True]Use Assumptions to specify a different strip of holomorphy:
InverseMellinTransform[expr, s, x, Assumptions -> -2 < Re[s] < -1]Use ConditionalExpression to specify the same assumptions:
InverseMellinTransform[ConditionalExpression[expr, -2 < Re[s] < -1], s, x]GenerateConditions (1)
Obtain conditions for validity of the result in InverseMellinTransform:
Together[InverseMellinTransform[π Csc[π s], s, x, GenerateConditions -> True]]GenerateConditions is set to False by default in this case:
Together[InverseMellinTransform[π Csc[π s], s, x]]Applications (2)
Evaluate ![int_0^infty(TemplateBox[{0, t}, BesselJ] TemplateBox[{1, {x, /, t}}, BesselJ])/tdt](Files/InverseMellinTransform.en/8.png "int_0^infty(TemplateBox[{0, t}, BesselJ] TemplateBox[{1, {x, /, t}}, BesselJ])/tdt"){kind=small}
, which may be regarded as a Mellin convolution of the following functions:
f[t_] := BesselJ[0, t]g[t_] := BesselJ[1, t]Apply MellinTransform to each function:
f1 = MellinTransform[f[t] , t, s]g1 = MellinTransform[g[t] , t, s]Obtain the required integral by performing an inverse Mellin transform:
InverseMellinTransform[f1 g1, s, x]Compute the integral directly using Integrate:
Integrate[f[t] g[x / t] / t, {t, 0, Infinity}, Assumptions -> x > 0]//FunctionExpandObtain the same result using MellinConvolve:
MellinConvolve[f[t], g[t], t, x]//FunctionExpandPlot[{f[x], g[x], %}//Evaluate, {x, 0, 10}, Filling -> Axis]Find a particular solution for a differential equation using a Mellin transform technique:
eqn = t Derivative[1][f][t] - f[t] == E^-t;Apply MellinTransform to the equation:
MellinTransform[eqn, t, s]Solve for the Mellin transform:
MellinTransform[f[t], t, s] /. Solve[%, MellinTransform[f[t], t, s]][[1]]Compute the required solution using InverseMellinTransform:
sol1 = Simplify[InverseMellinTransform[%, s, t]]Obtain the solution using DSolveValue with a boundary condition at infinity:
sol2 = DSolveValue[{t Derivative[1][f][t] - f[t] == E^-t, f[∞] == 0}, f[t], t]Verify that the two solutions are the same for t>0:
FullSimplify[sol1 - sol2, t > 0]Properties & Relations (4)
Use Asymptotic to compute an asymptotic approximation:
Asymptotic[Inactive[InverseMellinTransform][Gamma[s], s, x], x -> 0]InverseMellinTransform and MellinTransform are mutual inverses:
MellinTransform[InverseMellinTransform[g[s], s, x], x, s]InverseMellinTransform[MellinTransform[f[x], x, s], s, x]Verify the relationship for a specific function:
MellinTransform[E^-x, x, s]InverseMellinTransform[%, s, x]InverseMellinTransform is a linear operator:
InverseMellinTransform[a f[s] + b g[s], s, x]The inverse Mellin and Laplace transforms are related by ![TemplateBox[{{F, (, s, )}, s, x}, InverseMellinTransform1]=L_s^(-1)[F(s)](-log(x))](Files/InverseMellinTransform.en/9.png "TemplateBox[{{F, (, s, )}, s, x}, InverseMellinTransform1]=L_s^(-1)[F(s)](-log(x))"){kind=small}
:
InverseMellinTransform[1 / (s ^ 2 + 1), s, x]InverseLaplaceTransform[1 / (s ^ 2 + 1), s, t] /. {t -> -Log[x]}Possible Issues (2)
InverseMellinTransform may return different results depending on the assumptions:
InverseMellinTransform[Gamma[s], s, x]InverseMellinTransform[Gamma[s], s, x, Assumptions -> -2 < Re[s] < -1]In this example, the default answer is valid in a right half-plane:
InverseMellinTransform[Gamma[s], s, x, GenerateConditions -> True]The inverse Mellin transform may only exist for a certain range of values for x:
InverseMellinTransform[(1/s^2 + 1), s, x, GenerateConditions -> True]Neat Examples (1)
Create a table of basic inverse Mellin transforms:
flist = {1 / s, 1 / (s + 1), a ^ (s - 1), Gamma[s], Gamma[1 - s], Pi Csc[Pi s],
Gamma[s]Sin[(Pi s) / 2], Cos[(Pi s) / 2] Gamma[s],
Pi Cot[Pi s], (1 / 2)Gamma[s / 2],
(2 ^ (-1 + s) Gamma[1 / 2 + s / 2]) / Gamma[3 / 2 - s / 2]};Grid[Prepend[{#, InverseMellinTransform[#1, s, x]}& /@ flist, {f[s], InverseMellinTransform[f[s], s, x]}], IconizedObject[«Grid options»]]//TraditionalFormText
Wolfram Research (2016), InverseMellinTransform, Wolfram Language function, https://reference.wolfram.com/language/ref/InverseMellinTransform.html.
CMS
Wolfram Language. 2016. "InverseMellinTransform." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/InverseMellinTransform.html.
APA
Wolfram Language. (2016). InverseMellinTransform. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/InverseMellinTransform.html