WOLFRAM

Wolfram Language & System Documentation Center

Primes

represents the domain of prime numbers, as in x∈Primes.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

Primes

Primes

represents the domain of prime numbers, as in x∈Primes.

Details

  • x∈Primes evaluates only if x is a numeric quantity.
  • Simplify[expr∈Primes] can be used to try to determine whether an expression corresponds to a prime number.
  • The domain of primes is taken to be a subset of the domain of integers.
  • PrimeQ[expr] returns False unless expr explicitly has head Integer.
  • Primes is output in TraditionalForm as TemplateBox[{}, Primes]. This typeset form can be input using pris.

Examples

open all close all

Basic Examples  (3)

The number is a prime:

Wolfram Language code: Element[2 ^ 107 - 1, Primes]

Fermat's little theorem:

Wolfram Language code: Simplify[Mod[a ^ p, p] == Mod[a, p], Element[a, Integers] && Element[p, Primes]]

Find primes satisfying an inequality:

Wolfram Language code: Reduce[10 ^ 6 < x < 10 ^ 6 + 100, x, Primes]

Scope  (4)

Test domain membership of a numeric expression:

Wolfram Language code: Element[107, Primes]

Make domain membership assumptions:

Wolfram Language code: FullSimplify[GCD[p, q], Element[p | q, Primes] && p ≠ q]

Specify the default domain for Reduce and FindInstance:

Wolfram Language code: Reduce[x ^ 2 + y ^ 2 ≤ 10, {x, y}, Primes]
Wolfram Language code: FindInstance[p > 10 ^ 10, p, Primes]

TraditionalForm formatting:

Wolfram Language code: Primes//TraditionalForm

Applications  (2)

Wilson's theorem [more info]:

Wolfram Language code: FullSimplify[Mod[(p - 1)!, p], Element[p, Primes]]

A list of twin primes:

Wolfram Language code: p /. FindInstance[Element[p, Primes] && Element[p + 2, Primes], p, 5]

Check:

Wolfram Language code: (And @@ PrimeQ[{#, # + 2}])& /@ %

Properties & Relations  (3)

Primes is contained in Complexes, Reals, Algebraics, Rationals, and Integers:

Wolfram Language code: Refine[Element[x, #], Element[x, Primes]]& /@ {Complexes, Reals, Algebraics, Rationals, Integers}

Simplifications involving prime numbers:

Wolfram Language code: Simplify[p + 1∈Primes, p∈Primes && p > 2]
Wolfram Language code: Simplify[Cos[(p + q)π], p∈Primes && q∈Primes && p > 2 && q > 2]

Primes represents the set of positive integers that are prime:

Wolfram Language code: Element[#, Primes]& /@ {17, -17}

PrimeQ gives True if an integer, positive or negative, is prime:

Wolfram Language code: PrimeQ /@ {17, -17}

PrimeQ returns True for explicit numeric primes and False otherwise:

Wolfram Language code: PrimeQ /@ {7, a, (E + 7) ^ 2 / 7 - E ^ 2 / 7 - 2E}

Element remains unevaluated when it cannot decide whether an expression is a prime:

Wolfram Language code: Element[#, Primes]& /@ {7, a, (E + 7) ^ 2 / 7 - E ^ 2 / 7 - 2E}
Wolfram Language code: Simplify[%]
Wolfram Research (1999), Primes, Wolfram Language function, https://reference.wolfram.com/language/ref/Primes.html (updated 2017).

Text

Wolfram Research (1999), Primes, Wolfram Language function, https://reference.wolfram.com/language/ref/Primes.html (updated 2017).

CMS

Wolfram Language. 1999. "Primes." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2017. https://reference.wolfram.com/language/ref/Primes.html.

APA

Wolfram Language. (1999). Primes. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Primes.html

BibTeX

@misc{reference.wolfram_2026_primes, author="Wolfram Research", title="{Primes}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/Primes.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_primes, organization={Wolfram Research}, title={Primes}, year={2017}, url={https://reference.wolfram.com/language/ref/Primes.html}, note=[Accessed: 13-June-2026]}