WOLFRAM

Wolfram Language & System Documentation Center

PolygonalNumber[n]

gives the n^(th) triangular number .

PolygonalNumber[r,n]

gives the n^(th) r-gonal number .

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
Related Links
History
Cite this Page

PolygonalNumber

PolygonalNumber[n]

gives the n^(th) triangular number .

PolygonalNumber[r,n]

gives the n^(th) r-gonal number .

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • PolygonalNumber[n] is generically defined as TemplateBox[{{n, +, 1}, 2}, Binomial].
  • PolygonalNumber[r,n] is generically defined as .
  • PolygonalNumber[r,n] can be interpreted as the number of points arranged in the form of n-1 polygons of r sides. For instance for r=3 and n=4:
  • PolygonalNumber automatically threads over lists.

Examples

open all close all

Basic Examples  (2)

Return the first 10 triangular numbers:

Wolfram Language code: Table[PolygonalNumber[n], {n, 10}]

Return the tenth r-gonal number of several regular polygons:

Wolfram Language code: Table[PolygonalNumber[r, 10], {r, 3, 10}]

Scope  (4)

Use PolygonalNumber with integer arguments:

Wolfram Language code: PolygonalNumber[5, 3]
Wolfram Language code: PolygonalNumber[3, 5]

Use RegularPolygon to specify the number of sides of a regular polygon:

Wolfram Language code: PolygonalNumber[RegularPolygon[5], 3]
Wolfram Language code: PolygonalNumber[RegularPolygon[{0, 3}, 2, 5], 3]

PolygonalNumber automatically threads over lists:

Wolfram Language code: PolygonalNumber[4, Range[5, 10]]
Wolfram Language code: PolygonalNumber[Range[10, 20, 2], Range[5, 10]]

Use PolygonalNumber with symbolic input:

Wolfram Language code: PolygonalNumber[r, n]

Applications  (2)

Generate random octagonal numbers:

Wolfram Language code: SeedRandom[1]; numbers = RandomInteger[100, 10]; PolygonalNumber[8, numbers]

Plot the first 50 triangular, square, and pentagonal numbers:

Wolfram Language code: DiscretePlot[{PolygonalNumber[3, n], PolygonalNumber[4, n], PolygonalNumber[5, n]}, {n, 1, 50}, PlotLegends -> {"Triangular", "Square", "Pentagonal"}]

Properties & Relations  (9)

The 0^(th) polygonal number of any regular polygon is zero:

Wolfram Language code: Table[PolygonalNumber[r, 0], {r, 3, 10}]

The first polygonal number of any regular polygon is one:

Wolfram Language code: Table[PolygonalNumber[r, 1], {r, 3, 10}]

Every other triangular number is a hexagonal number:

Wolfram Language code: numbers = Range[100]; PolygonalNumber[2numbers - 1] == PolygonalNumber[6, numbers]

The sum of two consecutive triangular numbers is a square number:

Wolfram Language code: numbers = Range[100]; PolygonalNumber[numbers - 1] + PolygonalNumber[numbers] == PolygonalNumber[4, numbers]

Every pentagonal number is one third of a triangular number:

Wolfram Language code: numbers = Range[100]; PolygonalNumber[5, numbers] == 1 / 3 PolygonalNumber[3numbers - 1]

The difference between the n^(th) r-gonal number and the n^(th) (r+1)-gonal number is the (n-1)^(th) triangular number:

Wolfram Language code: sides = Range[3, 102]; numbers = Range[100]; (PolygonalNumber[#1 + 1, #2] - PolygonalNumber[#1, #2] == PolygonalNumber[#2 - 1])&[sides, numbers]

Even perfect numbers are triangular numbers related to Mersenne prime exponents:

Wolfram Language code: mersennePrime[n_] := 2 ^ MersennePrimeExponent[n] - 1; range = Range[40];
Wolfram Language code: PerfectNumber[range, "Even"] == PolygonalNumber[mersennePrime[range]]

Even perfect numbers are hexagonal numbers related to Mersenne prime exponents:

Wolfram Language code: powertwo[n_] := 2 ^ (MersennePrimeExponent[n] - 1); range = Range[40];
Wolfram Language code: PerfectNumber[range, "Even"] == PolygonalNumber[6, powertwo[range]]

All even perfect numbers greater than 6 are of the following form for some value of k:

Wolfram Language code: number[k_] := 1 + 9PolygonalNumber[8k + 2];
Wolfram Language code: PerfectNumber[2, "Even"] == number[0]
Wolfram Language code: PerfectNumber[3, "Even"] == number[1]
Wolfram Language code: PerfectNumber[4, "Even"] == number[5]
Wolfram Language code: PerfectNumber[5, "Even"] == number[341]
Wolfram Language code: PerfectNumber[6, "Even"] == number[5461]

Neat Examples  (1)

Visualize polygonal numbers:

Wolfram Language code: Manipulate[With[{ps = points[Range[0, n - 1], r]}, Labeled[Graphics[{PointSize[Large], Point /@ ps, Line /@ ps, Opacity[0.2], Polygon /@ ps}], PolygonalNumber[r, n]]], {{r, 4, "sides"}, 3, 10, 1}, {{n, 5, "steps"}, 1, 10, 1}, Initialization :> { points[0, r_] := {{0, 0}};points[n_Integer, r_] := Flatten[Subdivide[#1, #2, n]&@@@Partition[CirclePoints[-Last[CirclePoints[n, r]], n, r], 2, 1, 1], 1];points[ns_List, r_] := points[#, r]& /@ ns}]
Wolfram Research (2016), PolygonalNumber, Wolfram Language function, https://reference.wolfram.com/language/ref/PolygonalNumber.html.

Text

Wolfram Research (2016), PolygonalNumber, Wolfram Language function, https://reference.wolfram.com/language/ref/PolygonalNumber.html.

CMS

Wolfram Language. 2016. "PolygonalNumber." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/PolygonalNumber.html.

APA

Wolfram Language. (2016). PolygonalNumber. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/PolygonalNumber.html

BibTeX

@misc{reference.wolfram_2026_polygonalnumber, author="Wolfram Research", title="{PolygonalNumber}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/PolygonalNumber.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_polygonalnumber, organization={Wolfram Research}, title={PolygonalNumber}, year={2016}, url={https://reference.wolfram.com/language/ref/PolygonalNumber.html}, note=[Accessed: 13-June-2026]}