WOLFRAM

Wolfram Language & System Documentation Center

RandomArrayLayer[dist]

represents a net layer that has no input and produces a random array from the univariate distribution dist.

RandomArrayLayer[dfunc]

uses the univariate distribution dfunc[input] for each input value.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Arguments  
Ports  
Applications  
See Also
Related Guides
History
Cite this Page

RandomArrayLayer

RandomArrayLayer[dist]

represents a net layer that has no input and produces a random array from the univariate distribution dist.

RandomArrayLayer[dfunc]

uses the univariate distribution dfunc[input] for each input value.

Details and Options

Examples

open all close all

Basic Examples  (2)

Create a layer that draws 3 samples from a unit normal distribution:

Wolfram Language code: ra = RandomArrayLayer[NormalDistribution[], "Output" -> 3]

Sample a random vector:

Wolfram Language code: ra[]

Create a layer that draws samples from independent normal distributions whose means are determined by the input:

Wolfram Language code: ra = RandomArrayLayer[NormalDistribution[#, 1]&]

Sample a random vector with given values for the mean:

Wolfram Language code: ra[{-10, 0, 10}]

Scope  (3)

Arguments  (2)

Create a layer that draws real numbers from independent normal distributions whose means and standard deviations are determined by the inputs:

Wolfram Language code: ra = RandomArrayLayer[NormalDistribution[#1, #2]&]

Sample a random vector with given values for the mean and the standard deviation of the Gaussian distribution:

Wolfram Language code: ra[{{-10, 0, 10}, {0.01, 1, 100}}]

Create the same layer with custom input port names:

Wolfram Language code: ra = RandomArrayLayer[NormalDistribution[#μ, #σ]&]

Sample random numbers with this layer:

Wolfram Language code: ra[<|"μ" -> {-10, 0, 10}, "σ" -> {0.01, 1, 100}|>]

Create a layer that draws integers in a given range:

Wolfram Language code: ra = RandomArrayLayer[DiscreteUniformDistribution[{1, #Max}]&]

Sample random integers with given upper bounds:

Wolfram Language code: ra[{10, 100, 1000}]

Ports  (1)

Create a layer that draws a sequence of bounded integers with the same length as a given input:

Wolfram Language code: ra = RandomArrayLayer[DiscreteUniformDistribution[{1, 3}]&, "Inputs" -> {"Varying"}]

Sample a sequence of integers with different given lengths:

Wolfram Language code: ra[Range /@ {1, 3, 6, 12}]

Applications  (2)

Build a network that sums an array and a random vector drawn from a Gaussian distribution:

Wolfram Language code: noiser = NetGraph[{RandomArrayLayer[NormalDistribution[0, 0.2]], Plus}, {{1, NetPort["Input"]} -> 2}]

Apply the net to a matrix:

Wolfram Language code: noiser[(⁠| | | | | -- | -- | -- | | 1 | 2 | 3 | | -1 | -2 | -3 |⁠)]//MatrixForm

Apply the net to lists of different lengths:

Wolfram Language code: noiser[{{1, 2}, {1, 0, -1, -2, -3}}]

Derive a network that adds noise to images, by attaching an input NetEncoder and an output NetDecoder:

Wolfram Language code: imagenoiser = NetReplacePart[noiser, {"Input" -> NetEncoder["Image"], "Output" -> NetDecoder["Image"]}]

Apply the net on an image:

Wolfram Language code: imagenoiser[[image]]

Build a network that masks a vector of integers with a particular integer value, with a probability to switch a value of 0.3:

Wolfram Language code: integerpadder = NetGraph[{RandomArrayLayer[BernoulliDistribution[0.3]], ThreadingLayer[If[#1 > 0, 4, #2]&]}, {{1, NetPort["Input"]} -> 2}, "Input" -> {Automatic, Restricted["Integer", 3]}]

Apply the random mask to some inputs:

Wolfram Language code: integerpadder[{{1, 2, 3, 1, 2, 3}, {3, 2, 1, 3, 2, 1, 3, 2, 1, 3, 2, 1}}]
Wolfram Research (2020), RandomArrayLayer, Wolfram Language function, https://reference.wolfram.com/language/ref/RandomArrayLayer.html.

Text

Wolfram Research (2020), RandomArrayLayer, Wolfram Language function, https://reference.wolfram.com/language/ref/RandomArrayLayer.html.

CMS

Wolfram Language. 2020. "RandomArrayLayer." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/RandomArrayLayer.html.

APA

Wolfram Language. (2020). RandomArrayLayer. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/RandomArrayLayer.html

BibTeX

@misc{reference.wolfram_2026_randomarraylayer, author="Wolfram Research", title="{RandomArrayLayer}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/RandomArrayLayer.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_randomarraylayer, organization={Wolfram Research}, title={RandomArrayLayer}, year={2020}, url={https://reference.wolfram.com/language/ref/RandomArrayLayer.html}, note=[Accessed: 13-June-2026]}