WOLFRAM

Wolfram Language & System Documentation Center

SemanticRanking[{text1, …},ref]

sorts textual items texti by semantic similarity to the reference string ref.

SemanticRanking[list,ref,prop]

returns the specified property prop.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
Method  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

SemanticRanking

SemanticRanking[{text1, …},ref]

sorts textual items texti by semantic similarity to the reference string ref.

SemanticRanking[list,ref,prop]

returns the specified property prop.

Details and Options

  • SemanticRanking reorders the input textual list according to semantic similarity to a provided reference string.
  • SemanticRanking[{text1, text2, text3,… }, ref] sorts texti from the most to least similar.
  • Possible values for prop include:
  • "Ordering"similarity rank for each item
    "Item"items in the original order
    "Rank"item position in the ordered list
    "RankedItem"items reordered from most to least similar (default)
    "Relevance"numerical similarity between each item and the reference
    {prop1,…}a list of properties
    Alla Tabular with all the properties
  • The following options can be given:
  • Method Automaticsemantic ranking method
  • Possible values for Method include:
  • Automaticdefault local model
    Tiny, Small, Medium, Largepredefined model sizes
    {"string",size}a named model of the specified size
    fa custom ranking function
  • A custom ranker f must operate on the reference string and a list of strings to produce a numerical vector of the same length. The higher the number, the more similar the pair is.
  • Specific ranking models include:
  • "MiniLM"default (Medium) "MiniLM" ranker
    {"MiniLM",Tiny}MiniLM-V2 L-2
    {"MiniLM",Small}MiniLM-V2 L-4
    {"MiniLM",Medium}MiniLM-V2 L-6
    {"MiniLM",Large}MiniLM-V2 L-12

Examples

open all close all

Basic Examples  (2)

Rerank single-word items according to similarity:

Wolfram Language code: SemanticRanking[{"whale", "weasel", "shark", "goat", "cloud", "car", "turtle", "tuna"}, "fish"]

Retrieve the relevance of each item:

Wolfram Language code: SemanticRanking[{"whale", "weasel", "shark", "goat", "cloud", "car", "turtle", "tuna"}, "fish", "Relevance"]

Rerank sentences according to similarity to a query:

Wolfram Language code: faqAnswers = {"You can reset your password by clicking 'Forgot Password' on the login page.", "We ship orders within 2–3 business days.", "To cancel a subscription, go to your account settings.", "Our customer service is available 24/7 via chat and email.", "You can update your billing information under Payment Settings."};
Wolfram Language code: SemanticRanking[faqAnswers, "How do I change my credit card info?"]

Scope  (3)

Retrieve items in order of similarity from a reference text:

Wolfram Language code: SemanticRanking[{"whale", "weasel", "shark", "goat", "cloud", "car", "turtle", "tuna"}, "fish"]

Return a selected property of each item:

Wolfram Language code: SemanticRanking[{"whale", "weasel", "shark", "goat", "cloud", "car", "turtle", "tuna"}, "fish", "Relevance"]

Retrieve multiple properties:

Wolfram Language code: SemanticRanking[{"whale", "weasel", "shark", "goat", "cloud", "car", "turtle", "tuna"}, "fish", {"Item", "Relevance"}]

Get all properties:

Wolfram Language code: SemanticRanking[{"whale", "weasel", "shark", "goat", "cloud", "car", "turtle", "tuna"}, "fish", All]

Options  (1)

Method  (1)

Specify a reranking function for species designations using a custom text extractor:

Wolfram Language code: extractor = NetModel["SciBERT Trained on Semantic Scholar Data"];

Use the extractor in the function:

Wolfram Language code: reranker = Function[{reference, candidates}, EuclideanDistance[Mean[#], Mean[extractor[reference]]]& /@ extractor[candidates]];

Rank the text:

Wolfram Language code: SemanticRanking[{"Mustela nivalis", "Carcharodon carcharias", "Capra aegagrus hircus", "Chelonia mydas", "Thunnus albacares", "Manis temminckii"}, "Fish", Method -> reranker]

Check the ordering:

Wolfram Language code: Interpreter["Entity"] /@ %

Properties & Relations  (1)

SemanticSearch automatically reranks the results using SemanticRanking:

Wolfram Language code: index = CreateSemanticSearchIndex[{ "Jellyfish drift with ocean currents.", "Starfish regenerate lost body parts.", "Crayfish dig burrows in mud.", "Cuttlefish change color for camouflage.", "Silverfish infest homes, eating paper.", "Salmon migrate upstream to spawn.", "Starfish live on ocean floors.", "Shellfish create shells from calcium." }]
Wolfram Language code: query = "Fish" semanticSearchReranked = SemanticSearch[index, query, MaxItems -> 5]

This is equivalent to retrieving the "MinItems" for RerankingMethod without actually doing it:

Wolfram Language code: extendedResults = SemanticSearch[index, query, MaxItems -> 10, RerankingMethod -> None]

Then taking the first five results after using SemanticRanking:

Wolfram Language code: rankingResults = SemanticRanking[extendedResults, query][[1 ;; 5]]
Wolfram Language code: semanticSearchReranked === rankingResults

Possible Issues  (2)

Create several paragraphs of text:

Wolfram Language code: definitions = Map[StringJoin[#, ": ", WordDefinition[#]]&, RandomWord[200]];

Reranking such a large number of items is slow:

Wolfram Language code: AbsoluteTiming[reranked = SemanticRanking[definitions, definitions[[10]]];] First@reranked

Instead create a SemanticSearchIndex:

Wolfram Language code: index = CreateSemanticSearchIndex[definitions]

Use SemanticSearch to get a shortlist of the best matches:

Wolfram Language code: (shortlist = SemanticSearch[index, definitions[[10]]];)//AbsoluteTiming

Then rerank the shortlist:

Wolfram Language code: AbsoluteTiming[result = SemanticRanking[shortlist, definitions[[10]]];]

The closest result is identical:

Wolfram Language code: First[result] == First[reranked]

Words without context may not be ordered as expected:

Wolfram Language code: SemanticRanking[{"weasel", "sole", "turtle", "tuna"}, "fish"]

A larger ranking model may improve results:

Wolfram Language code: SemanticRanking[{"weasel", "sole", "turtle", "tuna"}, "fish", Method -> {"MiniLM", Large}]

Alternatively, add more context to make the results more reliable:

Wolfram Language code: SemanticRanking[StringRiffle[{#, ":", WordDefinition[#]}]& /@ {"weasel", "sole", "turtle", "tuna"}, "fish"]
Wolfram Research (2025), SemanticRanking, Wolfram Language function, https://reference.wolfram.com/language/ref/SemanticRanking.html.

Text

Wolfram Research (2025), SemanticRanking, Wolfram Language function, https://reference.wolfram.com/language/ref/SemanticRanking.html.

CMS

Wolfram Language. 2025. "SemanticRanking." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/SemanticRanking.html.

APA

Wolfram Language. (2025). SemanticRanking. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SemanticRanking.html

BibTeX

@misc{reference.wolfram_2026_semanticranking, author="Wolfram Research", title="{SemanticRanking}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/SemanticRanking.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_semanticranking, organization={Wolfram Research}, title={SemanticRanking}, year={2025}, url={https://reference.wolfram.com/language/ref/SemanticRanking.html}, note=[Accessed: 13-June-2026]}