WOLFRAM

Wolfram Language & System Documentation Center

NumberDecompose[x,{u1,…,un}]

returns a list of coefficients {c1,…,cn} of a decomposition of the number x in the basis {u1,…,un}.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

NumberDecompose

NumberDecompose[x,{u1,…,un}]

returns a list of coefficients {c1,…,cn} of a decomposition of the number x in the basis {u1,…,un}.

Details

  • The basis {u1,…,un} must be a list of nonincreasing positive numbers.
  • The result has the same length of the basis, even if the initial coefficients are zero.
  • The coefficients {c1,…,cn-1} are integers, but cn will be exact or not depending on the precision of x and the basis elements.
  • NumberDecompose[x,units] for negative x is equivalent to -NumberDecompose[-x,units].

Examples

open all close all

Basic Examples  (2)

Decompose an amount of money in different denominations:

Wolfram Language code: NumberDecompose[598.32, {100, 50, 20, 10, 5, 2, 1}]

Decompose an amount of seconds in days, hours, minutes, and seconds:

Wolfram Language code: NumberDecompose[100000, {86400, 3600, 60, 1}]

Scope  (3)

Decompose an exact number using a basis of exact numbers:

Wolfram Language code: NumberDecompose[99, {10, 5, 2, 1}]
Wolfram Language code: NumberDecompose[99 / 2, {10, 5, 2, 1}]

Decompose an exact numeric quantity using an exact basis:

Wolfram Language code: NumberDecompose[10Pi, {E, 1}]

Use inexact numbers:

Wolfram Language code: NumberDecompose[N[10Pi], {E, 1}]
Wolfram Language code: NumberDecompose[10Pi, {E, 1.}]

Decompose a negative number:

Wolfram Language code: NumberDecompose[-99, {10, 5, 2, 1}]

This is equivalent to the negative of the decomposition of its absolute value:

Wolfram Language code: -NumberDecompose[99, {10, 5, 2, 1}]

Applications  (2)

Decompose an amount of United States dollars in the available banknote denominations:

Wolfram Language code: denominations = {100, 50, 20, 10, 5, 2, 1};
Wolfram Language code: NumberDecompose[672, denominations]

Decompose an amount of Bahamian dollars in the available banknote denominations:

Wolfram Language code: denominations = {100, 50, 20, 10, 5, 3, 2, 1, 1 / 2};
Wolfram Language code: NumberDecompose[598.50, denominations]

Properties & Relations  (7)

The result of NumberDecompose is a list of non-negative numbers for a positive input:

Wolfram Language code: NumberDecompose[598.32, {100, 50, 20, 10, 5, 2, 1}]

The result is a list of nonpositive numbers for a negative input:

Wolfram Language code: NumberDecompose[-598.32, {100, 50, 20, 10, 5, 2, 1}]

NumberCompose is the inverse of NumberDecompose:

Wolfram Language code: units = {86400, 3600, 60, 1}
Wolfram Language code: NumberDecompose[513134, units]
Wolfram Language code: NumberCompose[%, units]

DMSList is a special case of NumberDecompose:

Wolfram Language code: DMSList[24.6254]
Wolfram Language code: NumberDecompose[24.6254, {1, 1 / 60, 1 / 3600}]

The length of the result equals the length of the basis:

Wolfram Language code: NumberDecompose[13, {5, 1}]
Wolfram Language code: NumberDecompose[13, {1}]
Wolfram Language code: NumberDecompose[13, {}]

For integers, NumberDecompose returns the last solution found by FrobeniusSolve:

Wolfram Language code: FrobeniusSolve[{5, 2, 1}, 17]
Wolfram Language code: Last[%] == NumberDecompose[17, {5, 2, 1}]

IntegerDigits is equivalent to NumberDecompose for an adequate choice of basis of units:

Wolfram Language code: IntegerDigits[54321, 10, 7]
Wolfram Language code: units = PowerRange[10 ^ 6, 1, 1 / 10]
Wolfram Language code: NumberDecompose[54321, units]

IntegerDigits with a MixedRadix specification performs a NumberDecompose operation:

Wolfram Language code: IntegerDigits[10 ^ 4, MixedRadix[{24, 60, 60}]]
Wolfram Language code: NumberDecompose[10 ^ 4, {60 60, 60, 1}]
Wolfram Research (2015), NumberDecompose, Wolfram Language function, https://reference.wolfram.com/language/ref/NumberDecompose.html.

Text

Wolfram Research (2015), NumberDecompose, Wolfram Language function, https://reference.wolfram.com/language/ref/NumberDecompose.html.

CMS

Wolfram Language. 2015. "NumberDecompose." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/NumberDecompose.html.

APA

Wolfram Language. (2015). NumberDecompose. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/NumberDecompose.html

BibTeX

@misc{reference.wolfram_2026_numberdecompose, author="Wolfram Research", title="{NumberDecompose}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/NumberDecompose.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_numberdecompose, organization={Wolfram Research}, title={NumberDecompose}, year={2015}, url={https://reference.wolfram.com/language/ref/NumberDecompose.html}, note=[Accessed: 13-June-2026]}