Wolfram Language & System Documentation Center

OrdinalScale

OrdinalScale[{cat₁,cat₂,…,cat_n}]

represents a set of ordered categories cat_i with order cat₁<cat₂<…<cat_n.

OrdinalScale[{cat₁,…,cat_n},{val₁,…,val_n}]

associates the category cat_i with the numeric value val_i.

OrdinalScale[<|cat₁val₁,…,cat_nval_n|>]

also associates the category cat_i with the numeric value val_i.

OrdinalScale[{cat₁,…,cat_n},vals,{lab₁,…,lab_n}]

displays the category cat_i as the corresponding lab_i when used as a label in plots etc.

OrdinalScale[…,<|cat_ilab_i,…|>]

uses lab_i to represent cat_i in plots.

OrdinalScale

OrdinalScale[{cat₁,cat₂,…,cat_n}]

represents a set of ordered categories cat_i with order cat₁<cat₂<…<cat_n.

OrdinalScale[{cat₁,…,cat_n},{val₁,…,val_n}]

associates the category cat_i with the numeric value val_i.

OrdinalScale[<|cat₁val₁,…,cat_nval_n|>]

also associates the category cat_i with the numeric value val_i.

OrdinalScale[{cat₁,…,cat_n},vals,{lab₁,…,lab_n}]

displays the category cat_i as the corresponding lab_i when used as a label in plots etc.

OrdinalScale[…,<|cat_ilab_i,…|>]

uses lab_i to represent cat_i in plots.

Details and Options

Ordinal scales are used to rank ordered things such as movie ratings, product quality and pain level. Typical examples include:
tiny<small<medium<large size categories

★<★★<★★★<★★★★<★★★★★ rating categories

F<D<C<B<A grade categories
Use OrdinalScale with ScalingFunctions to place categorical values along an axis.

The categories cat_i can be any expression.
By default, the category cat_i is given the value i for val_i.
The numerical values val_i can be any real number.
cat_i is considered to be less than cat_j if val_i<val_j.
If two categories cat_i and cat_j have the same associated numeric value val, they are considered to be in the same categorical class and one will be selected as the typical element.
When specifying labels, the value specification vals may be Automatic.
OrdinalScale[…][prop] gives the specified property of an ordinal scale.
Possible properties include:

	"CategoryAssociation"	association of the form <\|…,val_icat_i,…\|>
	"CategoryList"	list of categories {cat₁,…,cat_n}
	"LabelAssociation"	association of the form <\|…,cat_ilab_i,…\|>
	"LabelList"	list of labels {lab₁,…,lab_n}
	"ValueAssociation"	association of the form <\|…,cat_ival_i,…\|>
	"ValueList"	list of values {val₁,…,val_n}
	"Properties"	list of supported properties

OrdinalScale[…][prop,arg] or OrdinalScale[…][prop][arg] return the property prop according to the argument arg.
Possible properties prop and arguments arg include:

"Category"	val_i	categories cat_i corresponding to val_i
"Categories"	{…,val_i,…}	list of categories cat_i corresponding to val_i
"Label"	cat_i	labels lab_i corresponding to cat_i
"Labels"	{…,cat_i,…}	list of labels lab_i corresponding to cat_i
"Value"	cat_i	values val_i corresponding to cat_i
"Values"	{…,cat_i,…}	list of values val_i corresponding to cat_i

Examples

open all close all

Basic Examples (5)

Visualize a consumer satisfaction survey data:

Wolfram Language code:

ListPlot[IconizedObject[«consumer satisfaction survey»], ScalingFunctions -> OrdinalScale[{"Totally Dissatisfied", "Dissatisfied", "Neutral", "Satisfied", "Totally Satisfied"}]]

Provide values for satisfaction levels:

Wolfram Language code:

ListPlot[IconizedObject[«consumer satisfaction survey»], ScalingFunctions -> OrdinalScale[{"Totally Dissatisfied", "Dissatisfied", "Neutral", "Satisfied", "Totally Satisfied"}, {-1, 0, 1, 3, 6}]]

Specify a label for a category:

Wolfram Language code:

BarChart[{"A", "C", "B", "F", "C", "B"}, ChartLabels -> {"Alice", "Bill", "Chris", "Derek", "Eric", "Fiona"}, 
	ScalingFunctions -> OrdinalScale[<|"A" -> 5, "B" -> 4, "C" -> 3, "D" -> 2, "F" -> 1|>, 
	<|"F" -> "Failed"|>]]

Provide the scale order of ordinal data:

Wolfram Language code:

BubbleChart[IconizedObject[«egg size comparison»], ScalingFunctions -> {NominalScale[Automatic], OrdinalScale[{"Peewee", "Small", "Medium", "Large", "Extra Large", "Jumbo", "King"}], None}]

Use categorical labels to represent a list of numerical ratings:

Wolfram Language code:

ListPlot[{5, 4, 4, 1, 5, 1, 3, 4, 5, 2}, ScalingFunctions -> {None, OrdinalScale[{1, 2, 3, 4, 5}, Automatic, <|1 -> "★", 2 -> "★★", 3 -> "★★★", 4 -> "★★★★", 5 -> "★★★★★"|>]}, 
	Filling -> Bottom]

Plot a time series of physical exertion with the Borg CR10 scale:

Wolfram Language code:

DateListStepPlot[TemporalData[TimeSeries, {{{"Extremely hard", "Extremely hard", "Extremely hard", "Very hard", 
    "Hard", "Hard", "Hard", "Somewhat hard", "Somewhat hard", "Moderate", "Moderate", "Moderate", 
    "Light", "Light", "Very light", "Very light", "Ex ...  {TemporalData`DateSpecification[{2020, 1, 1, 1, 0, 0.}, {2020, 5, 27, 1, 0, 0.}, {1, "Week"}]}, 
  1, {"Continuous", 1}, {"Discrete", 1}, 1, 
  {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}, ValueDimensions -> 1}}, True, 
 13.1], ScalingFunctions -> OrdinalScale[IconizedObject[«Borg CR10»]], GridLines -> All, Frame -> True]

Scope (31)

Example Scales (10)

Seven-point Likert rating scale:

Wolfram Language code:

BarChart[{...}, ScalingFunctions -> OrdinalScale[{"Strongly Disagree", "Disagree", "Somewhat Disagree", "Neither Agree nor Disagree", "Somewhat Agree", "Agree", "Strongly Agree"}]]

Borg-RPE scale for assessing physical exertion:

Wolfram Language code:

BarChart[{...}, ScalingFunctions -> OrdinalScale[<|"No exertion at all" -> 6, "Extremely light" -> 7, "Very light" -> 9, "Light" -> 11, "Somewhat hard" -> 13, "Hard" -> 15, "Very hard" -> 17, "Extremely hard" -> 19, "Maximal exertion" -> 20|>]]

Borg-CR10 scale:

Wolfram Language code:

BarChart[{...}, ScalingFunctions -> OrdinalScale[<|"No exertion at all" -> 0, "Extremely light" -> 0.5, "Very light" -> 1, "Light" -> 2, "Somewhat hard" -> 3, "Hard" -> 5, "Very hard" -> 7, "Extremely hard" -> 10|>]]

Moody ratings for bonds:

Wolfram Language code:

BarChart[{...}, ScalingFunctions -> OrdinalScale[<|"C" -> -4, "Ca" -> -3, "Caa3" -> -2, "Caa2" -> -1, "Caa1" -> 0, "B3" -> 1, "B2" -> 2, "B1" -> 3, "Ba3" -> 4, "Ba2" -> 5, "Ba1" -> 6, "Baa3" -> 7, "Baa2" -> 8, "Baa1" -> 9, "A3" -> 10, "A2" -> 11, "A1" -> 12, "Aa3" -> 13, "Aa2" -> 14, "Aa1" -> 15, "Aaa" -> 16|>]]

Sizes:

Wolfram Language code: BarChart[{...}, ScalingFunctions -> OrdinalScale[{"Tiny", "Small", "Medium", "Large", "Extra Large"}]]

Judo ranks:

Wolfram Language code:

BarChart[{"White", "Yellow", "Orange", "Green", "Blue", "Brown", "Black", "Red"}, ScalingFunctions -> OrdinalScale[{"White", "Yellow", "Orange", "Green", "Blue", "Brown", "Black", "Red"}, Automatic, <|"White" -> "Beginner", "Yellow" -> "9th Kyu", "Orange" -> "8th & 7th Kyu", "Green" -> "6th & 5th Kyu", "Blue" -> "4th & 3rd Kyu", "Brown" -> "2nd & 1st Kyu", "Black" -> "Dan", "Red" -> "Grandmaster"|>], 
	ChartStyle -> {White, Yellow, Orange, Green, Blue, Brown, Black, Red}]

Sizes of container ships:

Wolfram Language code:

BarChart[{...}, ScalingFunctions -> OrdinalScale[<|"Small feeder" -> 1000, "Feeder" -> 2000, "Feedermax" -> 3000, "Panamax" -> 5100, "Post-panamax" -> 10000, "New Panamax" -> 14500|>]]

Pain scale:

Wolfram Language code:

BarChart[{...}, ScalingFunctions -> OrdinalScale[{"Pain free", "Very Mild", "Discomforting", "Tolerable", "Distressing", "Very Distressing", "Intense", "Very Intense", "Utterly Horrible", "Excruciating Unbearable", "Unimaginable Unspeakable"}, Range[11] - 1]]

USDA beef grades:

Wolfram Language code:

BarChart[{...}, ScalingFunctions -> OrdinalScale[{"Canner", "Cutter", "Utility", "Commercial", "Standard", "Select", "Choice", "Prime"}]
	]

USDA orange grades:

Wolfram Language code:

BarChart[{...}, ScalingFunctions -> OrdinalScale[{"US No.3", "US No.2 Russet", "US No.2", "US No.2 Bright", "US No.1 Russet", "US No.1 Bronze", "US No.1 Golden", "US No.1", "US No.1 Bright", "US Fancy"}]
	]

USDA egg size grades:

Wolfram Language code:

BarChart[{...}, ScalingFunctions -> OrdinalScale[<|"Peewee" -> 15, "Small" -> 18, "Medium" -> 21, "Large" -> 24, "Extra Large" -> 27, "Jumbo" -> 30|>]
	]

Categories, Values and Labels (7)

Categories can be any type of expression, such as strings:

Wolfram Language code:

BarChart[{"Yellow Pine", "Hard Maple", "Black Walnut", "Hard Maple", "Hard Maple", "Red Oak", "Yellow Pine", "Red Oak", "Hard Maple", "Red Oak"}, ScalingFunctions -> OrdinalScale[<|"Douglas Fir" -> 660, "Yellow Pine" -> 870, "Black Walnut" -> 1010, "Red Oak" -> 1290, "Hard Maple" -> 1450, "Hickory" -> 1820|>]]

Entities:

Wolfram Language code:

BarChart[{Entity["Aircraft", "Boeing767"], Entity["Aircraft", "JumboJet"], Entity["Aircraft", "Boeing767"], Entity["Aircraft", "Boeing787"], Entity["Aircraft", "Boeing767"], Entity["Aircraft", "Boeing737"], Entity["Aircraft", "Boeing787"]}, ScalingFunctions -> OrdinalScale[{Entity["Aircraft", "Boeing737"], Entity["Aircraft", "Boeing767"], Entity["Aircraft", "Boeing787"], Entity["Aircraft", "Boeing777"], Entity["Aircraft", "JumboJet"]}]]

Colors:

Wolfram Language code:

BarChart[{RGBColor[0, 1, 0], RGBColor[1, 0.5, 0], RGBColor[1, 1, 0], RGBColor[0.5, 0, 0.5], RGBColor[0, 0, 1], RGBColor[0, 0, 1], RGBColor[0.5, 0, 0.5], RGBColor[0, 1, 0], RGBColor[0, 0, 1], RGBColor[1, 0, 0], RGBColor[1, 1, 0], RGBColor[1, 0, 0], RGBColor[1, 0.5, 0], RGBColor[0, 0, 1], RGBColor[0.5, 0, 0.5]}, ScalingFunctions -> OrdinalScale[{Red, Orange, Yellow, Green, Blue, Purple}]]

Pictures:

Wolfram Language code: BarChart[{[image], [image], [image], [image]}, ScalingFunctions -> OrdinalScale[{[image], [image], [image], [image]}]]

Numeric categories do not use a numeric scale:

Wolfram Language code: BarChart[{1, 2, 4, 8, 12, 24}, ScalingFunctions -> OrdinalScale[{1, 2, 4, 8, 12, 24}]]

By default, OrdinalScale values are automatically assigned:

Wolfram Language code:

ListPlot[{"C4", "D4", "E4", "F4", "G4", "A4", "B4"}, ScalingFunctions -> OrdinalScale[{"C4", "D4", "E4", "F4", "G4", "A4", "B4"}], 
	Filling -> Bottom]

Provide the values for the 5th octave of music notes:

Wolfram Language code:

ListPlot[{"C4", "D4", "E4", "F4", "G4", "A4", "B4"}, ScalingFunctions -> OrdinalScale[{"C4", "D4", "E4", "F4", "G4", "A4", "B4"}, {262, 293, 330, 349, 392, 440, 494}], 
	Filling -> Bottom]

Specify labels for each note:

Wolfram Language code:

ListPlot[{"C4", "D4", "E4", "F4", "G4", "A4", "B4"}, ScalingFunctions -> OrdinalScale[{"C4", "D4", "E4", "F4", "G4", "A4", "B4"}, {262, 293, 330, 349, 392, 440, 494}, {"SubscriptBox[C, 4]", "SubscriptBox[D, 4]", "SubscriptBox[E, 4]", "SubscriptBox[F, 4]", "SubscriptBox[G, 4]", "SubscriptBox[A, 4](440Hz)", "SubscriptBox[B, 4]"}], 
	Filling -> Bottom]

Categories that are omitted from the scale are treated as missing and are not shown:

Wolfram Language code:

BarChart[{"Large", "Tiny", "XLarge", "XLarge", "Tiny", "Medium", "Medium", "XLarge"}, ScalingFunctions -> OrdinalScale[{"Small", "Medium", "Large", "XLarge"}]]

By default, the categories are used as labels:

Wolfram Language code:

BarChart[{"XLarge", "Small", "XLarge", "Small", "Large", "Medium", "Medium", "Large", "Large", "Large"}, ScalingFunctions -> OrdinalScale[{"Small", "Medium", "Large", "XLarge"}]]

Specify labels to use in place of the categories:

Wolfram Language code:

BarChart[{"XLarge", "Small", "XLarge", "Small", "Large", "Medium", "Medium", "Large", "Large", "Large"}, ScalingFunctions -> OrdinalScale[{"Small", "Medium", "Large", "XLarge"}, Automatic, <|"Small" -> "S", "Medium" -> "M", "Large" -> "L", "XLarge" -> "XL"|>]]

Provide labels for individual categories:

Wolfram Language code:

BarChart[{"XLarge", "Small", "XLarge", "Small", "Large", "Medium", "Medium", "Large", "Large", "Large"}, ScalingFunctions -> OrdinalScale[{"Small", "Medium", "Large", "XLarge"}, Automatic, <|"XLarge" -> "XL"|>]]

Labels can be any type of expression:

Wolfram Language code:

BarChart[{2, 4, 3, 5, 1, 4, 2, 2, 2, 3}, ScalingFunctions -> OrdinalScale[Range[5], <|1 -> Abs[x], 2 -> [image], 3 -> [image], 4 -> RGBColor[0.5, 0, 0.5], 5 -> [image]|>]]

Extracting Properties (14)

Obtain a list of properties for a nominal scale:

Wolfram Language code: OrdinalScale[IconizedObject[«likert scale»]]["Properties"]

Extract the list of categories:

Wolfram Language code: OrdinalScale[IconizedObject[«likert scale»]]["CategoryList"]

Extract the list of values:

Wolfram Language code: OrdinalScale[IconizedObject[«likert scale»]]["ValueList"]

Extract the mapping between categories and values:

Wolfram Language code: OrdinalScale[IconizedObject[«likert scale»]]["ValueAssociation"]

Extract the mapping between values and categories:

Wolfram Language code: OrdinalScale[IconizedObject[«likert scale»]]["CategoryAssociation"]

Extract the list of labels:

Wolfram Language code: OrdinalScale[IconizedObject[«likert scale»]]["LabelList"]

Extract the mapping between categories and labels:

Wolfram Language code: OrdinalScale[IconizedObject[«likert scale»]]["LabelAssociation"]

Determine the value for a single category:

Wolfram Language code: OrdinalScale[IconizedObject[«likert scale»]]["Value", "Satisfied"]

Wolfram Language code: OrdinalScale[IconizedObject[«likert scale»]]["Value"]["Satisfied"]

Determine the category for a value:

Wolfram Language code: OrdinalScale[IconizedObject[«likert scale»]]["Category", 5]

Wolfram Language code: OrdinalScale[IconizedObject[«likert scale»]]["Category"][5]

Determine the values for a list of categories:

Wolfram Language code:

OrdinalScale[IconizedObject[«likert scale»]]["Values", {"Unsatisfied", "Very Unsatisfied", "Very Satisfied", "Satisfied", "Very Satisfied", "Very Unsatisfied", "Very Unsatisfied", "Very Satisfied"}]

Determine the labels for a list of categories:

Wolfram Language code:

OrdinalScale[IconizedObject[«likert scale»]]["Labels", {"Unsatisfied", "Very Unsatisfied", "Very Satisfied", "Satisfied", "Very Satisfied", "Very Unsatisfied", "Very Unsatisfied", "Very Satisfied"}]

Use in a visualization function:

Wolfram Language code:

BarChart[{"Unsatisfied", "Very Unsatisfied", "Very Satisfied", "Satisfied", "Very Satisfied", "Very Unsatisfied", "Very Unsatisfied", "Very Satisfied"}, ScalingFunctions -> OrdinalScale[IconizedObject[«likert scale»]]]

By default, values are automatically assigned:

Wolfram Language code: OrdinalScale[{"Very Unsatisfied", "Unsatisfied", "Neural", "Satisfied", "Very Satisfied"}]["ValueAssociation"]

Specify values:

Wolfram Language code:

OrdinalScale[{"Very Unsatisfied", "Unsatisfied", "Neural", "Satisfied", "Very Satisfied"}, {-4, -2, 0, 2, 6}]["ValueAssociation"]

Specify specific labels:

Wolfram Language code:

OrdinalScale[{"Very Unsatisfied", "Unsatisfied", "Neural", "Satisfied", "Very Satisfied"}, {-4, -2, 0, 2, 6}, {{"angry", "annoyed", "neutral", "smily", "happy"}}]["LabelAssociation"]

Orders are specified automatically:

Wolfram Language code: OrdinalScale[{"A", "B", "C"}]["ValueAssociation"]

Specify orders manually:

Wolfram Language code: OrdinalScale[{"A", "B", "C"}, {2, 3, 1}]["ValueAssociation"]

Use Association to specify categories and values:

Wolfram Language code: OrdinalScale[<|"A" -> 2, "B" -> 3, "C" -> 1|>]["ValueAssociation"]

Categories that share the same value are combined:

Wolfram Language code:

ListPlot[{"D", "B", "C", "A", "D", "C", "B", "D", "C", "D"}, ScalingFunctions -> {None, OrdinalScale[<|"A" -> 1, "B" -> 2, "C" -> 3, "D" -> 2|>]}]

Applications (8)

Agriculture (2)

Plot a time series of egg size change of a growing hen:

Wolfram Language code:

DateListStepPlot[TemporalData[TimeSeries, {{{"Peewee", "Small", "Medium", "Large", "Extra Large", "Jumbo"}}, 
  {{{3.8214920541544046*^9, 3.8217111542537756*^9, 3.8227325729100084*^9, 3.8234681794958987*^9, 
     3.8273510174461837*^9, 3.828068401574386*^9}}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, 
  {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}, ValueDimensions -> 1}}, False, 
 13.1], ScalingFunctions -> {None, OrdinalScale[<|"Peewee" -> 15, "Small" -> 18, "Medium" -> 21, "Large" -> 24, "Extra Large" -> 27, "Jumbo" -> 30|>]}]

Show the prices of apples based on the types and sizes:

Wolfram Language code:

BubbleChart[IconizedObject[«{{Apple type, size, price}, …}»], ScalingFunctions -> {NominalScale[Automatic], OrdinalScale[{"125s", "113s", "100s", "88s", "80s", "72s", "64s", "56s"}], None}, AspectRatio -> 1 / 2, FrameLabel -> {{"size", None}, {"type", None}}]

Finance (2)

Plot US states' bond ratings in 2021 with a predefined Moody rating scale:

Wolfram Language code:

ListPlot[IconizedObject[«Moody state ratings 2021»], ScalingFunctions -> {NominalScale[Automatic, RotateLabel -> True], OrdinalScale[IconizedObject[«Moody Bond Ratings»]]}, ImageSize -> 400, LabelStyle -> 8, GridLines -> All, ColorFunction -> ColorData[{"Rainbow", "Reverse"}]]

Plot in S&P and Fitch rating scales:

Wolfram Language code:

ListPlot[IconizedObject[«S&P state ratings 2021»], ScalingFunctions -> {NominalScale[Automatic, RotateLabel -> True], OrdinalScale[IconizedObject[«S&PBondRatings»]]}, ImageSize -> 400, LabelStyle -> 8, GridLines -> All, ColorFunction -> ColorData[{"Rainbow", "Reverse"}]]

Wolfram Language code:

ListPlot[IconizedObject[«Fitch state ratings 2021»], ScalingFunctions -> {NominalScale[Automatic, RotateLabel -> True], OrdinalScale[IconizedObject[«FitchBondRatings»]]}, ImageSize -> 400, LabelStyle -> 8, GridLines -> All, ColorFunction -> ColorData[{"Rainbow", "Reverse"}]]

Historical S&P bond ranking of Illinois:

Wolfram Language code:

illinois = TimeSeries[Reverse@{"BBB", "BBB-", "BBB-", "BBB-", "BBB-", "BBB", "A-", "A-", "A-", "A", "A+", "A+", "A+", "AA", "AA", "AA", "AA", "AA", "AA", "AA", "AA"}, {{2001, 1, 1}, {2021, 1, 1}, "Year"}]

Wolfram Language code: DateListPlot[illinois, ScalingFunctions -> OrdinalScale["S&P"], DateTicksFormat -> {"Year"}]

Markov Chain (1)

Visualize simulations of the gambler's ruin process in ListLinePlot with OrdinalScale:

Wolfram Language code:

GamblersRuin[p_, n_] := SparseArray[{{1, 1} -> 1, {n + 1, n + 1} -> 1, {i_, j_} /; 1 < i < n + 1 && j == i + 1 -> p, {i_, j_} /; 1 < i < n + 1 && j == i - 1 -> 1 - p}, {n + 1, n + 1}]

With a winning probability of 0.5, the player's initial wealth is 7 and the total wealth is 10 between the player and the host. The states here are the integers 1 through 11, representing the gambler's wealth plus one:

Wolfram Language code: gamblerwealth = DiscreteMarkovProcess[8, GamblersRuin[0.5, 10]];

Simulate 15 times to observe that given a fair game, the winning possibility—that is the possibility of taking the whole wealth—depends on the player's initial wealth and the total wealth:

Wolfram Language code: path = Table[RandomFunction[gamblerwealth, {0, 50}]["Values"], {15}];

Wolfram Language code:

ListLinePlot[path, ScalingFunctions -> {None, OrdinalScale[Range[11], <|1 -> "Ruin", 11 -> "Win"|>]}, PlotLabels -> Range[15], ImageSize -> 450]

Education (1)

Show grades for students in a classroom:

Wolfram Language code:

BarChart[IconizedObject[«grades»], ScalingFunctions -> OrdinalScale[{1, 2, 3, 4, 5}, Automatic, {"F", "D", "C", "B", "A"}], 
	ChartLabels -> {"John", "Eric", "Rob", "Max", "Ian"}]

Medical (1)

Show pain scale for various injuries:

Wolfram Language code:

ListPlot[{{"Sprain", "Discomforting"}, {"Laceration", "Distressing"}, {"Cut", "Very Distressing"}, {"Fracture", "Intense"}, {"Bruise", "Very Intense"}, {"Digit amputation", "Excruciating Unbearable"}}, ScalingFunctions -> {NominalScale[Automatic, RotateLabel -> True], OrdinalScale[{"Pain free", "Very Mild", "Discomforting", "Tolerable", "Distressing", "Very Distressing", "Intense", "Very Intense", "Utterly Horrible", "Excruciating Unbearable", "Unimaginable Unspeakable"}, Range[11] - 1]}, 
	Filling -> Bottom]

Classification (1)

Use OrdinalScale value associations for classification:

Wolfram Language code:

woodhardnessscale = OrdinalScale[<|"Douglas Fir" -> 660, "Yellow Pine" -> 870, "Black Walnut" -> 1010, "Red Oak" -> 1290, "Hard Maple" -> 1450, "Hickory" -> 1820|>];

Wolfram Language code: woodhardness = Nearest[woodhardnessscale["ValueList"]]

Wolfram Language code: similarwood[hardness_] := woodhardnessscale["CategoryAssociation"][First@woodhardness[hardness]]

Given a hardness value, find a similar hardwood:

Wolfram Language code: similarwood[785]

Wolfram Language code: similarwood[1787]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

OrdinalScale

Details and Options

Examples

Basic Examples (5)

Scope (31)

Example Scales (10)

Categories, Values and Labels (7)

Extracting Properties (14)

Applications (8)

Agriculture (2)

Finance (2)

Markov Chain (1)

Education (1)

Medical (1)

Classification (1)

Text

CMS

APA

BibTeX

BibLaTeX

OrdinalScale

Details and Options

Examples

Basic Examples (5)

Scope (31)

Example Scales (10)

Categories, Values and Labels (7)

Extracting Properties (14)

Applications (8)

Agriculture (2)

Finance (2)

Markov Chain (1)

Education (1)

Medical (1)

Classification (1)

See Also

History

Text

CMS

APA

BibTeX

BibLaTeX