WOLFRAM

Wolfram Language & System Documentation Center

ShearingTransform[θ,v,n]

gives a TransformationFunction that represents a shear by θ radians along the direction of the vector v, normal to the vector n, and keeping the origin fixed.

ShearingTransform[θ,v,n,p]

gives a shear that keeps the point p fixed, rather than the origin.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
History
Cite this Page

ShearingTransform

ShearingTransform[θ,v,n]

gives a TransformationFunction that represents a shear by θ radians along the direction of the vector v, normal to the vector n, and keeping the origin fixed.

ShearingTransform[θ,v,n,p]

gives a shear that keeps the point p fixed, rather than the origin.

Details

  • ShearingTransform gives a TransformationFunction which can be applied to vectors.
  • ShearingTransform works in any number of dimensions, and always gives area- or volume-preserving transformations.
  • In 2D, ShearingTransform turns rectangles into parallelograms. ShearingTransform[θ,{1,0},{0,1}] effectively represents slanting by angle θ to the right.
  • In 3D, ShearingTransform does the analog of shearing a deck of cards by angle θ in the direction v, with the cards oriented so as to have normal vector n, and the card that goes through the point p kept fixed.

Examples

open all close all

Basic Examples  (3)

Shearing by θ radians along the axis:

Wolfram Language code: ShearingTransform[θ, {1, 0}, {0, 1}]

Apply a 30° shearing along the axis to the unit rectangle:

Wolfram Language code: Graphics[GeometricTransformation[Rectangle[], ShearingTransform[30Degree, {1, 0}, {0, 1}]], Frame -> True]

Apply a shearing transform in the plane:

Wolfram Language code: cow = ExampleData[{"Geometry3D", "Cow"}, "GraphicsComplex"];
Wolfram Language code: Manipulate[Graphics3D[{EdgeForm[None], GeometricTransformation[cow, ShearingTransform[k Pi / 5, {1, 0, 0}, {0, 0, 1}]]}], {k, -1, 1}, SaveDefinitions -> True]

Scope  (5)

Simple shearing along the axis:

Wolfram Language code: ShearingTransform[θ, {1, 0}, {0, 1}]

Simple shearing along the axis in the plane:

Wolfram Language code: ShearingTransform[θ, {1, 0, 0}, {0, 0, 1}]

Shearing along the axis in the plane :

Wolfram Language code: t = ShearingTransform[θ, {1, 0, 0}, {0, 0, 1}, {0, 0, 1}]

Points in the shearing plane are not changed:

Wolfram Language code: t[{0, 0, 1}]

Points outside the shearing plane are moved in the shearing direction:

Wolfram Language code: t[{0, 0, 2}]

Transformation applied to a 2D shape:

Wolfram Language code: gr = {Rectangle[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0}]}, {Green, Point[{1, 1}]}};
Wolfram Language code: Graphics[{{Opacity[.35], Blue, gr}, GeometricTransformation[{Opacity[.85], Red, gr}, ShearingTransform[-Pi / 6, {1, 0}, {0, 1}, {0, 1}]]}]

Transformation applied to a 3D shape:

Wolfram Language code: gr = {Cuboid[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0, 0}]}, {Green, Point[{1, 1, 1}]}};
Wolfram Language code: Graphics3D[{{Opacity[.35], Blue, gr}, GeometricTransformation[{Opacity[.85], Red, gr}, ShearingTransform[-Pi / 6, {1, 0, 0}, {0, 0, 1}, {0, 0, 1}]]}, Boxed -> False]

Applications  (2)

Transforming the output of Plot:

Wolfram Language code: Plot[Sin[x], {x, -2Pi, 2Pi}] /. L_Line :> GeometricTransformation[L, ShearingTransform[Pi / 4, {1, 0}, {0, 1}]]

Construct a slanted font from an upright font by shearing:

Wolfram Language code: Graphics[GeometricTransformation[Style[Text[StringJoin@CharacterRange["𝔸", "𝕆"]], 50], ShearingTransform[25 Degree, {1, 0}, {0, 1}]], ImageSize -> {All, {0, 50}}]

Properties & Relations  (3)

The inverse of ShearingTransform[θ,v,n] is given by ShearingTransform[-θ,v,n]:

Wolfram Language code: Composition[ShearingTransform[θ, {1, 0}, {0, 1}], ShearingTransform[-θ, {1, 0}, {0, 1}]]//Simplify

The inverse of ShearingTransform[θ,v,n] is given by ShearingTransform[θ,-v,n]:

Wolfram Language code: Composition[ShearingTransform[θ, {1, 0}, {0, 1}], ShearingTransform[θ, -{1, 0}, {0, 1}]]//Simplify

Performing the shearing transform multiple times corresponds to a single shearing transform:

Wolfram Language code: t = ShearingTransform[Pi / 4, {1, 0}, {0, 1}];
Wolfram Language code: Composition[t, t] == ShearingTransform[ArcTan[2], {1, 0}, {0, 1}]

Possible Issues  (3)

The order in which shearings are applied is significant:

Wolfram Language code: t1 = ShearingTransform[θ, {1, 0}, {0, 1}]; t2 = ShearingTransform[ϕ, {1, 1}, {1, -1}];

Applying the two shearings in different orders is not equivalent:

Wolfram Language code: Composition[t1, t2][{x, y}] - Composition[t2, t1][{x, y}]//Simplify

The transformation is not defined for angles such that :

Wolfram Language code: TransformationMatrix[ShearingTransform[a, {1, 0}, {0, 1}]] /. a -> Pi / 2

For non-orthogonal vectors, the direction is determined by the projection of the direction vector:

Wolfram Language code: ShearingTransform[a, {1, 1, 1}, {0, 0, 1}] == ShearingTransform[a, {1, 1, 0}, {0, 0, 1}]

Neat Examples  (1)

Shear a 3D object about a point p:

Wolfram Language code: cow = ExampleData[{"Geometry3D", "Cow"}, "GraphicsComplex"];
Wolfram Language code: p = {0, 0, -0.251619};

In the plane:

Wolfram Language code: Graphics3D[{EdgeForm[None], Opacity[0.5], Table[{Lighter[ColorData[1, k + 2], 0.5], GeometricTransformation[cow, ShearingTransform[k Pi / 5, {1, 0, 0}, {0, 0, 1}, p]]}, {k, -1, 1}]}, Lighting -> "Neutral", ImageSize -> Large, Boxed -> False]

In the plane:

Wolfram Language code: Graphics3D[{EdgeForm[None], Opacity[0.5], Table[{Lighter[ColorData[1, k + 2], 0.5], GeometricTransformation[cow, ShearingTransform[k Pi / 5, {1, 0, 0}, {0, 1, 0}, p]]}, {k, -1, 1}]}, Lighting -> "Neutral", ImageSize -> Large, Boxed -> False]

In the plane:

Wolfram Language code: Graphics3D[{EdgeForm[None], Opacity[0.5], Table[{Lighter[ColorData[1, k + 2], 0.5], GeometricTransformation[cow, ShearingTransform[k Pi / 8, {0, 1, 0}, {0, 0, 1}, p]]}, {k, -1, 1}]}, Lighting -> "Neutral", ImageSize -> Large, Boxed -> False]
Wolfram Research (2007), ShearingTransform, Wolfram Language function, https://reference.wolfram.com/language/ref/ShearingTransform.html.

Text

Wolfram Research (2007), ShearingTransform, Wolfram Language function, https://reference.wolfram.com/language/ref/ShearingTransform.html.

CMS

Wolfram Language. 2007. "ShearingTransform." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ShearingTransform.html.

APA

Wolfram Language. (2007). ShearingTransform. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ShearingTransform.html

BibTeX

@misc{reference.wolfram_2026_shearingtransform, author="Wolfram Research", title="{ShearingTransform}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/ShearingTransform.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_shearingtransform, organization={Wolfram Research}, title={ShearingTransform}, year={2007}, url={https://reference.wolfram.com/language/ref/ShearingTransform.html}, note=[Accessed: 12-June-2026]}