WOLFRAM

Wolfram Language & System Documentation Center

Show[graphics,options]

shows graphics with the specified options added.

Show[g1,g2,…]

shows several graphics combined.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Options  
DisplayFunction  
Applications  
Possible Issues  
See Also
Tech Notes
Related Guides
Related Workflows
Related Links
History
Cite this Page

Show

Show[graphics,options]

shows graphics with the specified options added.

Show[g1,g2,…]

shows several graphics combined.

Details

  • Show can be used with Graphics and Graphics3D.
  • Show allows any option that can be applied to graphics to be given.
  • Options explicitly specified in Show override those included in the graphics expression.
  • Show[g1,g2,…] or Show[{g1,g2,…}] concatenates the graphics primitives in the gi, effectively overlaying the graphics.
  • The lists of non‐default options in the gi are concatenated.
  • Show applies the function defined as the setting for DisplayFunction, and returns the result. For ordinary notebook operation, this function is just Identity.
  • Image and Image3D objects can also be combined with other graphics. Their pixel positions range from 0 to the dimensions of the image in the standard image coordinate system:

Examples

open all close all

Basic Examples  (3)

Combine the plot of a curve with the plot of a list:

Wolfram Language code: Show[Plot[x ^ 2, {x, 0, 3.5}], ListPlot[{1, 4, 9}]]

Combine the density plot with the contour plot:

Wolfram Language code: Show[DensityPlot[Sin[x]Sin[y], {x, -3, 3}, {y, -3, 3}], ContourPlot[Sin[x]Sin[y], {x, -3, 3}, {y, -3, 3}, ContourShading -> None]]

Change options for existing graphics:

Wolfram Language code: Plot[Sin[x ^ 2] / x, {x, 0, 10}]
Wolfram Language code: Show[%, PlotRange -> {{8, 10}, {-.3, .3}}, AxesOrigin -> {8.0, 0}]

Options  (2)

DisplayFunction  (2)

Display a graphic in PopupWindow when clicked:

Wolfram Language code: Show[Graphics[{Pink, Rectangle[]}], DisplayFunction -> (PopupWindow[Button["Click here"], #]&)]

Display a graphic in a new notebook:

Wolfram Language code: Show[Graphics3D[{Sphere[]}], DisplayFunction -> CreateDocument]

Applications  (1)

Import an elevation map and take a part of it:

Wolfram Language code: data = Import["http://exampledata.wolfram.com/hailey.dem.gz", "Data"];
Wolfram Language code: part = data[[800 ;; 1000, 800 ;; 1000]];

Draw a relief-shaded map:

Wolfram Language code: r = ReliefPlot[part, ColorFunction -> "Rainbow", ImageSize -> 200]

Draw contour lines:

Wolfram Language code: c = ListContourPlot[part, ContourShading -> None, Contours -> 5, ContourStyle -> {Opacity[.5], Opacity[.8]}, ImageSize -> 200]

Combine two plots:

Wolfram Language code: Show[r, c]

Possible Issues  (1)

Show uses the options from the first graphic:

Wolfram Language code: Show[{PolarPlot[1 + 2 Sin[t / 2], {t, 0, π}, Ticks -> None, PlotStyle -> Red, PlotRange -> {Automatic, {0, 3}}], PolarPlot[1 + 2 Sin[t / 2], {t, π, 2 π}, Ticks -> None, PlotStyle -> Orange], PolarPlot[1 + 2 Sin[t / 2], {t, -π, 0}, Ticks -> None, PlotStyle -> Blue], PolarPlot[1 + 2 Sin[t / 2], {t, -2 π, -π}, Ticks -> None, PlotStyle -> Green]}]

To see the entire graphic, use PlotRange->All:

Wolfram Language code: Show[{PolarPlot[1 + 2 Sin[t / 2], {t, 0, π}, Ticks -> None, PlotStyle -> Red, PlotRange -> {Automatic, {0, 3}}], PolarPlot[1 + 2 Sin[t / 2], {t, π, 2 π}, Ticks -> None, PlotStyle -> Orange], PolarPlot[1 + 2 Sin[t / 2], {t, -π, 0}, Ticks -> None, PlotStyle -> Blue], PolarPlot[1 + 2 Sin[t / 2], {t, -2 π, -π}, Ticks -> None, PlotStyle -> Green]}, PlotRange -> All]
Wolfram Research (1988), Show, Wolfram Language function, https://reference.wolfram.com/language/ref/Show.html (updated 2021).

Text

Wolfram Research (1988), Show, Wolfram Language function, https://reference.wolfram.com/language/ref/Show.html (updated 2021).

CMS

Wolfram Language. 1988. "Show." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/Show.html.

APA

Wolfram Language. (1988). Show. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Show.html

BibTeX

@misc{reference.wolfram_2026_show, author="Wolfram Research", title="{Show}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/Show.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_show, organization={Wolfram Research}, title={Show}, year={2021}, url={https://reference.wolfram.com/language/ref/Show.html}, note=[Accessed: 12-June-2026]}