WOLFRAM

Wolfram Language & System Documentation Center

NicholsGridLines

is an option to NicholsPlot that specifies contours of constant magnitude and constant phase of the closed-loop system.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
See Also
Related Guides
History
Cite this Page

NicholsGridLines

NicholsGridLines

is an option to NicholsPlot that specifies contours of constant magnitude and constant phase of the closed-loop system.

Details

  • The following settings can be given:
  • Noneno contours drawn
    Automaticcontours chosen automatically
    {magnitude,phase}contours specified by magnitude and phase are drawn
  • The magnitude values are the absolute values.
  • The phase values are in radians.
  • The following settings can be given for magnitude and phase:
  • Noneno contours drawn
    Automaticcontours chosen automatically
    {c1,c2,…}draw the contours ci
    {{c1,style1,r1},…}contours with specified styles and regions
  • The default style of a magnitude contour is Dashed, and the default style of a phase contour is Dotted.
  • The setting ri specifies that a point should be included if ri[x,y,ci] yields True.
  • The default value of ri is Automatic.

Examples

open all close all

Basic Examples  (1)

Show the closed-loop magnitude and phase contours:

Wolfram Language code: NicholsPlot[TransferFunctionModel[{{{5*(-1 + s)}}, s^2*(4 + s + s^2)}, s], NicholsGridLines -> Automatic]

Scope  (8)

Choose contours automatically:

Wolfram Language code: NicholsPlot[TransferFunctionModel[{{{1}}, s*(1 + s)*(1 + 2*s)}, s], NicholsGridLines -> Automatic]

Show specific magnitude and phase contours:

Wolfram Language code: NicholsPlot[TransferFunctionModel[{{{1}}, s*(1 + s)*(1 + 2*s)}, s], NicholsGridLines -> {{0.01, 0.05, 0.2, 0.5, 1.1, 1.25, 2}, Range[-60, 60, 10]Degree}]

Use different contour styles:

Wolfram Language code: NicholsPlot[TransferFunctionModel[{{{1}}, s*(1 + s)*(1 + 2*s)}, s], NicholsGridLines -> {{0.01, 0.05, 0.2, 0.5, {1.1, Directive[Dashed, Green]}, {1.25, Directive[Dashed, Yellow]}, {2, Directive[Dashed, Red]}}, {{-60 Degree, Green}, -50 Degree, -40 Degree, {-30 Degree, Yellow}, -20Degree, -10Degree, 0, 10Degree, 20Degree, {30Degree, Yellow}, 40Degree, 50Degree, {60Degree, Green}}}]

Specify different regions:

Wolfram Language code: NicholsPlot[TransferFunctionModel[{{{1}}, s*(1 + s)*(1 + 2*s)}, s], NicholsGridLines -> {{0.01, 0.05, 0.2, 0.5, {1.1, Directive[Dashed, Green], #2 > -5&}, {1.25, Directive[Dashed, Yellow]}, {2, Directive[Dashed, Red]}}, {{-60 Degree, Green}, -50 Degree, -40 Degree, {-30 Degree, Yellow, True&}, -20Degree, -10Degree, 0, 10Degree, 20Degree, {30Degree, Yellow, True&}, 40Degree, 50Degree, {60Degree, Green}}}]

Magnitude contours with specific dB values:

Wolfram Language code: NicholsPlot[TransferFunctionModel[{{{1}}, s*(1 + s)*(1 + 2*s)}, s], NicholsGridLines -> {10^(#/20)& /@ {10, 5, 3, 2, 1, -1, -2, -5, -10, -20, -35}, None}]

Specify contours with phase from -70 to 70 degrees in increments of 5:

Wolfram Language code: NicholsPlot[TransferFunctionModel[{{{1}}, s*(1 + s)*(1 + 2*s)}, s], NicholsGridLines -> {None, Range[-70, 70, 5] Degree}]

The contours depend on the type of feedback:

Wolfram Language code: GraphicsRow@Table[NicholsPlot[TransferFunctionModel[{{{1}}, s*(1 + s)*(1 + 2*s)}, s], NicholsGridLines -> Automatic, FeedbackType -> f, PlotLabel -> Style["Feedback Type: " <> ToString@f, Italic]], {f, {"Negative", "Positive", None}}]

A discrete-time system:

Wolfram Language code: NicholsPlot[TransferFunctionModel[{{{0.25 + z}}, (-0.25 + z)*z}, z, SamplingPeriod -> 1], NicholsGridLines -> Automatic]

Applications  (1)

Estimate closed-loop magnitude and phase values at various frequencies:

Wolfram Language code: NicholsPlot[TransferFunctionModel[{{{30}}, s*(1 + s)*(2 + s)* (3 + s)}, s], Mesh -> {{0.5, 1, 2, 4}}, MeshStyle -> Directive[PointSize[Medium], Red], NicholsGridLines -> Automatic]
Wolfram Research (2010), NicholsGridLines, Wolfram Language function, https://reference.wolfram.com/language/ref/NicholsGridLines.html.

Text

Wolfram Research (2010), NicholsGridLines, Wolfram Language function, https://reference.wolfram.com/language/ref/NicholsGridLines.html.

CMS

Wolfram Language. 2010. "NicholsGridLines." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/NicholsGridLines.html.

APA

Wolfram Language. (2010). NicholsGridLines. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/NicholsGridLines.html

BibTeX

@misc{reference.wolfram_2026_nicholsgridlines, author="Wolfram Research", title="{NicholsGridLines}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/NicholsGridLines.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_nicholsgridlines, organization={Wolfram Research}, title={NicholsGridLines}, year={2010}, url={https://reference.wolfram.com/language/ref/NicholsGridLines.html}, note=[Accessed: 12-June-2026]}