WOLFRAM

Wolfram Language & System Documentation Center

MersennePrimeExponentQ[n]

returns True if n is a Mersenne prime exponent, and False otherwise.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Basic Applications  
Special Sequences  
Number Theory  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
History
Cite this Page

MersennePrimeExponentQ

MersennePrimeExponentQ[n]

returns True if n is a Mersenne prime exponent, and False otherwise.

Details

  • MersennePrimeExponentQ is typically used to test whether an integer is a Mersenne prime exponent.
  • A positive integer n is a Mersenne prime exponent if the Mersenne number is prime.
  • MersennePrimeExponentQ[n] returns False unless n is manifestly a Mersenne prime exponent.

Examples

open all close all

Basic Examples  (2)

Test whether a number is a Mersenne prime exponent:

Wolfram Language code: MersennePrimeExponentQ[5]

The number is not a Mersenne prime exponent:

Wolfram Language code: MersennePrimeExponentQ[8]

Scope  (3)

MersennePrimeExponentQ works over integers:

Wolfram Language code: MersennePrimeExponentQ[5]

Negative integers are not Mersenne prime exponents:

Wolfram Language code: MersennePrimeExponentQ[-5]

Noninteger numbers are not Mersenne prime exponents:

Wolfram Language code: MersennePrimeExponentQ[13.5]

Applications  (8)

Basic Applications  (3)

Highlight Mersenne prime exponents:

Wolfram Language code: Multicolumn[If[MersennePrimeExponentQ[#], Style[#, Red, Bold], #]& /@ Range[100], 10, ...]

Generate random Mersenne prime exponents:

Wolfram Language code: randomMersennePrimeExp[n_, m_ : 1] := Table[MersennePrimeExponent[RandomInteger[{1, n}]], m];
Wolfram Language code: randomMersennePrimeExp[5, 4]
Wolfram Language code: AllTrue[%, MersennePrimeExponentQ]

Digits of a Mersenne prime :

Wolfram Language code: MersennePrimeExponentQ[23209]
Wolfram Language code: BarChart[KeySort[Counts[IntegerDigits[2 ^ 23209 - 1]]], ChartLabels -> Automatic]

Special Sequences  (2)

Recognize Mersenne numbers, numbers of the form :

Wolfram Language code: mersenneQ[n_] := EvenQ[n + 1] && PrimePowerQ[n + 1]
Wolfram Language code: Select[Range[100], mersenneQ]

The number is a Mersenne number; is not:

Wolfram Language code: mersenneQ[2147483647]
Wolfram Language code: mersenneQ[524285]

Recognize Gaussian Mersenne primes, prime numbers n such that is a Gaussian prime:

Wolfram Language code: gaussianMersennePrimeQ[n_] := PrimeQ[(1 + I) ^ n - 1, GaussianIntegers -> True];
Wolfram Language code: Select[Range[1000], gaussianMersennePrimeQ]

Number Theory  (3)

A trinomial whose order is a Mersenne prime exponent is primitive modulo if and only if it is irreducible:

Wolfram Language code: MersennePrimeExponentQ[89]
Wolfram Language code: p = x ^ 89 + x ^ 38 + 1;
Wolfram Language code: PrimitivePolynomialQ[p, 2]
Wolfram Language code: IrreduciblePolynomialQ[p, Modulus -> 2]

If p is a Mersenne prime exponent, then is a perfect number:

Wolfram Language code: MersennePrimeExponentQ[5]
Wolfram Language code: PerfectNumberQ[2 ^ (5 - 1)(2 ^ 5 - 1)]

Every even perfect number has the form , where p is a Mersenne prime exponent:

Wolfram Language code: PerfectNumberQ[496]
Wolfram Language code: IntegerExponent[496, 2]

Check that in the representation above p is 5:

Wolfram Language code: 2 ^ (5 - 1)(2 ^ 5 - 1)
Wolfram Language code: MersennePrimeExponentQ[5]

Properties & Relations  (10)

Mersenne prime exponents are prime numbers:

Wolfram Language code: Table[Element[MersennePrimeExponent[n], Primes], {n, 10}]

Composite numbers cannot be MersennePrimeExponents:

Wolfram Language code: CompositeQ[12]
Wolfram Language code: MersennePrimeExponentQ[12]

The only even Mersenne prime exponent is :

Wolfram Language code: MersennePrimeExponentQ[2]

MersennePrimeExponent gives the Mersenne prime exponent:

Wolfram Language code: MersennePrimeExponent[4]
Wolfram Language code: MersennePrimeExponentQ[%]

is a Mersenne prime, where p is a Mersenne prime exponent:

Wolfram Language code: MersennePrimeExponentQ[5]
Wolfram Language code: PrimeQ[2 ^ 5 - 1]

If p is a Mersenne prime exponent, then is a perfect number:

Wolfram Language code: MersennePrimeExponentQ[7]
Wolfram Language code: PerfectNumberQ[2 ^ (7 - 1)(2 ^ 7 - 1)]

Every even perfect number has the form , where p is a Mersenne prime exponent:

Wolfram Language code: PerfectNumberQ[496]
Wolfram Language code: IntegerExponent[496, 2]

Check that in the representation above p is 5:

Wolfram Language code: 2 ^ (5 - 1)(2 ^ 5 - 1)
Wolfram Language code: MersennePrimeExponentQ[5]

Triangular numbers of Mersenne primes are perfect numbers:

Wolfram Language code: mersennePrime[n_] := 2 ^ MersennePrimeExponent[n] - 1;
Wolfram Language code: AllTrue[PolygonalNumber[mersennePrime /@ Range[40]], PerfectNumberQ]

Hexagonal numbers related to Mersenne prime exponents are perfect numbers:

Wolfram Language code: powertwo[n_] := 2 ^ (MersennePrimeExponent[n] - 1);
Wolfram Language code: AllTrue[PolygonalNumber[6, powertwo /@ Range[40]], PerfectNumberQ]

Find Mersenne prime exponents:

Wolfram Language code: FindInstance[(2 ^ q - 1) == p && 0 < q < p < 100, {q, p}, Primes]
Wolfram Language code: MersennePrimeExponentQ[5]

Possible Issues  (2)

Expressions that represent Mersenne prime exponents but do not evaluate explicitly will give False:

Wolfram Language code: x = Log[8] / Log[2]; MersennePrimeExponentQ[x]

It is necessary to use symbolic simplification first:

Wolfram Language code: MersennePrimeExponentQ[FullSimplify[x]]

As of this version of the Wolfram Language, only 50 Mersenne prime exponents have definite ranking:

Wolfram Language code: TimeConstrained[MersennePrimeExponent[51], 10]

Two more Mersenne prime exponents are known, but their ranking is still unknown:

Wolfram Language code: mpe = {82589933, 136279841}; AllTrue[mpe, # > MersennePrimeExponent[50]&]
Wolfram Language code: AllTrue[mpe, MersennePrimeExponentQ]

Neat Examples  (1)

The minor planet 8191 Mersenne is named after Marin Mersenne:

Wolfram Language code: Entity["MinorPlanet", "Mersenne"]

The number is a Mersenne prime:

Wolfram Language code: FactorInteger[8191 + 1]
Wolfram Language code: MersennePrimeExponentQ[13]
Wolfram Research (2016), MersennePrimeExponentQ, Wolfram Language function, https://reference.wolfram.com/language/ref/MersennePrimeExponentQ.html.

Text

Wolfram Research (2016), MersennePrimeExponentQ, Wolfram Language function, https://reference.wolfram.com/language/ref/MersennePrimeExponentQ.html.

CMS

Wolfram Language. 2016. "MersennePrimeExponentQ." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/MersennePrimeExponentQ.html.

APA

Wolfram Language. (2016). MersennePrimeExponentQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MersennePrimeExponentQ.html

BibTeX

@misc{reference.wolfram_2026_mersenneprimeexponentq, author="Wolfram Research", title="{MersennePrimeExponentQ}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/MersennePrimeExponentQ.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_mersenneprimeexponentq, organization={Wolfram Research}, title={MersennePrimeExponentQ}, year={2016}, url={https://reference.wolfram.com/language/ref/MersennePrimeExponentQ.html}, note=[Accessed: 12-June-2026]}