WOLFRAM

Wolfram Language & System Documentation Center

OwenT[x,a]

gives Owen's T function TemplateBox[{x, a}, OwenT].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Show More Show More
Function Properties  
Differentiation  
Integration  
Series Expansions  
Function Identities  
Applications  
See Also
Related Guides
History
Cite this Page

OwenT

OwenT[x,a]

gives Owen's T function TemplateBox[{x, a}, OwenT].

Details

  • Mathematical function, suitable for both symbolic and numerical evaluation.
  • TemplateBox[{x, a}, OwenT]=1/(2pi)int_0^aexp(-x^2(1+t^2)/2)/(1+t^2)dt for real .
  • OwenT[x,a] is an entire function of x with no branch cut discontinuities.
  • OwenT[x,a] has branch cut discontinuities in the complex a plane running from to .
  • For certain special arguments, OwenT automatically evaluates to exact values.
  • OwenT can be evaluated to arbitrary numerical precision.
  • OwenT automatically threads over lists.

Examples

open all close all

Basic Examples  (6)

Evaluate numerically:

Wolfram Language code: OwenT[4., 1]

Plot over a subset of the reals:

Wolfram Language code: Plot[OwenT[x, 2], {x, -4, 4}]
Wolfram Language code: Plot3D[OwenT[x, a], {x, -3, 3}, {a, -3, 3}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[OwenT[z, 1], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[OwenT[x, a], {x, 0, 6}]

Series expansion at Infinity:

Wolfram Language code: Series[OwenT[x, 1], {x, ∞, 3}]//Normal//FullSimplify

Series expansion at a singular point:

Wolfram Language code: Series[OwenT[x, 2], {x, -I, 3}]//Normal//FullSimplify

Scope  (38)

Numerical Evaluation  (6)

Evaluate numerically:

Wolfram Language code: OwenT[0, .5]
Wolfram Language code: OwenT[4., -7]

Evaluate to high precision:

Wolfram Language code: N[OwenT[1 / 8, -1], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: OwenT[.44444444444444444444444, -7]

Complex number input:

Wolfram Language code: OwenT[2 + I, -7.5]

Evaluate efficiently at high precision:

Wolfram Language code: OwenT[1 / 7, -1`100]//Timing
Wolfram Language code: OwenT[1 / 9, -1`1000];//Timing

Compute average-case statistical intervals using Around:

Wolfram Language code: OwenT[ Around[2, 0.01], π]

Compute the elementwise values of an array:

Wolfram Language code: OwenT[{{1 / 2, 0}, {0, 1 / 2}}, 1]

Or compute the matrix OwenT function using MatrixFunction:

Wolfram Language code: MatrixFunction[OwenT[#, 1]&, {{1 / 2, 0}, {0, 1 / 2}}]//FullSimplify

Specific Values  (5)

Values of OwenT at fixed points:

Wolfram Language code: Table[OwenT[x, 2 ], {x, -2, 2}]//N

OwenT for symbolic a:

Wolfram Language code: OwenT[0, a]

Values at zero:

Wolfram Language code: OwenT[0, 0]

Find the first positive maximum of OwenT[x,1 ]:

Wolfram Language code: xmax = x /. FindRoot[D[OwenT[x, 1], x] == 0, {x, 0.6}]
Wolfram Language code: Plot[OwenT[x, 1 ], {x, -5, 5}, Epilog -> Style[Point[{xmax, OwenT[xmax, 1 ]}], PointSize[Large], Red]]

Compute the associated OwenT[x,1] function:

Wolfram Language code: OwenT[x, 1]

Visualization  (3)

Plot the OwenT function for various parameters:

Wolfram Language code: Plot[{OwenT[x, 1], OwenT[x, 2], OwenT[x, 3], OwenT[x, 4]}, {x, -3, 3}]

Plot the real part of TemplateBox[{z, 3}, OwenT]:

Wolfram Language code: ComplexContourPlot[Re[OwenT[z, 3]], {z, -1 - I, 1 + I}, Contours -> 24]

Plot the imaginary part of TemplateBox[{z, 3}, OwenT]:

Wolfram Language code: ComplexContourPlot[Im[OwenT[z, 3]], {z, -1 - I, 1 + I}, Contours -> 24]

Plot the real part of the function as two parameters vary:

Wolfram Language code: Plot3D[Re[OwenT[x, a]], {a, 0, 3}, {x, -2, 2}]

Function Properties  (11)

OwenT is defined for all real values:

Wolfram Language code: FunctionDomain[OwenT[z, a], {z, a}]

TemplateBox[{z, a}, OwenT] is defined for :

Wolfram Language code: FunctionDomain[OwenT[z, a], z, Complexes]

TemplateBox[{x, a}, OwenT] is even with respect to and odd with respect to :

Wolfram Language code: OwenT[-x, a] == OwenT[x, a]
Wolfram Language code: OwenT[x, -a] == -OwenT[x, a]

OwenT may reduce to a simpler form:

Wolfram Language code: OwenT[x, 1]
Wolfram Language code: OwenT[0, a]

OwenT is an analytic function in both its arguments:

Wolfram Language code: FunctionAnalytic[OwenT[x, a], {x, a}]

It is not an analytic function over the complexes:

Wolfram Language code: FunctionAnalytic[OwenT[x, a], {x, a}, Complexes]

OwenT is neither non-decreasing nor non-increasing:

Wolfram Language code: Table[FunctionMonotonicity[OwenT[x, a], x], {a, 4}]

TemplateBox[{x, a}, OwenT] is not injective for :

Wolfram Language code: FunctionInjective[OwenT[x, a], x, Assumptions -> a > 0]
Wolfram Language code: Plot[{OwenT[x, 1], OwenT[x, 2], .1}, {x, -3, 3}]

TemplateBox[{x, a}, OwenT] is not surjective for :

Wolfram Language code: FunctionSurjective[OwenT[x, a], x, Assumptions -> a > 0]
Wolfram Language code: Plot[{OwenT[x, 2], OwenT[x, 4], -.1}, {x, -3, 3}]

TemplateBox[{x, a}, OwenT] is non-negative for :

Wolfram Language code: FunctionSign[OwenT[x, a], x, Assumptions -> a > 0]

OwenT has no singularities or discontinuities:

Wolfram Language code: FunctionSingularities[OwenT[x, a], {x, a}]

TemplateBox[{x, a}, OwenT] has branch cut discontinuities with respect to over the complexes:

Wolfram Language code: FunctionSingularities[OwenT[x, a], a, Complexes]
Wolfram Language code: FunctionDiscontinuities[OwenT[x, a], a, Complexes]

OwenT is neither convex nor concave:

Wolfram Language code: Table[FunctionConvexity[OwenT[x, a], x], {a, 5}]

TraditionalForm formatting:

Wolfram Language code: OwenT[x, a]//TraditionalForm

Differentiation  (4)

First derivative with respect to x:

Wolfram Language code: D[OwenT[x, a], x]

Higher derivatives with respect to x:

Wolfram Language code: Table[D[OwenT[x, a], {x, k}], {k, 1, 3}]//FullSimplify

Plot the higher derivatives with respect to x when a=1.5:

Wolfram Language code: Plot[Evaluate[% /. { a -> 1.5}], {x, -3, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

First derivative with respect to a:

Wolfram Language code: D[OwenT[x, a], a]

Higher derivatives with respect to a:

Wolfram Language code: Table[D[OwenT[x, a], {a, k}], {k, 1, 3}]//FullSimplify

Plot the higher derivatives with respect to a when x=0.5:

Wolfram Language code: Plot[Evaluate[% /. { x -> 1.5}], {a, -3, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Integration  (4)

Compute the indefinite integral with respect to using Integrate:

Wolfram Language code: Integrate[OwenT[x, a], x]

Verify the antiderivative:

Wolfram Language code: FullSimplify[D[%, x]]

Compute the indefinite integral with respect to :

Wolfram Language code: Integrate[OwenT[x, a], a]

Verify the antiderivative:

Wolfram Language code: FullSimplify[D[%, a]]

Definite integral:

Wolfram Language code: Integrate[OwenT[x, a], {x, 0, 5}]

More integrals:

Wolfram Language code: Integrate[x OwenT[x, 4], x]//FullSimplify
Wolfram Language code: Integrate[ x OwenT[x^2, 1], {x, 0, 5}]//FullSimplify
Wolfram Language code: Integrate[a^2 OwenT[(1/2), a], a]//FullSimplify

Series Expansions  (2)

Find the Taylor expansion using Series:

Wolfram Language code: Series[OwenT[x, a], {x, 0, 6}]// FullSimplify

Plots of the first three approximations around :

Wolfram Language code: terms = Normal@Table[Series[OwenT[x, 1], {x, 0, m}], {m, 1, 5, 2}]; Plot[{OwenT[x, 1], terms}, {x, -3, 3}]

Taylor expansion at a generic point:

Wolfram Language code: Series[OwenT[x, a], {x, x0, 2}]

Function Identities  (3)

Ordinary differential equation with respect to satisfied by TemplateBox[{x, a}, OwenT]:

Wolfram Language code: y'''[x] + (a^2 + 2)x y''[x] + (a^2x^2 + x^2 + 1)y'[x] == 0 /. y -> Function[x, OwenT[x, a]]//Simplify

Ordinary differential equation with respect to satisfied by TemplateBox[{x, a}, OwenT]:

Wolfram Language code: (1 + a^2)y''[a] + a(x^2(1 + a^2) + 2)y'[a] == 0 /. y -> Function[a, OwenT[x, a]]//Simplify

Partial differential equation satisfied by TemplateBox[{x, a}, OwenT]:

Wolfram Language code: Subscript[∂, {x, 2}]y[x, a] + xSubscript[∂, x]y[x, a] + a(1 + a^2)Subscript[∂, a]y[x, a] == 0 /. y -> Function[{x, a}, OwenT[x, a]]//Simplify

Applications  (6)

Plot Owen's T-function in the complex a plane:

Wolfram Language code: Plot3D[Re[OwenT[1 / 2, u + I v]], {u, -1, 1}, {v, -2, 2}]

Compute the CDF of SkewNormalDistribution:

Wolfram Language code: CDF[SkewNormalDistribution[μ, σ, α], x]

Compute the probability of an uncorrelated bivariate normal over a truncated wedge:

Wolfram Language code: With[{a = 2, h = 3 / 2}, NProbability[x ≥ h && 0 < y < a * x, {x, y}BinormalDistribution[0]]]
Wolfram Language code: With[{a = 2, h = 3 / 2}, OwenT[h, a]]//N

The probability that a standard binormal variate with correlation lies within an equilateral triangle can be expressed using OwenT:

Wolfram Language code: TriangleProbability[r_] := 1 - OwenT[(1/2), (Sqrt[3] - r/Sqrt[1 - r^2])] - OwenT[(1/2), (Sqrt[3] + r/Sqrt[1 - r^2])] - OwenT[(1/Sqrt[2] Sqrt[2 - Sqrt[3] r]), (Sqrt[3] - r/Sqrt[1 - r^2])] + OwenT[(1/Sqrt[2] Sqrt[2 - Sqrt[3] r]), (2 r - Sqrt[3]/ Sqrt[1 - r^2])] - OwenT[(1/Sqrt[2] Sqrt[2 + Sqrt[3] r]), (2 r + Sqrt[3]/Sqrt[1 - r^2])] - OwenT[(1/Sqrt[2] Sqrt[2 + Sqrt[3] r]), (Sqrt[3] + r/ Sqrt[1 - r^2])]

Generate and visualize the region:

Wolfram Language code: reg = FullSimplify[RegionMember[RegularPolygon[{1, 0}, 3], {x, y}], (x | y)∈Reals]
Wolfram Language code: RegionPlot[reg, {x, -0.7, 1.1}, {y, -1.1, 1.1}]

Evaluate the probability for a particular value of the correlation coefficient:

Wolfram Language code: TriangleProbability[0.4]

Use NProbability to compute the probability directly:

Wolfram Language code: NProbability[reg, {x, y}BinormalDistribution[0.4]]

Use OwenT to compute the standard BinormalDistribution probability of :

Wolfram Language code: bnpr[ρ_, {x_, y_}] /; x * y ≠ 0 := (1/4)Erfc[-(x/Sqrt[2])] + (1/4)Erfc[-(y/Sqrt[2])] - OwenT[x, (y / x - ρ/Sqrt[1 - ρ^2])] - OwenT[y, (x / y - ρ/Sqrt[1 - ρ^2])] - UnitStep[-x y] / 2

Evaluate numerically:

Wolfram Language code: bnpr[0.87, {2, 1}]

Compute directly:

Wolfram Language code: CDF[BinormalDistribution[0.87], {2, 1}]

Compute the mean residual life function of a skew-normal random variate:

Wolfram Language code: μ[α_, t_] = Expectation[xx > t, xSkewNormalDistribution[α], Assumptions -> α > 0] - t

Plot the mean residual life function for several values of parameter , including the limiting case of a normal variate, i.e. :

Wolfram Language code: Plot[Table[Legended[μ[α, t], Row[{"α = ", α}]], {α, {0, 1 / 2, 2}}]//Evaluate, {t, -2, 5}]
Wolfram Research (2010), OwenT, Wolfram Language function, https://reference.wolfram.com/language/ref/OwenT.html.

Text

Wolfram Research (2010), OwenT, Wolfram Language function, https://reference.wolfram.com/language/ref/OwenT.html.

CMS

Wolfram Language. 2010. "OwenT." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/OwenT.html.

APA

Wolfram Language. (2010). OwenT. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/OwenT.html

BibTeX

@misc{reference.wolfram_2026_owent, author="Wolfram Research", title="{OwenT}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/OwenT.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_owent, organization={Wolfram Research}, title={OwenT}, year={2010}, url={https://reference.wolfram.com/language/ref/OwenT.html}, note=[Accessed: 12-June-2026]}