WOLFRAM

Wolfram Language & System Documentation Center

Mouseover[expr,over]

represents an object that displays as over when the mouse pointer is over it, and as expr otherwise.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
Alignment  
Background  
BaselinePosition  
FrameMargins  
ImageMargins  
ImageSize  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
History
Cite this Page

Mouseover

Mouseover[expr,over]

represents an object that displays as over when the mouse pointer is over it, and as expr otherwise.

Details and Options

Examples

open all close all

Basic Examples  (1)

Change from off to on when the mouse is over the expression:

Wolfram Language code: Mouseover[off, on]

Scope  (4)

Use anywhere in a formula:

Wolfram Language code: Mouseover[x, Graphics[Disk[], ImageSize -> 50]]
Wolfram Language code: 1 / Mouseover[x, Graphics3D[Sphere[], ImageSize -> 50]]
Wolfram Language code: Grid[{{a, Mouseover[x, Grid[{{e, f}, {g, h}}]]}, {c, d}}]
Wolfram Language code: Expand[(Mouseover[x, Style[xxxx, Red]] + y) ^ 3]

Use anywhere in a graphic:

Wolfram Language code: Graphics[Mouseover[Disk[], Circle[]], ImageSize -> 50]
Wolfram Language code: Graphics[Table[Mouseover[Point[p], {Point[p], Arrowheads[.1], Arrow[{Scaled[{1, 1}], p}]}], {p, RandomReal[1, {10, 2}]}]]

ImageSize->All keeps the overall size constant regardless of which expression is visible:

Wolfram Language code: Row[{"xxx", Mouseover["A very long string.", "Short!"], "xxx"}]
Wolfram Language code: Row[{"xxx", Mouseover["A very long string.", "Short!", ImageSize -> All], "xxx"}]

Use Dynamic to recompute the tooltip every time it is looked at:

Wolfram Language code: Mouseover[date, Dynamic[DateString[], UpdateInterval -> 1]]

Options  (6)

Alignment  (1)

Align within Mouseover:

Wolfram Language code: Grid[Table[Framed[Mouseover[x + y, Style[x + y, Red], ImageSize -> {50, 25}, Alignment -> {w, h}]], {h, {Top, Center, Bottom}}, {w, {Left, Center, Right}}]]

Background  (1)

Change the background color:

Wolfram Language code: Mouseover[x + y, Style[x + y, Red], ImageSize -> {30, 15}, Background -> Gray]

BaselinePosition  (1)

Align with surrounding text:

Wolfram Language code: Row[Table[Framed@Mouseover[x + y, Style[x + y, Red], BaselinePosition -> p], {p, {Top, Center, Bottom}}], " xxx "]

FrameMargins  (1)

Add margins to Mouseover:

Wolfram Language code: Table[Framed[Mouseover[x + y, Style[x + y, Red], FrameMargins -> m]], {m, {0, 10, 20}}]

ImageMargins  (1)

Add margins to Mouseover:

Wolfram Language code: Table[Framed[Mouseover[x + y, Style[x + y, Red], ImageMargins -> m]], {m, {0, 10, 20}}]

ImageSize  (1)

Control the overall size of Mouseover:

Wolfram Language code: Grid[Table[Framed[Mouseover[x + y, Style[x + y, Red], ImageSize -> {w, h}]], {h, {30, 50, 70}}, {w, {50, 70, 100}}]]

Applications  (1)

Use Mouseover to find the rule number of a particular CellularAutomaton:

Wolfram Language code: Table[Mouseover[ArrayPlot[CellularAutomaton[n, {{1}, 0}, {10, All}], ImageSize -> 50], n, Alignment -> Center, ImageSize -> All], {n, 64}]

Properties & Relations  (1)

Mouseover changes the expression itself:

Wolfram Language code: Mouseover[x + y, label]

StatusArea presents the label in the status area:

Wolfram Language code: StatusArea[x + y, label]

Tooltip presents the label in a popup box:

Wolfram Language code: Tooltip[x + y, label]

Possible Issues  (1)

If the mouseover is smaller than the original object, there can be an oscillation:

Wolfram Language code: Row[{"xxx", Mouseover[1000, 1], "xxx"}]

With ImageSize->All space is always left for the largest object:

Wolfram Language code: Row[{"xxx", Mouseover[1000, 1, ImageSize -> All], "xxx"}]

Neat Examples  (1)

Wolfram Language code: Table[Mouseover[Graphics[Circle[], ImageSize -> RandomReal[100]], Graphics[Disk[], ImageSize -> RandomReal[100]]], {5}]
Wolfram Research (2007), Mouseover, Wolfram Language function, https://reference.wolfram.com/language/ref/Mouseover.html.

Text

Wolfram Research (2007), Mouseover, Wolfram Language function, https://reference.wolfram.com/language/ref/Mouseover.html.

CMS

Wolfram Language. 2007. "Mouseover." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Mouseover.html.

APA

Wolfram Language. (2007). Mouseover. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Mouseover.html

BibTeX

@misc{reference.wolfram_2026_mouseover, author="Wolfram Research", title="{Mouseover}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Mouseover.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_mouseover, organization={Wolfram Research}, title={Mouseover}, year={2007}, url={https://reference.wolfram.com/language/ref/Mouseover.html}, note=[Accessed: 12-June-2026]}