WOLFRAM

Wolfram Language & System Documentation Center

NetDecoder["name"]

represents a decoder that takes a net representation and decodes it into an expression of a given form.

NetDecoder[{"name",…}]

represents a decoder with additional parameters specified.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Properties & Relations  
Neat Examples  
See Also
Tech Notes
Related Guides
History
Cite this Page

NetDecoder   

Listing of Net Decoders »

NetDecoder["name"]

represents a decoder that takes a net representation and decodes it into an expression of a given form.

NetDecoder[{"name",…}]

represents a decoder with additional parameters specified.

Details

  • NetDecoder[…][array] gives the specified decoded form for array.
  • NetDecoder[…][{array1,array2, …}] explicitly computes outputs for each of the arrayi.
  • NetDecoder[…][…,prop] can be used to calculate a specific property for the input data.
  • NetDecoder[…][…,"Properties"] gives the possible properties.
  • Possible named decoders include:
  • "Boolean"decode 1 and 0 as True and False
    "Characters"decode probability vectors as a string of characters
    "Class"decode probability arrays as class labels
    "CTCBeamSearch"decode sequences of probability vectors trained with a CTCLossLayer
    "Function"decode using a custom function
    "Image"decode a rank-3 array as a 2D image
    "Image3D"decode a rank-4 array as a 3D image
    "SubwordTokens"decode probability vectors as a string of subword tokens
    "Tokens"decode probability vectors as a string of tokens
  • A NetDecoder object can be attached to an output port of a net by specifying "port"->NetDecoder[…] when constructing the net. Specifying "port"->"type" will create a decoder of the given type and attach it.
  • When a decoder is attached to the output of a net, net[input] will return the decoded output of the net. The raw output of the net can be obtained by specifying net[input,None].
  • NetDecoder is not involved in training done by NetTrain. However, when NetTrain is allowed to automatically attach a loss layer and a NetDecoder is attached to the output of the net, a NetEncoder of the same type will be created for the "Target" input of the loss layer.
  • NetDecoder[NetEncoder[…]] will create a decoder based on the parameters of an existing encoder, when it is possible.

Examples

open all close all

Basic Examples  (1)

Create a class decoder:

Wolfram Language code: dec = NetDecoder[{"Class", {"a", "b", "c"}}]

Use it on a probability vector to make a class prediction:

Wolfram Language code: dec[{0.1, 0.5, .4}]

Predict the class for a batch of inputs:

Wolfram Language code: dec[{{0.1, 0.5, .4}, {0.9, 0.1, 0.0}}]

Scope  (1)

Create a pooling layer with an image decoder attached to the output port:

Wolfram Language code: layer = PoolingLayer[3, "Output" -> NetDecoder["Image"]]

The layer now returns an image when applied to an input array:

Wolfram Language code: layer[RandomReal[1, {3, 50, 79}]]

Properties & Relations  (2)

Decoders can be attached to a net to automatically decode the output of the net when the net is applied to data:

Wolfram Language code: dec = NetDecoder[{"Class", {a, b, c}}]; net = SoftmaxLayer["Output" -> dec]

Apply the net to an input:

Wolfram Language code: net[{1, 2, 3}]

Apply the net to a batch of inputs:

Wolfram Language code: net[{{3, 2, 1}, {1, 2, 3}}]

Calculate a property of the decoder for an input:

Wolfram Language code: net[{3, 2, 1}, "Probabilities"]

Calculate a property on a batch of inputs:

Wolfram Language code: net[{{1, 1, 1}, {1, 3, 9}}, "Entropy"]

NetTrain will automatically try to attach a decoder when a net is not fully specified. Automatic attachment of a class decoder:

Wolfram Language code: net = NetTrain[NetChain[{LinearLayer[], SoftmaxLayer[]}], {1.1 -> "a", 2.1 -> "a", 3.3 -> "b", 4.1 -> "b"}]
Wolfram Language code: NetExtract[net, "Output"]

Automatic attachment of an image decoder:

Wolfram Language code: net = NetTrain[LinearLayer[], {True -> [image], False -> [image], True -> [image], False -> [image]}]
Wolfram Language code: NetExtract[net, "Output"]
Wolfram Language code: net[True]

Neat Examples  (1)

Use an encoder and a decoder to produce an interactive display of the output of two successive convolutions:

Wolfram Language code: net = NetChain[{ ConvolutionLayer[2, 3, "Dilation" -> 3], Tanh, ConvolutionLayer[3, 3, "Dilation" -> 3], Tanh }, "Input" -> NetEncoder[{"Image", 64}], "Output" -> "Image"]
Wolfram Language code: net2 = NetInitialize[net, Method -> {"Random", "Weights" -> NormalDistribution[0.05, 0.2], "Biases" -> 0.3}]; Dynamic[Image[ImageAdjust@net2 @ CurrentImage[], Magnification -> 4]]
Wolfram Research (2016), NetDecoder, Wolfram Language function, https://reference.wolfram.com/language/ref/NetDecoder.html (updated 2022).

Text

Wolfram Research (2016), NetDecoder, Wolfram Language function, https://reference.wolfram.com/language/ref/NetDecoder.html (updated 2022).

CMS

Wolfram Language. 2016. "NetDecoder." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/NetDecoder.html.

APA

Wolfram Language. (2016). NetDecoder. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/NetDecoder.html

BibTeX

@misc{reference.wolfram_2026_netdecoder, author="Wolfram Research", title="{NetDecoder}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/NetDecoder.html}", note=[Accessed: 15-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_netdecoder, organization={Wolfram Research}, title={NetDecoder}, year={2022}, url={https://reference.wolfram.com/language/ref/NetDecoder.html}, note=[Accessed: 15-June-2026]}