Wolfram Language & System Documentation Center

ParameterMixtureDistribution

ParameterMixtureDistribution[dist[θ],θwdist]

represents a parameter mixture distribution where the parameter θ is distributed according to the weight distribution wdist.

ParameterMixtureDistribution[dist[θ₁,θ₂,…],{θ₁wdist₁,θ₂wdist₂,…}]

represents a parameter mixture distribution where the parameter θ₁ has weight distribution wdist₁, θ₂ has weight distribution wdist₂, etc.

Details and Options

The probability density for value is given by Expectation[PDF[dist[θ],x],θwdist].
The domain of the weight distribution wdist needs to be a subset or equal to the parameter domain expected for dist[θ].
Parameters θ_i can be discrete or continuous.
Assumptions on parameters can be specified using the option Assumptionsassum.
ParameterMixtureDistribution can be used with such functions as Mean, CDF, and RandomVariate, etc.

Examples

open all close all

Basic Examples (3)

Specify a parameter mixture distribution:

Wolfram Language code: ParameterMixtureDistribution[BinomialDistribution[n, p], p  BetaDistribution[α, β]]

Wolfram Language code: ParameterMixtureDistribution[PoissonDistribution[v], v  ExponentialDistribution[λ]]

Parameter mixture distributions work like any other distributions:

Wolfram Language code: 𝒟 = ParameterMixtureDistribution[GammaDistribution[2, β], βUniformDistribution[{1, 2}]]

Wolfram Language code: Plot[Evaluate[PDF[𝒟, x]], {x, 0, 11}, Filling -> Axis, PlotRange -> All]

Wolfram Language code: CDF[𝒟, x]

Wolfram Language code: {Mean[𝒟], Variance[𝒟]}

Find a parameter mixture of a multivariate distribution:

Wolfram Language code: 𝒟 = ParameterMixtureDistribution[DirichletDistribution[{α, 1, 2}], αExponentialDistribution[1]]

Wolfram Language code: SmoothHistogram3D[RandomVariate[𝒟, 10 ^ 3]]

Scope (36)

Basic Uses (7)

Find the parameter mixture of ExponentialDistribution with uniformly distributed weight:

Wolfram Language code: 𝒟 = ParameterMixtureDistribution[ExponentialDistribution[λ], λUniformDistribution[{0, 1}]];

Probability density function:

Wolfram Language code: Plot[PDF[𝒟, x]//Evaluate, {x, 0, 10}, Filling -> Axis]

The weight domain must satisfy the parameter assumptions of the main distribution:

Wolfram Language code: DistributionParameterAssumptions[RayleighDistribution[σ]]

Pick a weight distribution supported on the positive reals:

Wolfram Language code: CDF[HalfNormalDistribution[4], σ]

Wolfram Language code: 𝒫 = ParameterMixtureDistribution[RayleighDistribution[σ], σHalfNormalDistribution[4]];

The resulting parameter mixture CDF:

Wolfram Language code: CDF[𝒫, x]

Wolfram Language code: Plot[CDF[𝒫, x]//Evaluate, {x, 0, 2}, Filling -> Axis]

Use a discrete weight for a discrete parameter:

Wolfram Language code:

𝒟1 = ParameterMixtureDistribution[BenfordDistribution[b + 2], bBinomialDistribution[10, .4]];
𝒟2 = ParameterMixtureDistribution[BenfordDistribution[b + 2], bBinomialDistribution[10, .7]];

Compare the probability density functions:

Wolfram Language code: Table[DiscretePlot[PDF[d, x], {x, 1, 10}, PlotRange -> {0, 0.5}, ExtentSize -> 1 / 2], {d, {𝒟1, 𝒟2}}]

Compare probabilities of obtaining a value less than 4 from each distribution:

Wolfram Language code: {Probability[x < 4, x𝒟1], Probability[x < 4, x𝒟2]}

Vary only one parameter:

Wolfram Language code: 𝒟 = ParameterMixtureDistribution[GammaDistribution[α, β], βExponentialDistribution[λ]];

Cumulative distribution function:

Wolfram Language code: CDF[𝒟, x]

Mean and variance:

Wolfram Language code: {Mean[𝒟], Variance[𝒟]}

Use a multivariate distribution as a weight to vary more than one parameter:

Wolfram Language code:

𝒟 = ParameterMixtureDistribution[NormalDistribution[μ, σ], {μ, σ}UniformDistribution[{{-1 / 2, 1 / 2}, {0, 2}}]];

Wolfram Language code: Plot[PDF[𝒟, x]//Evaluate, {x, -3, 3}, Filling -> Axis]

Use more than one weight distribution to vary multiple parameters:

Wolfram Language code:

𝒟 = ParameterMixtureDistribution[BorelTannerDistribution[α, n], {nPoissonDistribution[10], αUniformDistribution[{0, 1}]}];

Visualize the probability density function:

Wolfram Language code: Histogram[RandomVariate[𝒟, 10 ^ 3], {-0.5, 60.5, 3}, "PDF"]

Estimate parameters in a parameter mixture distribution:

Wolfram Language code: 𝒟 = ParameterMixtureDistribution[PoissonDistribution[λ], λBetaDistribution[α, β]];

Create a random sample for a choice of weight distribution parameters:

Wolfram Language code: sample = Block[{α = 2, β = 3}, RandomVariate[𝒟, 10 ^ 2]];

Find the distribution parameters:

Wolfram Language code: edist = EstimatedDistribution[sample, 𝒟]

Compare the histogram of the sample with the PDF of the estimated distribution:

Wolfram Language code: Show[Histogram[sample, {-0.5, 4.5, 1}, "PDF"], DiscretePlot[PDF[edist, x], {x, 0, 5}, PlotStyle -> PointSize[Medium]]]

Weight Distributions (5)

Define a parameter mixture with a continuous univariate weight distribution:

Wolfram Language code: 𝒟 = ParameterMixtureDistribution[PoissonDistribution[μ], μHalfNormalDistribution[θ]];

Wolfram Language code: pdf = PDF[𝒟, x]

Wolfram Language code: DiscretePlot[Table[pdf, {θ, {1 / 4, 1 / 2, 3 / 4}}]//Evaluate, {x, 0, 10}, PlotMarkers -> Automatic]

Define a parameter mixture with a discrete univariate weight distribution:

Wolfram Language code: 𝒟 = ParameterMixtureDistribution[ErlangDistribution[k + 1, λ], kPoissonDistribution[μ]];

Find the probability density function:

Wolfram Language code: PDF[𝒟, x]

Moment has closed form for a symbolic order:

Wolfram Language code: Moment[𝒟, r]

Define a parameter mixture with a discrete univariate weight distribution:

Wolfram Language code: 𝒟 = ParameterMixtureDistribution[BinomialDistribution[n, 0.3], nBenfordDistribution[b]];

Probability density function:

Wolfram Language code:

Table[DiscretePlot[PDF[𝒟, x]//Evaluate, {x, 0, 8}, ExtentSize -> 1 / 2, PlotRange -> {Full, {0, 0.6}}, ImageSize -> Small], {b, {4, 10}}]

Define a parameter mixture with a multivariate weight distribution:

Wolfram Language code: 𝒟 = ParameterMixtureDistribution[ParetoDistribution[a, 1, 1, b], {a, b}UniformDistribution[{{1, 2}, {0, 1}}]];

Probability density function:

Wolfram Language code: PDF[𝒟, x]

Verify that the integral of the PDF is 1:

Wolfram Language code: Integrate[PDF[𝒟, x], {x, -∞, ∞}]//Simplify

Use more than one weight distribution:

Wolfram Language code:

𝒟 = ParameterMixtureDistribution[UniformDistribution[{a, b}], {aUniformDistribution[], bUniformDistribution[{2, 3}]}];

Wolfram Language code: pdf = PDF[𝒟, x]

Wolfram Language code: Plot[pdf, {x, 0, 3}, Filling -> Axis, Exclusions -> None]

Mean:

Wolfram Language code: Mean[𝒟]

Wolfram Language code: N[%]

Variance:

Wolfram Language code: Variance[𝒟]

Wolfram Language code: N[%]

Parametric Distributions (8)

Define a parameter mixture of a continuous univariate distribution:

Wolfram Language code: 𝒟 = ParameterMixtureDistribution[NormalDistribution[a, 3], aExponentialDistribution[2]];

Cumulative distribution function:

Wolfram Language code: CDF[𝒟, x]

Wolfram Language code: Plot[CDF[𝒟, x]//Evaluate, {x, -6, 10}, Filling -> Axis]

Find a mixture of a continuous univariate distribution:

Wolfram Language code: 𝒟 = ParameterMixtureDistribution[CauchyDistribution[a, 1], aWaringYuleDistribution[1 / 10]];

Probability density function:

Wolfram Language code: pdf = PDF[𝒟, x]//FullSimplify

Wolfram Language code: Plot[pdf, {x, -4, 6}, Filling -> Axis]

Define a parameter mixture of a discrete univariate distribution:

Wolfram Language code: 𝒟 = ParameterMixtureDistribution[PascalDistribution[10, p], pBetaDistribution[1 / 2, 3]];

Wolfram Language code: DiscretePlot[PDF[𝒟, x], {x, 0, 50}]

Generate a random sample:

Wolfram Language code: data = RandomVariate[𝒟, 10 ^ 3];

Find the mean and variance:

Wolfram Language code: {Mean[data], Variance[data]}//N

Find a parameter mixture of a discrete univariate distribution:

Wolfram Language code: 𝒟 = ParameterMixtureDistribution[NegativeBinomialDistribution[n, 1 / 3], nGeometricDistribution[p]];

Probability density function:

Wolfram Language code: PDF[𝒟, x]

Mean and variance:

Wolfram Language code: {Mean[𝒟], Variance[𝒟]}

For a fixed value of , Moment has closed form for symbolic order:

Wolfram Language code: Block[{p = 1 / 4}, Moment[𝒟, r]]

Define a parameter mixture of a bivariate continuous distribution:

Wolfram Language code: 𝒟 = ParameterMixtureDistribution[BinormalDistribution[ρ], ρUniformDistribution[{0, 1}]];

Use a random sample and a smooth histogram to visualize the density function:

Wolfram Language code: sample = RandomVariate[𝒟, 10 ^ 3];

Wolfram Language code: SmoothHistogram3D[sample, Automatic, "PDF"]

Define a parameter mixture of a bivariate distribution:

Wolfram Language code:

𝒟 = ParameterMixtureDistribution[MultivariateTDistribution[{{1, 0}, {0, 1}}, ν], νDiscreteUniformDistribution[{3, 4}]];

Probability density function:

Wolfram Language code: Plot3D[PDF[𝒟, {x, y}]//Evaluate, {x, -2, 2}, {y, -2, 2}]

Wolfram Language code: PDF[𝒟, {x, y}]

Mean:

Wolfram Language code: Mean[𝒟]

Covariance matrix:

Wolfram Language code: Covariance[𝒟]//MatrixForm

Find a parameter mixture distribution of a multivariate discrete distribution:

Wolfram Language code:

𝒟 = ParameterMixtureDistribution[MultivariatePoissonDistribution[μ, {1, 2, 3}], μBirnbaumSaundersDistribution[2, 3]];

Generate a random sample:

Wolfram Language code: sample = RandomVariate[𝒟, 10 ^ 3];

Histograms for each component:

Wolfram Language code: Table[Histogram[sample[[All, i]], Automatic, "PDF"], {i, 3}]

LaplaceDistribution can be represented as a parametric mixture:

Wolfram Language code: 𝒟 = ParameterMixtureDistribution[NormalDistribution[μ, σ], σRayleighDistribution[ν]];

Wolfram Language code: PDF[𝒟, x]//Refine[#, {x, μ}∈Reals && ν > 0]&

Wolfram Language code: PDF[LaplaceDistribution[μ, ν], x]

Wolfram Language code: FullSimplify[% - %%]

Nonparametric Distributions (3)

Use an EmpiricalDistribution as a weight:

Wolfram Language code:

ed = EmpiricalDistribution[RandomVariate[ExponentialDistribution[2], 10]];
𝒟 = ParameterMixtureDistribution[NormalDistribution[0, σ], σed];

Probability density function:

Wolfram Language code: Plot[PDF[𝒟, x], {x, -2, 2}, PlotRange -> All, Filling -> Axis]

Wolfram Language code: PDF[𝒟, x]

Use a HistogramDistribution as a weight:

Wolfram Language code:

hd = HistogramDistribution[RandomVariate[ExponentialDistribution[2], 10]];
𝒟 = ParameterMixtureDistribution[NormalDistribution[0, σ], σhd];

Probability density function:

Wolfram Language code: Plot[PDF[𝒟, x]//Evaluate, {x, -2, 2}, PlotRange -> All, Filling -> Axis]

Wolfram Language code: PDF[𝒟, x]

Define a parameter mixture with a SmoothKernelDistribution as a weight:

Wolfram Language code:

skd = SmoothKernelDistribution[RandomVariate[GammaDistribution[2, 3], 10 ^ 2], MaxRecursion -> 3];
𝒟 = ParameterMixtureDistribution[NormalDistribution[μ, 1], μskd];

Plot the probability density function:

Wolfram Language code: Plot[PDF[𝒟, x]//Evaluate, {x, -5, 20}, PlotPoints -> 2, Filling -> Axis]

Plot the cumulative distribution function:

Wolfram Language code: Plot[CDF[𝒟, x]//Evaluate, {x, -5, 20}, PlotPoints -> 2, Filling -> Axis]

Derived Distributions (11)

Use a ProductDistribution as a weight distribution in a parameter mixture:

Wolfram Language code:

𝒫 = ProductDistribution[LogNormalDistribution[2, 1 / 3], LogNormalDistribution[1, 1 / 2]];
𝒟 = ParameterMixtureDistribution[BetaDistribution[α, β], {α, β}𝒫];

Use the histogram of a random sample from  to visualize the PDF:

Wolfram Language code: sample = RandomVariate[𝒟, 10 ^ 3];

Wolfram Language code: Show[Histogram[sample, 20, "PDF"], SmoothHistogram[sample, PlotStyle -> Thick]]

Find a parameter mixture distribution of a TransformedDistribution:

Wolfram Language code:

𝒫 = TransformedDistribution[u + 3, uGammaDistribution[α, β]];
𝒟 = ParameterMixtureDistribution[𝒫, {αExponentialDistribution[1 / 10], βUniformDistribution[{0, 1}]}];

Visualize the density function using a random sample:

Wolfram Language code:

sample = RandomVariate[𝒟, 10 ^ 3];
Show[Histogram[sample, Automatic, "PDF"], SmoothHistogram[sample, PlotStyle -> Thick, PlotRange -> All]]

Find a parameter mixture using a TransformedDistribution as a weight distribution:

Wolfram Language code:

𝒲 = TransformedDistribution[2 u, uExponentialDistribution[1]];
𝒟 = ParameterMixtureDistribution[MaxwellDistribution[σ], σ𝒲];

Probability density function:

Wolfram Language code: pdf = PDF[𝒟, x]

Wolfram Language code: Plot[pdf, {x, 0, 10}, Filling -> Axis]

Use a MixtureDistribution as a weight distribution in a parameter mixture:

Wolfram Language code:

ℳ = MixtureDistribution[{1, 2}, {PoissonDistribution[3], PoissonDistribution[13]}];
𝒟 = ParameterMixtureDistribution[ErlangDistribution[k + 1, 4], kℳ];

Probability density function:

Wolfram Language code: Plot[PDF[𝒟, x]//Evaluate, {x, 0, 7}, Filling -> Axis]

Mean and variance:

Wolfram Language code: {Mean[𝒟], Variance[𝒟]}

Vary weights in a MixtureDistribution according to a probability distribution:

Wolfram Language code:

ℳ = MixtureDistribution[{a, b}, {NormalDistribution[1, 1 / 2], NormalDistribution[-3, 1]}];
𝒟 = ParameterMixtureDistribution[ℳ, {a, b}UniformDistribution[{{0, 1}, {0, 1}}]];

Probability density function:

Wolfram Language code: pdf = PDF[𝒟, x]//PowerExpand

Compare to the MixtureDistribution with fixed weights at the average values:

Wolfram Language code:

{w1, w2} = Mean[UniformDistribution[{{0, 1}, {0, 1}}]];pdf2 = PDF[MixtureDistribution[{w1, w2}, {NormalDistribution[1, 1 / 2], NormalDistribution[-3, 1]}], x]//PowerExpand

Both density functions are equal:

Wolfram Language code: pdf - pdf2//FullSimplify

Wolfram Language code: Plot[{pdf, pdf2}, {x, -6, 4}, Filling -> Axis]

Define a parameter mixture of a TruncatedDistribution:

Wolfram Language code:

𝒟 = ParameterMixtureDistribution[TruncatedDistribution[{-1, b}, NormalDistribution[]], bBinomialDistribution[3, 0.7]];

Wolfram Language code: Plot[PDF[𝒟, x], {x, -1.5, 3}, Filling -> Axis]

Wolfram Language code: PDF[𝒟, x]

Mean and variance:

Wolfram Language code: {Mean[𝒟], Variance[𝒟]}

Define a parameter distribution of a TruncatedDistribution:

Wolfram Language code:

𝒟 = ParameterMixtureDistribution[TruncatedDistribution[{0, 4}, NormalDistribution[0, σ]], σUniformDistribution[{0, 1}]];

Visualize the probability density function using random sample:

Wolfram Language code: SmoothHistogram[RandomVariate[𝒟, 10 ^ 3], Filling -> Axis]

Use a TruncatedDistribution as a weight distribution in a parameter mixture:

Wolfram Language code:

𝒟 = ParameterMixtureDistribution[HalfNormalDistribution[θ], θTruncatedDistribution[{0, 2}, RayleighDistribution[2]]];

Probability density function:

Wolfram Language code: Plot[PDF[𝒟, x]//Evaluate, {x, 0, 4}, Filling -> Axis]

Wolfram Language code: PDF[𝒟, x]

Mean:

Wolfram Language code: Mean[𝒟]

Find a parameter mixture distribution of an OrderDistribution:

Wolfram Language code:

𝒫 = OrderDistribution[{NormalDistribution[], n + 1}, n + 1];
𝒟 = ParameterMixtureDistribution[𝒫, nPoissonDistribution[μ]];

Probability density function:

Wolfram Language code: pdf = PDF[𝒟, x]

Wolfram Language code: Plot[Table[pdf, {μ, {2, 5, 10}}]//Evaluate, {x, -3, 4}, Filling -> Axis]

Use an OrderDistribution as a weight distribution:

Wolfram Language code:

𝒲 = OrderDistribution[{ExponentialDistribution[λ], 4}, 4];
𝒟 = ParameterMixtureDistribution[PoissonDistribution[μ], μ𝒲];

Probability density function:

Wolfram Language code: pdf = PDF[𝒟, x]//FullSimplify[#, λ > 0]&

Wolfram Language code: DiscretePlot[Table[pdf, {λ, {1 / 4, 1 / 2, 1}}]//Evaluate, {x, 0, 12}, PlotMarkers -> Automatic]

Parameter mixture of QuantityDistribution evaluates to QuantityDistribution:

Wolfram Language code:

𝒟 = ParameterMixtureDistribution[QuantityDistribution[NormalDistribution[μ, σ], "Nanometers"], μCauchyDistribution[0, 𝓈]]

Wolfram Language code:

ParameterMixtureDistribution[QuantityDistribution[ExponentialDistribution[λ], "Nanometers"], λGammaDistribution[2, μ]]

Automatic Simplifications (2)

Discrete Distributions (1)

Parameter mixtures with BetaDistribution as a weight:

Wolfram Language code: ParameterMixtureDistribution[BinomialDistribution[n, p], p  BetaDistribution[a, b]]

Wolfram Language code:

ParameterMixtureDistribution[NegativeBinomialDistribution[n, p], 
	p  BetaDistribution[a, b]]

Parameter mixtures involving PoissonDistribution:

Wolfram Language code: ParameterMixtureDistribution[PoissonDistribution[v], v  ExponentialDistribution[m]]

Wolfram Language code: ParameterMixtureDistribution[PoissonDistribution[μ], μGammaDistribution[1, (1 - p) / p]]

Wolfram Language code: ParameterMixtureDistribution[PoissonDistribution[v], v  GammaDistribution[n, m]]

Wolfram Language code:

ParameterMixtureDistribution[BorelTannerDistribution[α, n], 
    n  PoissonDistribution[μ]]

Continuous Distributions (1)

Wolfram Language code: ParameterMixtureDistribution[ExponentialDistribution[λ], λExponentialDistribution[1]]

Parameter mixtures of RayleighDistribution:

Wolfram Language code: ParameterMixtureDistribution[RayleighDistribution[σ], σLogNormalDistribution[μ, ν]]

Wolfram Language code: ParameterMixtureDistribution[RayleighDistribution[Sqrt[σ]], σGammaDistribution[α, β]]

Parameter mixtures of NormalDistribution:

Wolfram Language code: ParameterMixtureDistribution[NormalDistribution[p, Subscript[σ, 1]], pNormalDistribution[μ, Subscript[σ, 2]]]

Wolfram Language code: ParameterMixtureDistribution[NormalDistribution[μ, σ], σRayleighDistribution[ν]]

Wolfram Language code: ParameterMixtureDistribution[NormalDistribution[μ, 1 / Sqrt[σ]], σGammaDistribution[α, β]]

Options (1)

Assumptions (1)

WaringYuleDistribution is a parameter mixture of geometric distribution and UniformDistribution:

Wolfram Language code: 𝒟 = ParameterMixtureDistribution[GeometricDistribution[w^1 / a], wUniformDistribution[], Assumptions -> a > 0];

Wolfram Language code: PDF[𝒟, k]

Compare with the built-in answer:

Wolfram Language code: PDF[WaringYuleDistribution[a], k]

Wolfram Language code: FullSimplify[% - %%]

Applications (7)

SuzukiDistribution is defined as a parameter mixture of RayleighDistribution and LogNormalDistribution:

Wolfram Language code: 𝒟 = ParameterMixtureDistribution[RayleighDistribution[σ], σLogNormalDistribution[μ, ν]]

KDistribution can be represented as a parameter mixture of RayleighDistribution and GammaDistribution:

Wolfram Language code: 𝒟 = ParameterMixtureDistribution[RayleighDistribution[Sqrt[σ]], σGammaDistribution[α, β / (2 α)]]

The time in minutes it takes a bank teller to serve a customer follows ExponentialDistribution, with average time having LindleyDistribution with mean 3. Find the service time distribution:

Wolfram Language code: {sol} = NSolve[Mean[LindleyDistribution[δ]] == 3 && δ > 0, δ]

Wolfram Language code:

𝒟 = ParameterMixtureDistribution[ExponentialDistribution[1 / Quantity[λ, "Minutes"]], λLindleyDistribution[δ]] /. sol;

Probability density function:

Wolfram Language code: pdf = PDF[𝒟, Quantity[t, "Minutes"]]

Wolfram Language code: Plot[pdf, {t, 0, 6}, Filling -> Axis, AxesLabel -> {"min"}]

The average service time:

Wolfram Language code: mean = Mean[𝒟]

Simulate the service time for the next 30 customers:

Wolfram Language code:

ListPlot[{RandomVariate[𝒟, 30], {{0, mean}, {30, mean}}}, Filling -> {1 -> Axis}, Joined -> {False, True}, AxesLabel -> Automatic]

In an optical communication system, transmitted light generates current at the receiver. The number of electrons follows the parametric mixture of a Poisson distribution and another distribution, depending on the type of light. If the source uses coherent laser light of intensity , then the electron-count distribution is Poisson:

Wolfram Language code:

𝒟1 = ParameterMixtureDistribution[PoissonDistribution[μ], μTransformedDistribution[λ x, xBernoulliDistribution[1]], Assumptions -> λ > 0];

Wolfram Language code: PDF[𝒟1, x]

Which is PoissonDistribution:

Wolfram Language code: PDF[PoissonDistribution[λ], x]

If the source uses thermal illumination, then the Poisson parameter follows ExponentialDistribution with parameter , and the electron count distribution can be determined:

Wolfram Language code:

𝒟2 = ParameterMixtureDistribution[PoissonDistribution[μ], μExponentialDistribution[1 / λ], Assumptions -> λ > 0]

These two distributions are distinguishable and allow you to determine the type of source:

Wolfram Language code: Block[{λ = 3}, Histogram[{RandomVariate[𝒟1, 10 ^ 4], RandomVariate[𝒟2, 10 ^ 4]}, {0, 20, 1}, "PDF"]]

The Voigt spectral line profile results from combining a Doppler (Cauchy) profile and a Lorentzian (normal) profile:

Wolfram Language code: ParameterMixtureDistribution[CauchyDistribution[μ, δ], μNormalDistribution[0, σ]]

Compute the density function:

Wolfram Language code: pdf[δ_, σ_, z_] = PDF[VoigtDistribution[δ, σ], z]

Plot the density function:

Wolfram Language code: Plot[pdf[1, 2, z], {z, -10, 10}, Filling -> Axis]

Compute the profile half-width:

Wolfram Language code: With[{δ = 1, σ = 2}, 2z /. FindRoot[pdf[δ, σ, z] == pdf[δ, σ, 0] / 2, {z, 2}]]//Chop

Define modified normal distribution:

Wolfram Language code:

ModifiedNormalDistribution[a_, σ_] = ParameterMixtureDistribution[NormalDistribution[0, σ Sqrt[t]], tPowerDistribution[1, a]];

Wolfram Language code: pdf[a_, σ_, x_] = PDF[ModifiedNormalDistribution[a, σ], x]

Plot modified normal distribution densities for several values of and compare them with standard normal density:

Wolfram Language code:

Show[Plot[{pdf[1, 1, x], pdf[2, 1, x], pdf[5, 1, x]}, {x, -5, 5}], Plot[PDF[NormalDistribution[], x], {x, -5, 5}, PlotStyle -> Dashed]]

Define multivariate Pólya distribution:

Wolfram Language code:

𝒟 = ParameterMixtureDistribution[NegativeMultinomialDistribution[10, {p1, p2}], {p1, p2}DirichletDistribution[{1, 2, 3}]];

Probability density function:

Wolfram Language code: pdf = PDF[𝒟, {x, y}]

Wolfram Language code: DiscretePlot3D[pdf, {x, 0, 10}, {y, 0, 10}, ExtentSize -> 1 / 2]

Properties & Relations (4)

The PDF of a parameter mixture can be computed using Expectation:

Wolfram Language code: 𝒟 = ParameterMixtureDistribution[ExponentialDistribution[λ], λUniformDistribution[{1, 2}]];

Wolfram Language code: PDF[𝒟, x]

Wolfram Language code: Expectation[PDF[ExponentialDistribution[λ], x], λUniformDistribution[{1, 2}]]

Parameter mixture with a discrete weight, assuming a finite number of values can be represented as a MixtureDistribution:

Wolfram Language code: 𝒟1 = ParameterMixtureDistribution[ErlangDistribution[k + 1, λ], kBinomialDistribution[3, p]];

Wolfram Language code:

weights = Table[PDF[BinomialDistribution[3, p], k], {k, 0, 3}];
dists = Table[ErlangDistribution[k + 1, λ], {k, 0, 3}];
𝒟2 = MixtureDistribution[weights, dists];

Compare PDFs:

Wolfram Language code: PDF[𝒟1, x]//FullSimplify

Wolfram Language code: PDF[𝒟2, x]//FullSimplify

Parameter mixture with a discrete weight, assuming a countable number of values can be approximated by a MixtureDistribution:

Wolfram Language code: 𝒟1 = ParameterMixtureDistribution[ErlangDistribution[k + 1, λ], kPoissonDistribution[μ]];

Wolfram Language code:

weights[q_] := Table[PDF[PoissonDistribution[μ], k], {k, 0, Quantile[PoissonDistribution[μ], q]}];
dists[q_] := Table[ErlangDistribution[k + 1, λ], {k, 0, Quantile[PoissonDistribution[μ], q]}];
𝒟2[q_] := MixtureDistribution[weights[q], dists[q]];

Compare approximations for different quantiles as cut-offs:

Wolfram Language code:

Legended[Block[{μ = 9, λ = 2}, Table[Plot[{PDF[𝒟1, x], PDF[𝒟2[q], x]}//Evaluate, {x, 0, 15}, PlotLabel -> Row[{"q = ", q}]], {q, {0.8, 0.9, 0.95, .99}}]], Placed[LineLegend[97, {"𝒟1", "𝒟2"}, LegendLayout -> "Row"], Below]]

Approximating a parameter mixture with a continuous weight by a MixtureDistribution:

Wolfram Language code:

weight𝒟 = WeibullDistribution[1.5, 3];
Plot[PDF[weight𝒟, x], {x, 0, 10}]

Wolfram Language code:

𝒟1 = ParameterMixtureDistribution[NormalDistribution[0, λ], λweight𝒟];
pdf1 = PDF[𝒟1, x];

Wolfram Language code:

weights[q_] := Table[PDF[weight𝒟, λ], {λ, Quantile[weight𝒟, q], Quantile[weight𝒟, 1 - q], 0.1}];
dists[q_] := Table[NormalDistribution[0, λ], {λ, Quantile[weight𝒟, q], Quantile[weight𝒟, 1 - q], 0.1}];
𝒟2[q_] := MixtureDistribution[weights[q], dists[q]];

Compare PDFs:

Wolfram Language code:

Legended[Table[Plot[({pdf1, PDF[𝒟2[q], x]}//Evaluate), {x, -3, 3}, PlotRange -> All, PlotLabel -> Row[{"q = ", q}]], {q, {0.1, 0.05, .01}}], Placed[LineLegend[97, {"𝒟1", "𝒟2"}, LegendLayout -> "Row"], Below]]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

ParameterMixtureDistribution

Details and Options

Examples

Basic Examples (3)

Scope (36)

Basic Uses (7)

Weight Distributions (5)

Parametric Distributions (8)

Nonparametric Distributions (3)

Derived Distributions (11)

Automatic Simplifications (2)

Discrete Distributions (1)

Continuous Distributions (1)

Options (1)

Assumptions (1)

Applications (7)

Properties & Relations (4)

Text

CMS

APA

BibTeX

BibLaTeX

ParameterMixtureDistribution

Details and Options

Examples

Basic Examples (3)

Scope (36)

Basic Uses (7)

Weight Distributions (5)

Parametric Distributions (8)

Nonparametric Distributions (3)

Derived Distributions (11)

Automatic Simplifications (2)

Discrete Distributions (1)

Continuous Distributions (1)

Options (1)

Assumptions (1)

Applications (7)

Properties & Relations (4)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX