WOLFRAM

Wolfram Language & System Documentation Center
"TextCompletion" (Question Interface Type)

"TextCompletion" (Question Interface Type)

"TextCompletion"

provides a fill-in-the-blank interface with textual input fields.

Properties

  • In QuestionInterface["TextCompletion",props], props is an Association that supports the following keys in addition to the options supported by InputField:
  • "Prompt"Nonetext asking the user a question
    "Template"(required)string template with slots to be filled
    FieldSizeAutomaticsize of input fields
  • The "Template" should be a string of the type used in StringTemplate. Template slots denoted by backticks `` define locations for blanks in the question interface.
  • Additionally, options for InputField are supported including:
  • BackgroundAutomaticinput field background color
    FieldHintNullexpression to display when the input field is empty
    FieldSize{{{{5,Infinity},{1,Infinity}}}}the size of the menu field
  • For an InputField setting optvalue, the following forms of value are supported:
  • expruse expr for all fields
    {expr1, expr2, …}use the expri in order for each field, then use defaults
    {expr1, expr2,…,{c},exprm,…,exprn}use the sequence of expri, then repeatedly use c, then use the last sequence of expri at the end
    {i1->v1,i2->v2,…}specify what to use at positions ik
    {spec,rules}use rules to override specifications in spec

Corresponding AssessmentFunction

Examples

open all close all

Basic Examples  (3)

Create a text completion interface without assessment:

Wolfram Language code: QuestionObject[QuestionInterface["TextCompletion", <|"Prompt" -> "Fill in the form", "Template" -> "Name ``"|>]]

Define a text completion question with assessment:

Wolfram Language code: QuestionObject[QuestionInterface["TextCompletion", <|"Prompt" -> "Fill in the countries", "Template" -> "Shanghai is in `` and London is in ``"|>], AssessmentFunction[{{"China", "England"}}]]

Create a text completion question providing a full TemplateObject:

Wolfram Language code: cellularRespiration = TemplateObject[{"SubscriptBox[C, 6]SubscriptBox[H, 12]SubscriptBox[O, 6]+", TemplateSlot[1], "SubscriptBox[O, 2]->", TemplateSlot[2], "SubscriptBox[CO, 2]+", TemplateSlot[3], "SubscriptBox[H, 2]O"}]
Wolfram Language code: QuestionObject[QuestionInterface["TextCompletion", <|"Prompt" -> "Complete the mass balance of the following reaction", "Template" -> cellularRespiration|>], AssessmentFunction[{{"6", "6", "6"} -> 1}]]

Scope  (3)

A question with multiple possible correct answers:

Wolfram Language code: QuestionObject[QuestionInterface["TextCompletion", <|"Prompt" -> "Give the correct color", "Template" -> "Apples are ``"|>], AssessmentFunction[{{"red"}, {"green"}}]]

Specify an interpreter to standardize input as well as an image to include in the prompt:

Wolfram Language code: QuestionObject[QuestionInterface["TextCompletion", <|"Prompt" -> Column[{"Identify the animal", [image]}], "Template" -> "This is a `` ", "Interpreter" -> "Species"|>], AssessmentFunction[{Entity["TaxonomicSpecies", "Ursidae::46k8d"]}, <|"Comparator" -> (First[#1]["Family"] === #2["Family"]&)|>] ]

Create a grammar question:

Wolfram Language code: QuestionObject[QuestionInterface["TextCompletion", <|"Prompt" -> "Complete the sentence using proper grammar", "Template" -> "I arrived `` Chicago `` Monday "|>], AssessmentFunction[{{"in", "on"}}]]

Generalizations & Extensions  (1)

Customize the input fields' color and include hints:

Wolfram Language code: QuestionObject[QuestionInterface["TextCompletion", <|"Prompt" -> "Fill in the right words", "Template" -> "During the archery contest, `` Hood amazed the `` by `` an `` with such precision that it `` the bullseye.", FieldHint -> {"R   ", "cr  ", "sh     ", "rr ", "st  k"}, DefaultFieldHintStyle -> GrayLevel[0.6], Background -> {{Blue}, 1 -> Cyan, 3 -> Yellow, 5 -> Yellow}|>], AssessmentFunction[{{"Robin", "crowd", "shooting", "arrow", "struck"}}]]

Applications  (1)

Create a question generator for a fill-in-the-blank question:

Wolfram Language code: gen = QuestionGenerator[{"a" :> RandomInteger[10], "b" :> RandomInteger[10]}, QuestionObject[QuestionInterface["TextCompletion", <|"Prompt" -> "Fill in the blank", "Template" -> StringTemplate["`a` plus `b` equals "][#] <> "``?"|>], AssessmentFunction[{ToString[#a + #b]} -> 1]]&]

Create three instances of the question:

Wolfram Language code: Table[gen[], {3}]

Possible Issues  (2)

The values in the AssessmentFunction should be lists:

Wolfram Language code: QuestionObject[QuestionInterface["TextCompletion", <|"Prompt" -> "Fill in the blank", "Template" -> "apples are ``"|>], AssessmentFunction["red" -> 1]]

Specify the values as a list instead:

Wolfram Language code: QuestionObject[QuestionInterface["TextCompletion", <|"Prompt" -> "Fill in the blank", "Template" -> "apples are ``"|>], AssessmentFunction[{"red"} -> 1]]

The TemplateObject created by StringTemplate contains options incompatible with "TextCompletion":

Wolfram Language code: fromStringTemplate = StringTemplate["`` and Juliet"]
Wolfram Language code: Options[fromStringTemplate]

Attempting to use this template will create a broken interface:

Wolfram Language code: QuestionObject[QuestionInterface["TextCompletion", <|"Prompt" -> "Fill in the blank", "Template" -> fromStringTemplate|>], AssessmentFunction[{{"Romeo"}}]]

Remove the option settings:

Wolfram Language code: withoutOptions = TemplateObject[First@fromStringTemplate]

Now the template works in "TextCompletion":

Wolfram Language code: QuestionObject[QuestionInterface["TextCompletion", <|"Prompt" -> "Fill in the blank", "Template" -> withoutOptions|>], AssessmentFunction[{{"Romeo"}}]]

Alternatively, use TemplateObject directly instead of StringTemplate:

Wolfram Language code: directTemplate = TemplateObject[{TemplateSlot[1], " and Juliet"}];

This template does not have any options settings:

Wolfram Language code: Options[directTemplate]

It works in "TextCompletion":

Wolfram Language code: QuestionObject[QuestionInterface["TextCompletion", <|"Prompt" -> "Fill in the blank", "Template" -> directTemplate|>], AssessmentFunction[{{"Romeo"}}]]