WOLFRAM

Wolfram Language & System Documentation Center

Normalize[v]

gives the normalized form of a vector v.

Normalize[z]

gives the normalized form of a complex number z.

Normalize[expr,f]

normalizes with respect to the norm function f.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Generalizations & Extensions  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

Normalize

Normalize[v]

gives the normalized form of a vector v.

Normalize[z]

gives the normalized form of a complex number z.

Normalize[expr,f]

normalizes with respect to the norm function f.

Details

  • Normalize[v] is effectively v/Norm[v], except that zero vectors are returned unchanged.
  • Except in the case of zero vectors, Normalize[v] returns the unit vector in the direction of v.
  • For a complex number z, Normalize[z] returns z/Abs[z], except that Normalize[0] gives 0.
  • Normalize[expr,f] is effectively expr/f[expr], except when there are zeros in f[expr].

Examples

open all close all

Basic Examples  (1)

Wolfram Language code: Normalize[{1, 5, 1}]

Scope  (5)

Symbolic vectors:

Wolfram Language code: Normalize[{x, y}]

Use an arbitrary norm function:

Wolfram Language code: Normalize[{x, y}, f]

v is a complex‐valued vector:

Wolfram Language code: v = {1, 2 I, 3, 4 I, 5, 6I};

Normalize using exact arithmetic:

Wolfram Language code: Normalize[v]

Use machine arithmetic:

Wolfram Language code: Normalize[N[v]]

Use 24‐digit precision arithmetic:

Wolfram Language code: Normalize[N[v, 24]]

Normalize a sparse vector:

Wolfram Language code: s = N[SparseArray[Table[{2 ^ i} -> i, {i, 20}]]]
Wolfram Language code: Normalize[s]
Wolfram Language code: ArrayRules[%]

Normalize a TimeSeries:

Wolfram Language code: ts = TimeSeries[{1, 2, 3}, {.1, .3}];
Wolfram Language code: ts["Path"]
Wolfram Language code: Norm[ts["Values"]]
Wolfram Language code: nts = Normalize[ts]
Wolfram Language code: nts["Path"]
Wolfram Language code: Norm[nts["Values"]]

Generalizations & Extensions  (2)

Normalize a matrix by explicitly specifying a norm function:

Wolfram Language code: Normalize[{{1, 2}, {4, 5}}, Norm]

Normalize a polynomial with respect to integration over the interval to :

Wolfram Language code: Normalize[1 + x + x ^ 2, Integrate[# ^ 2, {x, -1, 1}]&]

Applications  (1)

m is a symmetric matrix with distinct eigenvalues:

Wolfram Language code: m = {{1, 2, 3}, {2, 4, 5}, {5, 3, 1}}

Power method to find the eigenvector associated with the largest eigenvalue:

Wolfram Language code: v = FixedPoint[Normalize[m.#]&, RandomReal[1, {3}]]

This is consistent (up to sign) with what Eigenvectors gives:

Wolfram Language code: Eigenvectors[N[m], 1]

The eigenvalue can be found with Norm:

Wolfram Language code: Norm[m.v]

Properties & Relations  (1)

v is a random vector:

Wolfram Language code: v = RandomReal[{-1, 1}, 2]

u is the normalization of v:

Wolfram Language code: u = Normalize[v]

u is a unit vector in the direction of v:

Wolfram Language code: Show[Graphics[{Circle[{0, 0}, 1], {Thickness[0.025], Arrow[{{0, 0}, u}]}, {Green, Thickness[0.0125], Arrow[{{0, 0}, v}]}}]]
Wolfram Research (2007), Normalize, Wolfram Language function, https://reference.wolfram.com/language/ref/Normalize.html.

Text

Wolfram Research (2007), Normalize, Wolfram Language function, https://reference.wolfram.com/language/ref/Normalize.html.

CMS

Wolfram Language. 2007. "Normalize." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Normalize.html.

APA

Wolfram Language. (2007). Normalize. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Normalize.html

BibTeX

@misc{reference.wolfram_2026_normalize, author="Wolfram Research", title="{Normalize}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Normalize.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_normalize, organization={Wolfram Research}, title={Normalize}, year={2007}, url={https://reference.wolfram.com/language/ref/Normalize.html}, note=[Accessed: 13-June-2026]}