WOLFRAM

Wolfram Language & System Documentation Center

Element[x,dom]

or x∈dom asserts that x is an element of the domain dom.

Element[x,reg]

or x∈reg asserts that x is an element of the region reg.

Element[x1|x2|…,dom]

asserts that all the xi are elements of dom.

Element[patt,dom]

asserts that any expression matching the pattern patt is an element of dom.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Properties & Relations  
Possible Issues  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

Element

Element[x,dom]

or x∈dom asserts that x is an element of the domain dom.

Element[x,reg]

or x∈reg asserts that x is an element of the region reg.

Element[x1|x2|…,dom]

asserts that all the xi are elements of dom.

Element[patt,dom]

asserts that any expression matching the pattern patt is an element of dom.

Details

  • x∈dom can be entered as x el dom or x \[Element] dom.
  • Element can be used to set up assumptions in Simplify and related functions.
  • dom may be a numeric domain or a region in .
  • Possible domains dom are:
  • Algebraicsalgebraic numbers
    BooleansTrue or False
    Complexescomplex numbers
    Integersintegers
    Primesprime numbers
    Rationalsrational numbers
    Realsreal numbers
  • Possible regions reg are defined by RegionQ.
  • x∈dom if possible evaluates immediately when x is numeric.
  • For a domain dom, {x1,x2,…}∈dom is equivalent to (x1|x2|…)∈dom.
  • For a region reg, {x1,x2,…}∈reg asserts that the point with coordinates x1,x2,… belongs to reg.
  • {x1,x2,…}∈dom evaluates to (x1|x2|…)∈dom if its truth or falsity cannot immediately be determined.

Examples

open all close all

Basic Examples  (5)

Test whether is an element of the reals:

Wolfram Language code: Pi ∈ Reals

Test whether the point belongs to the unit disk:

Wolfram Language code: {1 / 2, 1 / 3}∈Disk[]

Express domain membership for an expression:

Wolfram Language code: Element[x + y, Reals]

Assert that the point belongs to the unit ball:

Wolfram Language code: Element[{x, y, z}, Ball[]]

Use element assertions to integrate over a region:

Wolfram Language code: Integrate[1, {x, y, z}∈Ball[]]

Or to optimize over a region:

Wolfram Language code: MinValue[x + y, {x, y, z}∈Ball[]]

Enter using elem:

Wolfram Language code: x∈Reals

Scope  (9)

Test domain membership:

Wolfram Language code: Element[Sqrt[2], #]& /@ {Complexes, Algebraics, Reals, Rationals, Integers, Primes}

Test region membership:

Wolfram Language code: Subscript[ℛ, 1] = Disk[{1, 1}]; Subscript[ℛ, 2] = Rectangle[{0, 0}, {1, 1}]; Subscript[ℛ, 3] = ImplicitRegion[x ^ 2 ≤ y ^ 3 + 1, {x, y}]; Subscript[ℛ, 4] = RegionUnion[Disk[{-1, 0}], Line[{{0, 0}, {2, 2}}]];
Wolfram Language code: Element[{3 / 2, 3 / 2}, #]& /@ {Subscript[ℛ, 1], Subscript[ℛ, 2], Subscript[ℛ, 3], Subscript[ℛ, 4]}

Plot it:

Wolfram Language code: Show[{DiscretizeRegion[Subscript[ℛ, 3]], Graphics[{{Opacity[0.5], {Orange, Subscript[ℛ, 1]}, {Yellow, Subscript[ℛ, 2]}, {Green, Disk[{-1, 0}], Line[{{0, 0}, {2, 2}}]}}, {Red, PointSize[Large], Point[{3 / 2, 3 / 2}]}}]}]

Make domain membership assumptions:

Wolfram Language code: Refine[Sin[Pi x], Element[x, Integers]]
Wolfram Language code: Integrate[Abs[1 - Abs[x + 2]], x, Assumptions -> Element[x, Reals]]

Express region membership:

Wolfram Language code: Refine[Sqrt[(x + y - 2) ^ 2], Element[{x, y}, Disk[]]]
Wolfram Language code: Solve[x + y == 1 / 2 && Element[{x, y}, Circle[]], {x, y}]
Wolfram Language code: Integrate[1, Element[{x, y}, Circle[]]]

Test domain membership using assumptions:

Wolfram Language code: Refine[Element[x ^ y + Log[x + y], Reals], x > 0 && y > 0]

Test region membership using assumptions:

Wolfram Language code: Refine[Element[{x, y}, Rectangle[{-1, -1}, {1, 1}]], x ^ 2 + y ^ 2 ≤ 1]

Specify variable domains:

Wolfram Language code: Reduce[E ^ x - 2x == 3 && Element[x, Reals], x]
Wolfram Language code: FindInstance[x ^ 2 - 2y ^ 2 == 1 && x > 10 ^ 10 && Element[x | y, Integers], {x, y}]
Wolfram Language code: Minimize[{x - y, x ^ 2 + y ^ 2 ≤ 100 && Element[x | y, Integers]}, {x, y}]

Specify assumptions on objects matching a pattern:

Wolfram Language code: Simplify[Sin[2Pi x[1] + 4x[2]x[3] ^ 2Pi + a Pi], Element[x[_], Integers]]

TraditionalForm formatting:

Wolfram Language code: Element[x, Reals]//TraditionalForm

Properties & Relations  (2)

For a single variable, the negation of Element is automatically converted to NotElement:

Wolfram Language code: !Element[a, Reals]

For multiple variables, the negation of Element is not automatically simplified:

Wolfram Language code: !Element[a | b | c, Reals]

Use LogicalExpand to find the representation in terms of NotElement:

Wolfram Language code: LogicalExpand[%]

Element asserts region membership:

Wolfram Language code: Element[{x, y}, Disk[]]

RegionMember gives explicit region membership conditions:

Wolfram Language code: RegionMember[Disk[], {x, y}]

Possible Issues  (1)

When domain membership cannot be decided the Element statement remains unevaluated:

Wolfram Language code: Element[I ^ Pi, Algebraics]
Wolfram Research (1999), Element, Wolfram Language function, https://reference.wolfram.com/language/ref/Element.html (updated 2014).

Text

Wolfram Research (1999), Element, Wolfram Language function, https://reference.wolfram.com/language/ref/Element.html (updated 2014).

CMS

Wolfram Language. 1999. "Element." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/Element.html.

APA

Wolfram Language. (1999). Element. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Element.html

BibTeX

@misc{reference.wolfram_2026_element, author="Wolfram Research", title="{Element}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Element.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_element, organization={Wolfram Research}, title={Element}, year={2014}, url={https://reference.wolfram.com/language/ref/Element.html}, note=[Accessed: 12-June-2026]}