WOLFRAM

Wolfram Language & System Documentation Center

ShearingMatrix[θ,v,n]

gives the matrix corresponding to shearing by θ radians along the direction of the vector v, and normal to the vector n.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
History
Cite this Page

ShearingMatrix

ShearingMatrix[θ,v,n]

gives the matrix corresponding to shearing by θ radians along the direction of the vector v, and normal to the vector n.

Details

  • ShearingMatrix gives matrices corresponding to shearing with the origin kept fixed.
  • ShearingMatrix gives matrices with determinant 1, corresponding to area- or volume-preserving transformations.
  • In 2D, ShearingMatrix turns rectangles into parallelograms. ShearingMatrix[θ,{1,0},{0,1}] effectively slants by angle θ to the right.
  • In 3D, ShearingMatrix does the analog of shearing a deck of cards by angle θ in the direction v, with the cards being oriented so as to have normal vector n.

Examples

open all close all

Basic Examples  (2)

A shearing by θ radians along the axis:

Wolfram Language code: ShearingMatrix[θ, {1, 0}, {0, 1}]//MatrixForm

Apply a 30° shear along the axis to a square:

Wolfram Language code: Graphics[GeometricTransformation[Rectangle[], ShearingMatrix[30 Degree, {1, 0}, {0, 1}]], Frame -> True]

Scope  (5)

Shearing along the axis:

Wolfram Language code: ShearingMatrix[θ, {1, 0}, {0, 1}]//MatrixForm

Shearing along the axis:

Wolfram Language code: ShearingMatrix[θ, {0, 1}, {1, 0}]//MatrixForm

Shearing in the plane along the axis:

Wolfram Language code: ShearingMatrix[θ, {1, 0, 0}, {0, 0, 1}]//MatrixForm

Shearing the plane along the axis:

Wolfram Language code: ShearingMatrix[θ, {1, 0, 0}, {0, 1, 0}]//MatrixForm

A shearing by angle theta in the {1,1} direction in the line {1,-1}.p==0:

Wolfram Language code: ShearingMatrix[θ, {1, 1}, {1, -1}]//MatrixForm

Transformation applied to a 2D shape:

Wolfram Language code: gr = {Rectangle[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0}]}, {Green, Point[{1, 1}]}};
Wolfram Language code: Graphics[{{Opacity[.35], Blue, gr}, GeometricTransformation[{Opacity[.85], Red, gr}, ShearingMatrix[Pi / 6, {1, 0}, {0, 1}]]}]

Transformation applied to a 3D shape:

Wolfram Language code: gr = {Cuboid[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0, 0}]}, {Green, Point[{1, 1, 1}]}};
Wolfram Language code: Graphics3D[{{Opacity[.35], Blue, gr}, GeometricTransformation[{Opacity[.85], Red, gr}, ShearingMatrix[Pi / 4, {1, 0, 0}, {-1, 1, 0}]]}, Boxed -> False]

Applications  (2)

Applying the transformation to a surface:

Wolfram Language code: Plot3D[-Sin[x y], {x, 0, Pi}, {y, 0, Pi}, BoxRatios -> Automatic, PlotRange -> All] /. gc_GraphicsComplex :> GeometricTransformation[gc, ShearingMatrix[-Pi / 4, {1, 1, 0}, {0, 0, 1}]]

Generate all simple (directions parallel to axes) shearing matrices for dimension n:

Wolfram Language code: Shearings[θ_, n_] := With[{pairs = Subsets[Table[ UnitVector[n, j], {j, n}], {2}]}, Map[ShearingMatrix[θ, #[[1]], #[[2]]]&, Join[pairs, Reverse /@ pairs]]];

All shearings in 2D:

Wolfram Language code: Map[ MatrixForm, Shearings[θ, 2]]
Wolfram Language code: Map[Framed@Graphics[GeometricTransformation[Rectangle[], #], PlotRange -> {{0, 1.6}, {0, 1.6}}]&, Shearings[Pi / 6, 2]]

All shearings in 3D:

Wolfram Language code: Map[ MatrixForm, Shearings[θ, 3]]
Wolfram Language code: Map[Graphics3D[GeometricTransformation[Cuboid[], #]]&, Shearings[Pi / 6, 3]]

All shearings in 4D:

Wolfram Language code: Map[ MatrixForm, Shearings[θ, 4]]

Properties & Relations  (4)

The determinant of a shearing matrix is 1; hence it preserves areas and volumes:

Wolfram Language code: Det[ ShearingMatrix[θ, {1, 0, 0}, {0, 0, 1}]]

The inverse of ShearingMatrix[θ,v,n] is given by ShearingMatrix[-θ,v,n]:

Wolfram Language code: ShearingMatrix[θ, {1, 0, 0}, {0, 0, 1}].ShearingMatrix[-θ, {1, 0, 0}, {0, 0, 1}]

The inverse of ShearingMatrix[θ,v,n] is also given by ShearingMatrix[θ,-v,n]:

Wolfram Language code: ShearingMatrix[θ, {1, 0, 0}, {0, 0, 1}].ShearingMatrix[θ, -{1, 0, 0}, {0, 0, 1}]

The n^(th) power of a shearing matrix is again a shearing matrix with the same v and n:

Wolfram Language code: MatrixPower[ShearingMatrix[a, {1, 0}, {0, 1}], n] == ShearingMatrix[ArcTan[n Tan[a]], {1, 0}, {0, 1}]

Possible Issues  (3)

The order in which shearings are applied is significant:

Wolfram Language code: t1 = ShearingMatrix[θ, {1, 0, 0}, {0, 0, 1}]; t2 = ShearingMatrix[ϕ, {1, 0, 0}, {-1, 1, 0}];

Here the two different orders do not yield the same matrix:

Wolfram Language code: t1.t2 - t2.t1//Simplify

The transformation is not defined for angles such that :

Wolfram Language code: Limit[ShearingMatrix[a, {1, 0, 0}, {0, 0, 1}], a -> Pi / 2]

For non-orthogonal vectors, the direction is determined by the projection of the direction vector:

Wolfram Language code: ShearingMatrix[a, {1, 0}, {1, 1}] == ShearingMatrix[a, Projection[{1, 0}, Cross[{1, 1}]], {1, 1}]

Neat Examples  (1)

The transformation applied to a sphere:

Wolfram Language code: Graphics3D[Table[GeometricTransformation[Sphere[{1, 1, 1}], ShearingMatrix[Pi / 3, {Cos[u], 0, Sin[u]}, {0, 1, 0}]], {u, 2Pi / 5Range[5]}], Boxed -> False]
Wolfram Research (2007), ShearingMatrix, Wolfram Language function, https://reference.wolfram.com/language/ref/ShearingMatrix.html.

Text

Wolfram Research (2007), ShearingMatrix, Wolfram Language function, https://reference.wolfram.com/language/ref/ShearingMatrix.html.

CMS

Wolfram Language. 2007. "ShearingMatrix." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ShearingMatrix.html.

APA

Wolfram Language. (2007). ShearingMatrix. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ShearingMatrix.html

BibTeX

@misc{reference.wolfram_2026_shearingmatrix, author="Wolfram Research", title="{ShearingMatrix}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/ShearingMatrix.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_shearingmatrix, organization={Wolfram Research}, title={ShearingMatrix}, year={2007}, url={https://reference.wolfram.com/language/ref/ShearingMatrix.html}, note=[Accessed: 12-June-2026]}