WOLFRAM

Wolfram Language & System Documentation Center

QuestionInterface[type,<|p1s1,p2s2,…|>]

defines an interface for a QuestionObject using the given type and properties pi with settings si.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Generalizations & Extensions  
See Also
Related Guides
History
Cite this Page

QuestionInterface   

List of interface types »

QuestionInterface[type,<|p1s1,p2s2,…|>]

defines an interface for a QuestionObject using the given type and properties pi with settings si.

Details

Examples

open all close all

Basic Examples  (2)

Create a multiple-choice poll question:

Wolfram Language code: QuestionObject[QuestionInterface["MultipleChoice", <|"Prompt" -> "What is your favorite ice cream flavor?", "Choices" -> {"Vanilla", "Strawberry", "Chocolate", "Cookie Dough"}|>]]

Create a free-form poll question:

Wolfram Language code: QuestionObject[QuestionInterface["ShortAnswer", <|"Prompt" -> "What is your favorite Sci-Fi movie?"|>]]

Scope  (8)

Create a grid for assigning an answer to each of several items:

Wolfram Language code: QuestionObject[QuestionInterface["MultipleChoiceGrid", <|"Prompt" -> "Order the US Presidents by inauguration date:", "Choices" -> {"Washington", "Lincoln", "Kennedy"}, "Categories" -> {"First", "Second", "Third"}|>]]

Make an interface for pairing two items:

Wolfram Language code: QuestionObject[QuestionInterface["SelectPair", <|"Prompt" -> "Choose a good food and wine pairing?", "Choices" -> {"Steak", "Pancakes", "Cheese"}, "Categories" -> {"Pinot Grigio", "Chardonnay", "Merlot"}|>]]

Create a multiple-choice question with assessment:

Wolfram Language code: QuestionObject[QuestionInterface["MultipleChoice", <|"Prompt" -> "What is the capitol of Alberta?", "Choices" -> {"Calgary", "Edmonton", "Banff"}|>], AssessmentFunction["Edmonton"]]

Create a true/false question with a test for assessment:

Wolfram Language code: QuestionObject[QuestionInterface["TrueFalse", <|"Prompt" -> "A whale is a mammal, true or false?"|>], TrueQ]

Create a quiz with a color as an input and assessment using tolerance:

Wolfram Language code: QuestionObject[QuestionInterface["SelectColor", <|"Prompt" -> "What color is a pickle?"|>], AssessmentFunction[Green, Tolerance -> 0.2]]

Create a multiple-choice question with multiple correct answers:

Wolfram Language code: QuestionObject[QuestionInterface["ChooseMultiple", <|"Prompt" -> "Which quarterbacks have won a Super Bowl?", Appearance -> "Vertical"|>], AssessmentFunction[{"Joe Montana" -> 1, "Dan Marino" -> 0, "John Elway" -> 1, "Philip Rivers" -> 0, "Brett Favre" -> 1}, <|"ElementwiseAssessment" -> True|>]]

Create a slider-based question interface with assessment using a test function:

Wolfram Language code: QuestionObject[QuestionInterface["NumericRange", <|"Prompt" -> "How many people live in Tokyo?", "Range" -> {.2, 5} * QuantityMagnitude[Entity["City", {"Tokyo", "Tokyo", "Japan"}][EntityProperty["City", "Population"]]]|>], Between[{.8, 1.2} * QuantityMagnitude[Entity["City", {"Tokyo", "Tokyo", "Japan"}][EntityProperty["City", "Population"]]]]]

Create a question that hides the results of the assessment from the user:

Wolfram Language code: QuestionObject[QuestionInterface["MultipleChoice", <|"Prompt" -> "What is 4^3?", "ShowAssessment" -> False|>], AssessmentFunction[{16, -64, 64 -> 1}]]

The assessment above is lost. Use EpilogFunction in QuestionObject to record the result:

Wolfram Language code: QuestionObject[QuestionInterface["MultipleChoice", <|"Prompt" -> "What is 4^3?", "ShowAssessment" -> False|>], AssessmentFunction[{16, -64, 64 -> 1}], EpilogFunction -> (PutAppend[#Assessment, "assessmentresults"]&)]

See the recorded assessments:

Wolfram Language code: ReadList["assessmentresults"]

Clean up the records:

Wolfram Language code: DeleteFile["assessmentresults"]

Generalizations & Extensions  (1)

Use arbitrary content in the prompt:

Wolfram Language code: QuestionObject[QuestionInterface["TrueFalse", <|"Prompt" -> Grid[{{Entity["TaxonomicSpecies", "BalaenopteraMusculus::mk5bs"][EntityProperty["TaxonomicSpecies", "Image"]]}, {Style["A whale is a fish", 16]}, {Style["TRUE OR FALSE", 12, Italic]}}]|>], Not]
Wolfram Research (2021), QuestionInterface, Wolfram Language function, https://reference.wolfram.com/language/ref/QuestionInterface.html (updated 2025).

Text

Wolfram Research (2021), QuestionInterface, Wolfram Language function, https://reference.wolfram.com/language/ref/QuestionInterface.html (updated 2025).

CMS

Wolfram Language. 2021. "QuestionInterface." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/QuestionInterface.html.

APA

Wolfram Language. (2021). QuestionInterface. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/QuestionInterface.html

BibTeX

@misc{reference.wolfram_2026_questioninterface, author="Wolfram Research", title="{QuestionInterface}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/QuestionInterface.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_questioninterface, organization={Wolfram Research}, title={QuestionInterface}, year={2025}, url={https://reference.wolfram.com/language/ref/QuestionInterface.html}, note=[Accessed: 12-June-2026]}