WOLFRAM

Wolfram Language & System Documentation Center

RenewalProcess[rdist]

represents a renewal process with interarrival times distributed according to rdist.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Continuous Interarrival Distributions  
Discrete Interarrival Distributions  
Parameter Estimation  
Applications  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

RenewalProcess

RenewalProcess[rdist]

represents a renewal process with interarrival times distributed according to rdist.

Details

  • RenewalProcess is a continuous- or discrete-time and discrete-state process.
  • RenewalProcess is a discrete-state and continuous-time or discrete-time process depending on rdist.
  • The state is the number of events in the interval 0 to and .
  • The distribution rdist can be any continuous or discrete distribution with positive domain.
  • RenewalProcess can be used with such functions as Mean, PDF, Probability, and RandomFunction.

Examples

open all close all

Basic Examples  (2)

Simulate a renewal process:

Wolfram Language code: data = RandomFunction[RenewalProcess[LogNormalDistribution[.2, 1]], {25}]
Wolfram Language code: ListStepPlot[data, Filling -> Axis]

Mean function:

Wolfram Language code: Mean[RenewalProcess[GammaDistribution[.2, 1]][4]]

Scope  (6)

Continuous Interarrival Distributions  (2)

Renewal process with interarrival times that follow an Erlang distribution:

Wolfram Language code: proc[k_, λ_] := RenewalProcess[ErlangDistribution[k, λ]];

Slice distribution functions:

Wolfram Language code: DiscretePlot[#[proc[3, 4][12], x], {x, 0, 30}, PlotRange -> All, ExtentSize -> 1 / 2, PlotLabel -> #]& /@ {PDF, CDF, HazardFunction, SurvivalFunction}

Compute the probability of an event:

Wolfram Language code: Probability[x[27] < 5, xproc[2, 1 / 3]]

Simulate the process:

Wolfram Language code: ListPlot[Table[RandomFunction[proc[2, λ], {200}], {λ, #}], PlotLegends -> (StringJoin["λ = ", ToString[#]]& /@ #)]&@{.2, .5, .7}

Renewal process with interarrival times that follow a gamma distribution:

Wolfram Language code: proc[α_, β_] = RenewalProcess[GammaDistribution[α, β]];

Slice distribution functions:

Wolfram Language code: DiscretePlot[#[proc[.7, 2][12], x], {x, 0, 30}, PlotRange -> All, ExtentSize -> 1 / 2, PlotLabel -> #]& /@ {PDF, CDF, HazardFunction, SurvivalFunction}

Compute the probability of an event:

Wolfram Language code: Probability[12 < x[12] ^ 3 + 12x[12] < 120, xproc[.7, 2]]
Wolfram Language code: NProbability[12 < x[12] ^ 3 + 12x[12] < 120, xproc[.7, 2]]

Simulate the process:

Wolfram Language code: ListPlot[Table[RandomFunction[proc[.7, β], {200}], {β, #}], PlotLegends -> (StringJoin["β = ", ToString[#]]& /@ #)]&@{.5, 1, 2}

Discrete Interarrival Distributions  (2)

Renewal process with interarrival times that follow a Pascal distribution:

Wolfram Language code: proc[p_] := RenewalProcess[PascalDistribution[3, p]]

Slice distribution functions:

Wolfram Language code: DiscretePlot[#[proc[.4][70], x], {x, 0, 15}, PlotRange -> All, ExtentSize -> 1 / 2, PlotLabel -> #]& /@ {PDF, CDF, HazardFunction, SurvivalFunction}

Compute the probability of an event:

Wolfram Language code: Probability[x[20] < 5, xproc[.7]]

Simulate the process:

Wolfram Language code: ListPlot[Table[RandomFunction[proc[p], {300}], {p, #}], PlotLegends -> (StringJoin["p = ", ToString[#]]& /@ #)]&@{.2, .5, .7}

Renewal process with interarrival times that follow a Borel–Tanner distribution:

Wolfram Language code: proc[p_] := RenewalProcess[BorelTannerDistribution[p, 2]]

Slice distribution functions:

Wolfram Language code: DiscretePlot[#[proc[.4][70], x], {x, 0, 30}, PlotRange -> All, ExtentSize -> 1 / 2, PlotLabel -> #]& /@ {PDF, CDF, HazardFunction, SurvivalFunction}

Compute the probability of an event:

Wolfram Language code: Probability[x[100] < 5, xproc[.7]]

Simulate the process:

Wolfram Language code: ListPlot[Table[RandomFunction[proc[p], {1, 300}], {p, #}], PlotLegends -> (StringJoin["p = ", ToString[#]]& /@ #)]&@{.2, .5, .7}

Parameter Estimation  (2)

Process parameter estimation:

Wolfram Language code: sample = RandomFunction[RenewalProcess[BetaDistribution[1, 3]], {10 ^ 3}];

Estimate the distribution parameters from sample data:

Wolfram Language code: EstimatedProcess[sample, RenewalProcess[BetaDistribution[a, b]]]

Approximate value of the mean:

Wolfram Language code: ListLinePlot@Table[Mean[RenewalProcess[WeibullDistribution[1, .7]][t]], {t, 0.5, 8, .5}]
Wolfram Language code: ListLinePlot@Table[Mean[RenewalProcess[GammaDistribution[1, 4]][t]], {t, 0.5, 8, .5}]

Applications  (1)

Messages arrive at a communication line according to a two-phase hyperexponential distribution with phase probabilities 0.4 and 0.6. The average arrival times for the two phases are 4.8 milliseconds and 0.8 milliseconds, respectively. Simulate the process for 100 milliseconds:

Wolfram Language code: communicationLine = RenewalProcess[HyperexponentialDistribution[{0.4, 0.6}, {1 / 4.8, 1 / 0.8}]];
Wolfram Language code: ListStepPlot[RandomFunction[communicationLine, {0, 100}], Filling -> Axis]

Mean number of arrivals during the first 10 milliseconds:

Wolfram Language code: Mean[communicationLine[10]]

Compare with the value obtained from simulation of the time slice distribution:

Wolfram Language code: Mean[RandomVariate[communicationLine[10], 10 ^ 4]]//N

Properties & Relations  (2)

RenewalProcess is a jump process:

Wolfram Language code: path = RandomFunction[RenewalProcess[WeibullDistribution[2, .7]], {10}]; f = path["PathFunction"]; jumps = path["Times"];
Wolfram Language code: Plot[f[t], {t, 0, 10}, Exclusions -> jumps, ExclusionsStyle -> Red]

RenewalProcess is not weakly stationary for any distribution:

Wolfram Language code: WeakStationarity[RenewalProcess[GammaDistribution[a, b]]]
Wolfram Language code: WeakStationarity[RenewalProcess[PascalDistribution[n, p]]]

Possible Issues  (1)

Closed forms are not available for most properties:

Wolfram Language code: 𝒫 = RenewalProcess[BetaDistribution[1, 3]];
Wolfram Language code: Mean[𝒫[1]]

Obtain approximate values using inexact input or simulation:

Wolfram Language code: Mean[𝒫[1.]]
Wolfram Language code: Mean[RandomVariate[𝒫[1], 10 ^ 4]]//N
Wolfram Research (2012), RenewalProcess, Wolfram Language function, https://reference.wolfram.com/language/ref/RenewalProcess.html.

Text

Wolfram Research (2012), RenewalProcess, Wolfram Language function, https://reference.wolfram.com/language/ref/RenewalProcess.html.

CMS

Wolfram Language. 2012. "RenewalProcess." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/RenewalProcess.html.

APA

Wolfram Language. (2012). RenewalProcess. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/RenewalProcess.html

BibTeX

@misc{reference.wolfram_2026_renewalprocess, author="Wolfram Research", title="{RenewalProcess}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/RenewalProcess.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_renewalprocess, organization={Wolfram Research}, title={RenewalProcess}, year={2012}, url={https://reference.wolfram.com/language/ref/RenewalProcess.html}, note=[Accessed: 12-June-2026]}