MusicChord
MusicChord[p]
returns a chord with the specified pitch list p.
MusicChord[p,d]
returns a chord with the specified pitch list p and duration d.
MusicChord[p,d,properties]
returns a chord with the specified property association properties.
MusicChord[music,p,d,properties]
returns a chord with properties inherited from another chord music.
Details and Options
- MusicChord represents a musical chord, whose defining characteristics are its pitch list and its duration.
- MusicChord represents a musical chord, whose defining characteristics are its pitch list and its duration.
- The pitch list p can be specified using:
-
name a string represanting a named chord (e.g. "CMajor") {p1,p2,…} a list of pitches as MusicPitch {i1,i2,…} a list of intervals as MusicInterval - Use MusicChord["Names"] to list supported chord names.
- The association properties can contain the following keys:
-
"Duration" chord duration as MusicDuration "Bass" lowest note of the chord "IntervalList" list of intervals included in the chord as MusicInterval "Inversion" inversion number of the chord "Name" common name of the chord "NameWithRoot" name of the chord including the root and bass notes "PitchList" list of pitches included in the chord as MusicPitch "Root" pitch of the root of the chord as MusicPitch "SoundVolume" volume at which the chord is going to be played "Style" metadata about the chord "TieType" whether this chord is tied to an adjacent note - For a music chord object obj, any of the above properties can be obtained using obj["prop"]. Use obj["PropertyAssociation"] to retrieve the values of all available properties.
- Possible "TieType" values are:
-
"NotTied" the current note is not tied "TiedAfter" the note is tied to the one after it "TiedBefore" the note is tied to the one before it "TiedBeforeAfter" the note is tied both to the one after and the one before it - Possible "Style" values include:
-
"Staccato" the playback duration is reduced to 0.5 of the original » "Staccatissimo" the playback duration is reduced to 0.25 of the original » "Arpeggio" the playback staggers the notes of the chord starting from the lowest pitch » "DownArpeggio" the playback staggers the notes of the chord starting from the highest pitch »
Examples
open all close allBasic Examples (6)
Construct the music chord with the specified common name:
MusicChord["CMajor"]Construct the music chord with a specified name and duration:
MusicChord["CMajor", 1 / 2]Specify the duration using its common name:
MusicChord["CMajor", "Half"]Specify the duration using a MusicDuration object:
MusicChord["CMajor", MusicDuration[1 / 8]]Construct a music chord with an explicit pitch list:
MusicChord[{"E4", "C5", "G5"}]Construct a music chord from a list of music intervals:
MusicChord[{MusicInterval[4], MusicInterval[5]}]Construct a chord with properties specified in an Association:
MusicChord[<|"Root" -> "D", "Inversion" -> 2|>]Construct a chord with default properties inherited from another MusicChord:
m = MusicChord["CMajor"]MusicChord[m, 1 / 2, <|"Inversion" -> 1|>]Scope (9)
m = MusicChord["D4Major", 1 / 2];
m["Properties"]List all available properties with their values:
m["PropertyAssociation"]//DatasetUse MusicChord["Names"] to see the list of supported chord names:
MusicChord["Names"]//ShortMany chord types are supported:
MusicChord /@ {"Minor", "Diminished"}The root note of a chord can be specified in its name:
MusicChord["D4Major"]Alternatively, it can be passed separately using an association with a "Root" key:
MusicChord[<|"Name" -> "Major", "Root" -> MusicPitch@"D4"|>]The bass note of a chord can be specified in its name:
MusicChord["D4Major/A3"]Alternatively, it can be passed separately using an association with a "Bass" key:
MusicChord[<|"Name" -> "D4Major", "Bass" -> MusicPitch@"A3"|>]Specify the inversion of a chord using an association with an "Inversion" key:
MusicChord[<|"Name" -> "D4Major", "Inversion" -> 2|>]Use the "TieType" property to tie one or more notes of a chord to the previous or following events:
MusicScore[{MusicChord[{"C", "E", "G"}, <|"TieType" -> {"NotTied", "TiedAfter", "NotTied"}|>], MusicNote["E", <|"TieType" -> "TiedBefore"|>]}]If a chord spans multiple measures, it is automatically split and its "TieType" is modified:
MusicScore[{MusicChord["Major", 2]}]chords = Cases[%, _MusicChord, Infinity]Through[chords["TieType"]]Use MusicChord["Styles"] to see the list of recognized values for the "Style" property:
MusicChord["Styles"]MusicMeasure@MusicChord[<|"Name" -> "G", "Duration" -> 1, "Style" -> "Arpeggio"|>]The "Arpeggio" style is equivalent to "UpArpeggio":
MusicMeasure@MusicChord[<|"Name" -> "G", "Duration" -> 1, "Style" -> "UpArpeggio"|>]Create an arpeggiated chord where the first note is the highest one:
MusicMeasure@MusicChord[<|"Name" -> "G", "Duration" -> 1, "Style" -> "DownArpeggio"|>]Play a chord with a "Staccato" style:
MusicMeasure@{MusicChord[<|"Name" -> "G", "Duration" -> 1 / 2, "Style" -> "Staccato"|>], MusicNote["A", 1 / 2]}The playback duration of the chord is half of the original duration.
Play a chord with a "Staccatissimo" style:
MusicMeasure@{MusicChord[<|"Name" -> "G", "Duration" -> 1 / 2, "Style" -> "Staccatissimo"|>], MusicNote["A", 1 / 2]}The playback duration of the chord is one-quarter of the original duration.
Options (1)
Properties & Relations (5)
Use MusicMeasurements to compute the quality of a chord:
MusicMeasurements[MusicChord["Cm7b5"], "Quality"]Use MusicMeasurements to find the name of a chord given a list of pitches:
MusicMeasurements[MusicPitch /@ {"C3", "G5", "D#5", "Bb5"}, "MatchingChords"]Use MusicTransform to separate chords in notes in different voices:
v = MusicVoice[{MusicChord["G", 1 / 2], MusicChord["C", 1 / 2]}]
MusicTransform[v, "Separate"]Use the "Combine" transformation to combine the notes into chords:
MusicTransform[%, "Combine"]MusicMeasurements[%, "NoteList"]Convert a MusicChord object to Audio:
Audio@MusicChord["G", 1 / 2]Use MusicChord as a Sound primitive:
Sound[{MusicChord["G", 1 / 2]}]Neat Examples (2)
Create a chord by stacking perfect fourth intervals:
MusicChord[NestList[# + MusicInterval["PerfectFourth"]&, MusicPitch["C"], 3]]toPosition[pc_] := With[{angle = -pc / 12 * 2 Pi + Pi / 2}, AngleVector[angle]]
visualize[in_] := visualize[Sort@in["PitchList", All, "PitchClass"], in["Name"]];
visualize[pitchClasses_List, name_] := Module[{points = toPosition /@ pitchClasses}, Labeled[Graphics[{Line[Append[points, points[[1]]]], RGBColor[0.922526, 0.385626, 0.209179], PointSize[.1], Point /@ points, AxisObject[Circle[], {0, 12}, Ticks -> IconizedObject[«ticks»]]}], name]
]Multicolumn[visualize /@ {MusicChord["Cm7"], MusicChord["CmΔ9"], MusicChord["CM7#11"], MusicChord["CM13"]}]Text
Wolfram Research (2026), MusicChord, Wolfram Language function, https://reference.wolfram.com/language/ref/MusicChord.html.
CMS
Wolfram Language. 2026. "MusicChord." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/MusicChord.html.
APA
Wolfram Language. (2026). MusicChord. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MusicChord.html