WOLFRAM

Wolfram Language & System Documentation Center

Sound[primitives]

represents a sound.

Sound[primitives,t]

specifies that the sound should have duration t.

Sound[primitives,{tmin,tmax}]

specifies that the sound should extend from time tmin to time tmax.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Time Sequences  
Style Directives  
Applications  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Workflows
Related Links
History
Cite this Page

Sound

Sound[primitives]

represents a sound.

Sound[primitives,t]

specifies that the sound should have duration t.

Sound[primitives,{tmin,tmax}]

specifies that the sound should extend from time tmin to time tmax.

Details and Options

  • Lists containing the following primitives can be used:
  • SampledSoundFunction[f,n,r]amplitude levels generated by a function
    SampledSoundList[{a1,a2,…},r]amplitude levels given in a list
    SoundNote[spec,…]a music-like note
    MusicNote[…]a symbolic music note
    MusicChord[…]a symbolic music chord
    MusicScore[…]a symbolic music score
    Sound[prims,t]a sound scaled to have duration t
    Sound[prims,{tmin,tmax}]a sound played over the time interval tmin to tmax
  • Primitives with duration specifications are played consecutively in sequence, independent of primitives with explicit time specifications.
  • When primitives prims appear in Sound[prims,tspec], the sequence of durations and time specifications in prims are rescaled and shifted to fit into the time interval defined by tspec.
  • For the outermost Sound object, times are by default taken to be given in absolute seconds.
  • For inner Sound objects, times can be given as Scaled[r].
  • Sound[prims,Scaled[r]] will slow down prims by a factor r.
  • Mixed into lists of sound primitives can be the following SoundNote directives:
  • "style"use the specified style
    opt->valueuse the specified option setting
  • The possible styles and options are those for SoundNote.
  • Nested lists of sound primitives and directives can be given. Directive specifications normally remain in effect only until the end of the list which contains them.
  • A list containing only sound directives is treated as if its elements were directly inserted into an enclosing list.
  • Style[obj,opts] can be used to apply the options or directives opts to obj.
  • Sound can be played using EmitSound.
  • Sound[…] is displayed in StandardForm as a button containing a graphic representing the sound. Clicking the button plays the sound, preempting any other sounds that are already playing.
  • In InputForm, Sound[…] is displayed as an explicit list of primitives.
  • The option SoundVolume->v specifies a relative sound volume v for a note.
  • The following options can be given:
  • SoundVolume1relative sound volume

Examples

open all close all

Basic Examples  (2)

Represent a sound consisting of a sequence of two notes:

Wolfram Language code: Sound[{SoundNote["C"], SoundNote["G"]}]

Represent a sound consisting of a sequence of two waveforms:

Wolfram Language code: Sound[{Play[Sin[1000t(1 + t ^ 2)], {t, 0, .2}], Play[Sin[500t (1 + t ^ 3)], {t, 0, .5}]}]

Scope  (7)

Time Sequences  (5)

Represent a sequence of notes, with each note taking 1 second:

Wolfram Language code: Sound[Table[SoundNote[i], {i, 0, 12}]]

Represent a sequence of notes, with the whole sequence lasting 1.5 seconds:

Wolfram Language code: Sound[Table[SoundNote[i], {i, 0, 12}], 1.5]

Represent a sequence of notes to be played between and :

Wolfram Language code: s1 = Sound[Table[SoundNote[i], {i, 0, 12}], {0, 1.5}]

Represent a sequence of notes to be played between and :

Wolfram Language code: s2 = Sound[Table[SoundNote[12 - i], {i, 0, 12}], {0.5, 2}]

Combine the two sound sequences:

Wolfram Language code: Sound[{s1, s2}]

Superimpose three time-warped versions of a sound:

Wolfram Language code: s = Sound[Table[SoundNote[i], {i, 0, 12}], 1]
Wolfram Language code: Sound[{Sound[s, {0, 2}], Sound[s, {.5, 1.5}], Sound[s, {.7, .9}]}]

Use a list of MusicNote objects:

Wolfram Language code: Sound[Table[MusicNote[i], {i, 65, 70}]]

Style Directives  (2)

Represent a sequence of notes to be rendered in accordion style:

Wolfram Language code: Sound[{"Accordion", Table[SoundNote[i], {i, 5}]}]

Combine two note sequences with different instrument styles:

Wolfram Language code: s = Sound[Table[SoundNote[i], {i, 0, 12}], 1]
Wolfram Language code: Sound[{"Flute", Sound[s, {0, 1}], "Trumpet", Sound[s, {.2, 1.3}]}]

Applications  (3)

Create an algorithmic composition from a cellular automaton pattern:

Wolfram Language code: Sound[SoundNote[DeleteCases[3 Range[21]Reverse[#], 0] - 24, .1]& /@ Transpose[CellularAutomaton[90, {{1}, 0}, 20]]]

Generate a simple WolframTones-like composition:

Wolfram Language code: Sound[SoundNote[#, 1 / 6, "Warm"]& /@ (Pick[{0, 5, 9, 12, 16, 21}, #, 1]& /@ CellularAutomaton[30, {{1, 0, 0, 0, 0, 0}, 0}, 13, {13, 5}])]

Record a sound:

Wolfram Language code: data = SystemDialogInput["RecordSound"]

Squash the sound to play over 0.8 seconds:

Wolfram Language code: Sound[data, .8]

Possible Issues  (1)

Passing music primitives directly to sound will convert them to SoundNote objects:

Wolfram Language code: Sound[MusicNote["D"]]//InputForm
Wolfram Language code: Sound[MusicScore[{"C", "D", "G", "F"}]]//InputForm

Wrapping music objects in lists will preserve them:

Wolfram Language code: Sound[{MusicNote["D"]}]//InputForm
Wolfram Language code: Sound[{MusicScore[{"C", "D", "G", "F"}]}]//InputForm

Neat Examples  (1)

Play a random sequence of notes from different instruments:

Wolfram Language code: Sound[SoundNote[#, 1, RandomChoice[{"Piano", "Cello", "Tuba"}]]& /@ RandomInteger[12, 30], 4]

Make each note have a random duration:

Wolfram Language code: Sound[SoundNote[#, RandomReal[2], RandomChoice[{"Piano", "Cello", "Tuba"}]]& /@ RandomInteger[12, 30], 4]
Wolfram Research (1991), Sound, Wolfram Language function, https://reference.wolfram.com/language/ref/Sound.html (updated 2026).

Text

Wolfram Research (1991), Sound, Wolfram Language function, https://reference.wolfram.com/language/ref/Sound.html (updated 2026).

CMS

Wolfram Language. 1991. "Sound." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/Sound.html.

APA

Wolfram Language. (1991). Sound. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Sound.html

BibTeX

@misc{reference.wolfram_2026_sound, author="Wolfram Research", title="{Sound}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/Sound.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_sound, organization={Wolfram Research}, title={Sound}, year={2026}, url={https://reference.wolfram.com/language/ref/Sound.html}, note=[Accessed: 13-June-2026]}