WOLFRAM

Wolfram Language & System Documentation Center

NeighborhoodGraph[g,v]

gives the graph neighborhood of a vertex v in the graph g.

NeighborhoodGraph[g,{a1,a2,…}]

gives the graph neighborhood of the ai that can be vertices, edges, or subgraphs of g.

NeighborhoodGraph[g,patt]

gives the graph neighborhood of the vertices and edges that match the pattern patt.

NeighborhoodGraph[g,…,d]

gives the neighborhood up to distance d.

NeighborhoodGraph[{vw,…},…]

uses rules vw to specify the graph g.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

NeighborhoodGraph

NeighborhoodGraph[g,v]

gives the graph neighborhood of a vertex v in the graph g.

NeighborhoodGraph[g,{a1,a2,…}]

gives the graph neighborhood of the ai that can be vertices, edges, or subgraphs of g.

NeighborhoodGraph[g,patt]

gives the graph neighborhood of the vertices and edges that match the pattern patt.

NeighborhoodGraph[g,…,d]

gives the neighborhood up to distance d.

NeighborhoodGraph[{vw,…},…]

uses rules vw to specify the graph g.

Details and Options

  • The neighborhood graph for a vertex v is given by vertices adjacent to v and the edges connecting them.
  • The neighborhood graph for an edge e is the neighborhood graph for the vertices of e.
  • The neighborhood graph for a subgraph h is the neighborhood graph for the vertices in h.
  • The neighborhood graph at distance d is the neighborhood graph for the vertices of the neighborhood graph at distance d-1.
  • The default value for d is 1.
  • NeighborhoodGraph works with undirected graphs, directed graphs, multigraphs, and mixed graphs.

Examples

open all close all

Basic Examples  (2)

Give the neighborhood from vertex 1 in a graph:

Wolfram Language code: g = PetersenGraph[5, 2]
Wolfram Language code: HighlightGraph[g, {NeighborhoodGraph[g, 1], Labeled[1, 1]}]

From a set of vertices:

Wolfram Language code: HighlightGraph[g, {NeighborhoodGraph[g, {1, 2}], Labeled[#, #]& /@ {1, 2}}]

Give the neighborhood up to distance k from the vertices:

Wolfram Language code: GridGraph[{4, 4}]
Wolfram Language code: Table[HighlightGraph[%, NeighborhoodGraph[%, 1, k]], {k, 4}]

Scope  (8)

NeighborhoodGraph works with undirected graphs:

Wolfram Language code: GridGraph[{3, 4}, VertexSize -> {1 -> 0.2, 11 -> 0.2}]
Wolfram Language code: HighlightGraph[%, NeighborhoodGraph[%, {1, 11}]]

Directed graphs:

Wolfram Language code: g = [image];
Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, {1, 11}]]

Multigraphs:

Wolfram Language code: g = [image];
Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, {1, 11}]]

Mixed graphs:

Wolfram Language code: g = [image];
Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, {1, 11}]]

NeighborhoodGraph works with vertices:

Wolfram Language code: g = GridGraph[{5, 5}]
Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, 1]]

Edges:

Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, 16]]

Use rules to specify the graph:

Wolfram Language code: g = {1 -> 2, 1 -> 3, 2 -> 4, 3 -> 4, 3 -> 5, 4 -> 6, 5 -> 6};
Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, 1]]

Use patterns to specify a set of vertices:

Wolfram Language code: g = PetersenGraph[5, 2]
Wolfram Language code: NeighborhoodGraph[g, _ ? ((# < 3)&)]

NeighborhoodGraph works with large graphs:

Wolfram Language code: g = GridGraph[{10, 10, 10, 10}];
Wolfram Language code: NeighborhoodGraph[g, 1];//Timing

Applications  (2)

Highlight the neighborhood from the vertices in CompleteGraph:

Wolfram Language code: g = CompleteGraph[8, VertexSize -> {1 -> 0.2}];
Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, 1]]

CycleGraph:

Wolfram Language code: g = CycleGraph[8, VertexSize -> {1 -> 0.2}];
Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, 1]]

StarGraph:

Wolfram Language code: g = StarGraph[8, VertexSize -> {1 -> 0.2}];
Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, 1]]

GridGraph:

Wolfram Language code: v = {1, 15, 18};g = GridGraph[{6, 6}, VertexSize -> 0.2];
Wolfram Language code: HighlightGraph[g, MapThread[Style[NeighborhoodGraph[g, #1], #2]&, {{1, 15, 18}, {Blue, Red, Green}}]]

CompleteKaryTree:

Wolfram Language code: g = CompleteKaryTree[3, 3, VertexSize -> {1 -> 0.2}];
Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, 1]]

PathGraph:

Wolfram Language code: g = PathGraph[Range[20], VertexSize -> 0.2];
Wolfram Language code: HighlightGraph[g, MapThread[Style[NeighborhoodGraph[g, #1], #2]&, {{1, 6, 20}, {Blue, Red, Green}}]]

RandomGraph:

Wolfram Language code: g = RandomGraph[{10, 20}, VertexSize -> {1 -> 0.3}];
Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, 1]]

Manipulate the neighborhood of vertices:

Wolfram Language code: Manipulate[HighlightGraph[GridGraph[{5, 5}], NeighborhoodGraph[GridGraph[{5, 5}], i]], {i, 1, 25, 1}]

Properties & Relations  (2)

Use Subgraph to find the neighborhood graph of a set of vertices:

Wolfram Language code: g = GridGraph[{8, 12}]
Wolfram Language code: v = {28, 36, 37, 43};
Wolfram Language code: nbg = Subgraph[g, Join[v, AdjacencyList[g, v]]];

Highlight the subgraph:

Wolfram Language code: HighlightGraph[g, nbg, GraphHighlightStyle -> "DehighlightGray"]

This is equivalent to:

Wolfram Language code: NeighborhoodGraph[g, v]

The neighborhood of a vertex in a complete graph is the graph itself:

Wolfram Language code: CompleteGraph[8]
Wolfram Language code: NeighborhoodGraph[%, 1]

Neat Examples  (2)

Pick out random neighborhoods from a grid:

Wolfram Language code: g = GridGraph[{50, 75}];
Wolfram Language code: NeighborhoodGraph[g, RandomSample[VertexList[g], 35], 1]

Subtract random neighborhoods from a grid:

Wolfram Language code: g = GridGraph[{25, 50}];
Wolfram Language code: Subgraph[g, Complement[VertexList[g], VertexList[NeighborhoodGraph[g, RandomSample[VertexList[g], 25], 1]]]]
Wolfram Research (2010), NeighborhoodGraph, Wolfram Language function, https://reference.wolfram.com/language/ref/NeighborhoodGraph.html (updated 2015).

Text

Wolfram Research (2010), NeighborhoodGraph, Wolfram Language function, https://reference.wolfram.com/language/ref/NeighborhoodGraph.html (updated 2015).

CMS

Wolfram Language. 2010. "NeighborhoodGraph." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2015. https://reference.wolfram.com/language/ref/NeighborhoodGraph.html.

APA

Wolfram Language. (2010). NeighborhoodGraph. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/NeighborhoodGraph.html

BibTeX

@misc{reference.wolfram_2026_neighborhoodgraph, author="Wolfram Research", title="{NeighborhoodGraph}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/NeighborhoodGraph.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_neighborhoodgraph, organization={Wolfram Research}, title={NeighborhoodGraph}, year={2015}, url={https://reference.wolfram.com/language/ref/NeighborhoodGraph.html}, note=[Accessed: 12-June-2026]}