WOLFRAM

Wolfram Language & System Documentation Center

Nor[e1,e2,…]

is the logical NOR function. It evaluates its arguments in order, giving False immediately if any of them are True, and True if they are all False.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

Nor

Nor[e1,e2,…]

is the logical NOR function. It evaluates its arguments in order, giving False immediately if any of them are True, and True if they are all False.

Details

  • Nor[e1,e2,…] can be input in StandardForm and InputForm as e_(1) nor e_(2) nor .... The character ⊽ can be entered as nor or \[Nor]. »
  • Nor[e1,e2,…] is equivalent to Not[Or[e1,e2,…]]. »
  • Nor has attribute HoldAll, and explicitly controls the evaluation of its arguments. In Nor[e1,e2,…] the e_(i) are evaluated in order, stopping if any one of them is found to be True. »
  • Nor gives symbolic results when necessary, removing initial arguments that are False.
  • Nor is not Flat.

Examples

open all close all

Basic Examples  (2)

Wolfram Language code: Nor[True, False]

Enter using nor:

Wolfram Language code: p⊽q
Wolfram Language code: InputForm[%]

Scope  (4)

Nor with explicit True or False arguments will simplify:

Wolfram Language code: Nor[x, True, z]
Wolfram Language code: Nor[x, False, z]

Nor evaluates its arguments in order, stopping when an argument evaluates to True:

Wolfram Language code: Nor[Print[1];True, Print[2];True]
Wolfram Language code: Nor[Print[1];False, Print[2];True]

Symbolic transformations may not preserve argument ordering or Nor operations:

Wolfram Language code: z⊽!x⊽!y
Wolfram Language code: Simplify[%]

TraditionalForm formatting:

Wolfram Language code: Nor[x, y, z]//TraditionalForm

Applications  (4)

Find the Nor of two regions:

Wolfram Language code: RegionPlot[Nor[x ^ 2 + y ^ 2 < 1, x + y > 0], {x, -2, 2}, {y, -2, 2}]

A cellular automaton based on Nor:

Wolfram Language code: ArrayPlot[Boole[CellularAutomaton[{Nor@@#&, {}}, RandomChoice[{True, False}, 40], 20]]]

Simplify trees involving Nor:

Wolfram Language code: NestList[Nor[#, #]&, p, 4]
Wolfram Language code: Simplify[%]

Find the area of the complement of the union of sets given by algebraic conditions:

Wolfram Language code: Integrate[Boole[Nor[x ^ 2 + y ^ 2 < 1, (x - 1) ^ 2 + y ^ 2 < 2]], {x, -3 / 2, 5 / 2}, {y, -2, 2}]

This shows the set:

Wolfram Language code: RegionPlot[Nor[x ^ 2 + y ^ 2 < 1, (x - 1) ^ 2 + y ^ 2 < 2], {x, -3 / 2, 5 / 2}, {y, -2, 2}]

Properties & Relations  (6)

Truth table for binary Nor:

Wolfram Language code: BooleanTable[{x, y, Nor[x, y]}, {x, y}]//Grid

Ternary Nor:

Wolfram Language code: BooleanTable[{x, y, z, Nor[x, y, z]}, {x, y, z}]//Grid

Zero-argument Nor is True:

Wolfram Language code: Nor[]

Nor with a single argument will return the negated argument regardless of value:

Wolfram Language code: Nor[2 + 2]

Use BooleanConvert to expand in terms of And and Not:

Wolfram Language code: BooleanConvert[Nor[p, q, r]]

The negation of Nor is equivalent to Or:

Wolfram Language code: BooleanConvert[!Nor[p, q, r]]

Nor of conditions in Boole functions:

Wolfram Language code: Boole[Nor[a, b, c]] - (1 - Boole[a])(1 - Boole[b])(1 - Boole[c])
Wolfram Language code: Simplify[%]
Wolfram Research (2000), Nor, Wolfram Language function, https://reference.wolfram.com/language/ref/Nor.html.

Text

Wolfram Research (2000), Nor, Wolfram Language function, https://reference.wolfram.com/language/ref/Nor.html.

CMS

Wolfram Language. 2000. "Nor." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Nor.html.

APA

Wolfram Language. (2000). Nor. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Nor.html

BibTeX

@misc{reference.wolfram_2026_nor, author="Wolfram Research", title="{Nor}", year="2000", howpublished="\url{https://reference.wolfram.com/language/ref/Nor.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_nor, organization={Wolfram Research}, title={Nor}, year={2000}, url={https://reference.wolfram.com/language/ref/Nor.html}, note=[Accessed: 12-June-2026]}