WOLFRAM

Wolfram Language & System Documentation Center

MersennePrimeExponent[n]

gives the n^(th) Mersenne prime exponent.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

MersennePrimeExponent

MersennePrimeExponent[n]

gives the n^(th) Mersenne prime exponent.

Details

  • A Mersenne prime exponent is a prime number p for which the Mersenne number is prime.
  • In MersennePrimeExponent[n], n must be a positive integer.
  • As of this version of the Wolfram Language, only 50 Mersenne prime exponents have definite ranking. Two more Mersenne prime exponents are known, but their ranking is still unknown. MersennePrimeExponent[n] will attempt to find Mersenne prime exponents for n larger than 50, but cannot be expected to return results in a reasonable time.

Examples

open all close all

Basic Examples  (1)

Return the first ten Mersenne prime exponents:

Wolfram Language code: Table[MersennePrimeExponent[n], {n, 10}]

Construct the corresponding Mersenne primes:

Wolfram Language code: 2 ^ % - 1

Check that they are all primes:

Wolfram Language code: AllTrue[%, PrimeQ]

Scope  (1)

MersennePrimeExponent automatically threads over lists:

Wolfram Language code: MersennePrimeExponent[Range[10]]

Properties & Relations  (5)

Mersenne prime exponents generate even perfect numbers:

Wolfram Language code: n = Range[10]; mpe = MersennePrimeExponent[n]
Wolfram Language code: PerfectNumber[n, "Even"] == 2 ^ (mpe - 1)(2 ^ mpe - 1)

Triangular numbers of Mersenne primes generate even perfect numbers:

Wolfram Language code: mersennePrime[n_] := 2 ^ MersennePrimeExponent[n] - 1; range = Range[40];
Wolfram Language code: PolygonalNumber[mersennePrime[range]] == PerfectNumber[range, "Even"]

Hexagonal numbers related to Mersenne prime exponents generate even perfect numbers:

Wolfram Language code: powertwo[n_] := 2 ^ (MersennePrimeExponent[n] - 1); range = Range[40];
Wolfram Language code: PolygonalNumber[6, powertwo[range]] == PerfectNumber[range, "Even"]

Mersenne prime exponents generate superperfect numbers:

Wolfram Language code: superPerfectQ[n_] := DivisorSigma[1, DivisorSigma[1, n]] == 2n; powertwo[n_] := 2 ^ (MersennePrimeExponent[n] - 1);
Wolfram Language code: AllTrue[powertwo[Range[20]], superPerfectQ]

A trinomial whose order is a Mersenne prime exponent is primitive modulo 2 if and only if it is irreducible:

Wolfram Language code: MersennePrimeExponent[10]
Wolfram Language code: poly = x ^ 89 + x ^ 38 + 1;
Wolfram Language code: PrimitivePolynomialQ[poly, 2]
Wolfram Language code: IrreduciblePolynomialQ[poly, Modulus -> 2]

Possible Issues  (1)

As of this version of the Wolfram Language, only 50 Mersenne prime exponents have definite ranking:

Wolfram Language code: TimeConstrained[MersennePrimeExponent[51], 10]

Two more Mersenne prime exponents are known, but their ranking is still unknown:

Wolfram Language code: mpe = {82589933, 136279841}; AllTrue[mpe, # > MersennePrimeExponent[50]&]
Wolfram Language code: AllTrue[mpe, MersennePrimeExponentQ]
Wolfram Research (2016), MersennePrimeExponent, Wolfram Language function, https://reference.wolfram.com/language/ref/MersennePrimeExponent.html (updated 2026).

Text

Wolfram Research (2016), MersennePrimeExponent, Wolfram Language function, https://reference.wolfram.com/language/ref/MersennePrimeExponent.html (updated 2026).

CMS

Wolfram Language. 2016. "MersennePrimeExponent." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/MersennePrimeExponent.html.

APA

Wolfram Language. (2016). MersennePrimeExponent. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MersennePrimeExponent.html

BibTeX

@misc{reference.wolfram_2026_mersenneprimeexponent, author="Wolfram Research", title="{MersennePrimeExponent}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/MersennePrimeExponent.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_mersenneprimeexponent, organization={Wolfram Research}, title={MersennePrimeExponent}, year={2026}, url={https://reference.wolfram.com/language/ref/MersennePrimeExponent.html}, note=[Accessed: 12-June-2026]}