Enable JavaScript to interact with content and submit forms on Wolfram websites. Learn how

Wolfram Language & System Documentation Center

MeshCoordinates

MeshCoordinates

MeshCoordinates[mreg]

gives a list of coordinates in the mesh region mreg.

Details

MeshCoordinates gives a list of coordinates {p₁,p₂,…}.
The mesh region mreg can be either MeshRegion or BoundaryMeshRegion.
The integer indexes returned by MeshCells refer to coordinates in the list {p₁,p₂,…}.

Examples

open all close all

Basic Examples (2)

Get the 2D cell coordinates from a MeshRegion:

Wolfram Language code: ℛ = MeshRegion[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}, Polygon[{1, 2, 3, 4}]]

Wolfram Language code: MeshCoordinates[ℛ]

Get the 3D cell coordinates from a BoundaryMeshRegion:

Wolfram Language code: ℛ = ConvexHullMesh[RandomReal[1, {5, 3}]]

Wolfram Language code: MeshCoordinates[ℛ]

Scope (4)

Get the coordinates of a 1D BoundaryMeshRegion:

Wolfram Language code: BoundaryMeshRegion[{{0}, {1}}, Point[{{1}, {2}}]]

Wolfram Language code: MeshCoordinates[%]

A 1D MeshRegion:

Wolfram Language code: MeshRegion[{{0}, {1}, {2}}, {Line[{1, 2}], Point[{3}]}]

Wolfram Language code: MeshCoordinates[%]

Get the coordinates of a 2D BoundaryMeshRegion:

Wolfram Language code: BoundaryMeshRegion[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}, Line[{1, 2, 3, 4, 1}]]

Wolfram Language code: MeshCoordinates[%]

A 2D MeshRegion:

Wolfram Language code: MeshRegion[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}, {Polygon[{1, 2, 3}], Line[{3, 4}]}]

Wolfram Language code: MeshCoordinates[%]

Get the coordinates of a 3D BoundaryMeshRegion:

Wolfram Language code: ConvexHullMesh[RandomReal[1, {5, 3}]]

Wolfram Language code: MeshCoordinates[%]

A 3D MeshRegion:

Wolfram Language code: DelaunayMesh[RandomReal[1, {5, 3}]]

Wolfram Language code: MeshCoordinates[%]

Coordinates that are not used in primitives do not appear in MeshCoordinates:

Wolfram Language code: MeshRegion[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}, Polygon[{1, 2, 3}]]

Wolfram Language code: MeshCoordinates[%]

Applications (2)

Create a GraphicsComplex from a 2D MeshRegion:

Wolfram Language code: ℛ = DelaunayMesh[RandomReal[1, {25, 2}]]

The indices given in MeshCells correspond to MeshCoordinates:

Wolfram Language code:

pts = MeshCoordinates[ℛ];
polys = MeshCells[ℛ, 2];

Create the GraphicsComplex:

Wolfram Language code: Graphics[{FaceForm[LightRed], EdgeForm[Gray], GraphicsComplex[pts, polys]}]

Extract the lines from a MeshRegion to make a wireframe mesh:

Wolfram Language code: ℛ = DelaunayMesh[RandomReal[1, {8, 3}]]

The indices given in MeshCells correspond to MeshCoordinates:

Wolfram Language code:

pts = MeshCoordinates[ℛ];
lines = MeshCells[ℛ, 1];

Create the wireframe mesh:

Wolfram Language code: MeshRegion[pts, lines]

Properties & Relations (2)

The number of coordinate points is given by MeshCellCount[mreg,0]:

Wolfram Language code: mr = DelaunayMesh[RandomReal[1, {25, 2}]]

Wolfram Language code: {Length[MeshCoordinates[mr]], MeshCellCount[mr, 0]}

The indices in MeshCells refer to the MeshCoordinates:

Wolfram Language code: mr = MeshRegion[{{0, 0}, {1, 0}, {0, 1}}, Triangle[{1, 2, 3}]]

Wolfram Language code: l = MeshCells[mr, {1, 1}]

Wolfram Language code: Show[mr, Graphics[{Red, Thick, GraphicsComplex[MeshCoordinates[mr], l]}]]

Possible Issues (1)

When a coordinate in MeshRegion is unused, it does not appear in MeshCoordinates:

Wolfram Language code: mr = MeshRegion[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}, Polygon[{1, 2, 4}]]

Wolfram Language code: MeshCoordinates[mr]

The cell indices still refer to MeshCoordinates, not the input coordinates:

Wolfram Language code: MeshCells[mr, 2]

Top