WOLFRAM

Wolfram Language & System Documentation Center

Xor[e1,e2,…]

is the logical XOR (exclusive OR) function. It gives True if an odd number of the ei are True, and the rest are False. It gives False if an even number of the ei are True, and the rest are False.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

Xor

Xor[e1,e2,…]

is the logical XOR (exclusive OR) function. It gives True if an odd number of the ei are True, and the rest are False. It gives False if an even number of the ei are True, and the rest are False.

Details

  • Xor[e1,e2,…] can be input in StandardForm and InputForm as e_(1) xor e_(2) xor .... The character ⊻ can be entered as xor or \[Xor].
  • Xor gives symbolic results when necessary, applying various simplification rules to them.
  • Unlike And, Nand, Or, and Nor, Xor must always test all its arguments, and so is not a control structure, and does not have attribute HoldAll.

Examples

open all close all

Basic Examples  (2)

Wolfram Language code: Xor[True, False]
Wolfram Language code: Xor[True, True]

Enter using xor:

Wolfram Language code: p⊻q

Scope  (4)

Xor is associative and commutative:

Wolfram Language code: Xor[Xor[x, y], z]
Wolfram Language code: Xor[y, x]

Do symbolic simplification:

Wolfram Language code: Simplify[Xor[True, x]]
Wolfram Language code: Simplify[Xor[x, x, y]]

Expand in terms of And, Or, and Not:

Wolfram Language code: LogicalExpand[Xor[x, y]]

TraditionalForm formatting:

Wolfram Language code: Xor[x, y, z]//TraditionalForm

Applications  (3)

Find the Xor of two regions in 2D:

Wolfram Language code: RegionPlot[Xor[x ^ 2 + y ^ 2 < 1, x + y > 0], {x, -2, 2}, {y, -2, 2}]

Find the Xor of three regions in 3D:

Wolfram Language code: RegionPlot3D[Xor[x > 0, y > 0, z > 0], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]

A cellular automaton based on Xor:

Wolfram Language code: ArrayPlot[Boole[CellularAutomaton[{Xor@@#&, {}}, {{True}, False}, 40]]]

Find the area of the symmetric difference of sets given by algebraic conditions:

Wolfram Language code: Integrate[Boole[Xor[x ^ 2 + y ^ 2 < 1, (x - 1) ^ 2 + y ^ 2 < 2]], {x, -Infinity, Infinity}, {y, -Infinity, Infinity}]//FullSimplify

This shows the set:

Wolfram Language code: RegionPlot[Xor[x ^ 2 + y ^ 2 < 1, (x - 1) ^ 2 + y ^ 2 < 2], {x, -1.5, 2.5}, {y, -2, 2}]

Properties & Relations  (3)

Truth table for binary Xor:

Wolfram Language code: BooleanTable[{x, y, Xor[x, y]}, {x, y}]//Grid

Ternary Xor:

Wolfram Language code: BooleanTable[{x, y, z, Xor[x, y, z]}, {x, y, z}]//Grid

Use BooleanConvert to expand in terms of And, Or, and Not:

Wolfram Language code: BooleanConvert[Xor[p, q, r]]

Xor of conditions in Boole functions:

Wolfram Language code: Boole[Xor[a, b, c]] - Mod[Boole[a] + Boole[b] + Boole[c], 2]
Wolfram Language code: Simplify[%]

Neat Examples  (2)

The Xor of disks on a circle:

Wolfram Language code: disk[m_, n_] := Block[{x0 = 1 / 2Cos[m 2Pi / n], y0 = 1 / 2Sin[m 2Pi / n]}, (x - x0) ^ 2 + (y - y0) ^ 2 < 1]
Wolfram Language code: disk[n_] := Apply[Xor, Table[disk[m, n], {m, 0, n - 1}]]

Generate three disks on a circle:

Wolfram Language code: disk[3]
Wolfram Language code: Table[RegionPlot[disk[n], {x, -2, 2}, {y, -2, 2}, FrameTicks -> None], {n, 2, 5}]

A truth table for a 12-variable Xor function:

Wolfram Language code: ArrayPlot[BooleanTable[Xor@@Array[x, 12], Array[x, 6], Array[x, 6, 7]], ColorRules -> {False -> White, True -> Black}]
Wolfram Research (1988), Xor, Wolfram Language function, https://reference.wolfram.com/language/ref/Xor.html (updated 2003).

Text

Wolfram Research (1988), Xor, Wolfram Language function, https://reference.wolfram.com/language/ref/Xor.html (updated 2003).

CMS

Wolfram Language. 1988. "Xor." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2003. https://reference.wolfram.com/language/ref/Xor.html.

APA

Wolfram Language. (1988). Xor. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Xor.html

BibTeX

@misc{reference.wolfram_2026_xor, author="Wolfram Research", title="{Xor}", year="2003", howpublished="\url{https://reference.wolfram.com/language/ref/Xor.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_xor, organization={Wolfram Research}, title={Xor}, year={2003}, url={https://reference.wolfram.com/language/ref/Xor.html}, note=[Accessed: 12-June-2026]}