WOLFRAM

Wolfram Language & System Documentation Center

SiegelTheta[Ω,s]

gives the Siegel theta function with Riemann modular matrix Ω and vector s.

SiegelTheta[{ν1,ν2},Ω,s]

gives the Siegel theta function with characteristics ν1 and ν2.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Generalizations & Extensions  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
Related Links
History
Cite this Page

SiegelTheta

SiegelTheta[Ω,s]

gives the Siegel theta function with Riemann modular matrix Ω and vector s.

SiegelTheta[{ν1,ν2},Ω,s]

gives the Siegel theta function with characteristics ν1 and ν2.

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • The matrix Ω must be symmetric, with positive definite imaginary part.
  • If Ω is a p×p matrix, the vectors s and v or νi must have length p.
  • , where n ranges over all possible vectors in the p-dimensional integer lattice.
  • , where n ranges over all possible vectors in the p-dimensional integer lattice.
  • SiegelTheta can be evaluated to arbitrary numerical precision.

Examples

open all close all

Basic Examples  (3)

Evaluate numerically:

Wolfram Language code: SiegelTheta[{{I, -1 / 2}, {-1 / 2, I}}, {0.5, 0}]//Chop

Plot over a subset of the reals:

Wolfram Language code: Plot[Re[SiegelTheta[{{I, -1 / 2}, {-1 / 2, I}}, {x, 2 x}]], {x, -1, 1}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[SiegelTheta[{{I, -1 / 2}, {-1 / 2, I}}, {z, 2 z}], {z, -1 / 2 - I / 2, 1 / 2 + I / 2}, PlotLegends -> Automatic]

Scope  (7)

Numerical Evaluation  (3)

Evaluate numerically:

Wolfram Language code: N[SiegelTheta[IdentityMatrix[2] I, {1, 2}]]
Wolfram Language code: N[SiegelTheta[{{2, 4}, {4, 2}}, IdentityMatrix[2] I, {1, 2}]]

Evaluate to high precision:

Wolfram Language code: N[SiegelTheta[{{2, 1 / 3}, {4, 2}}IdentityMatrix[2] I, {9, 2}], 20]//Chop

The precision of the output tracks the precision of the input:

Wolfram Language code: SiegelTheta[{{I + 1, -2}, {-2, I + 4}}, {1.2222222222222222222, I + 1}]//Chop

Evaluate efficiently at high precision:

Wolfram Language code: SiegelTheta[{{I + 1, -1}, {-1, I + 4}}, {1 / 2, I + 9`100}]//Timing
Wolfram Language code: SiegelTheta[{{I + 1, -1}, {-1, I + 4}}, {1 / 3, I + 9`1000}];//Timing//Quiet

Specific Values  (2)

Value at zero:

Wolfram Language code: SiegelTheta[{{I, 0}, {0, I}}, {0, 0}]//N//Chop

Find a value of x for which Re[SiegelTheta[{{I,1},{1, I}},{x,x/3}]]=1:

Wolfram Language code: xval = x /. FindRoot[Re[SiegelTheta[{{I, 1}, {1, I}}, {x, x / 3}]] == 1, {x, 0.5}]//Quiet
Wolfram Language code: Plot[Re[SiegelTheta[{{I, 1}, {1, I}}, {x, x / 3}]], {x, -1, 2}, Epilog -> Style[Point[{xval, Re[SiegelTheta[{{I, 1}, {1, I}}, {xval, xval / 3}]]}], PointSize[Large], Red]]

Visualization  (2)

Plot the SiegelTheta function for various parameters:

Wolfram Language code: Plot[{Re[SiegelTheta[{{I, 1}, {1, I}}, {x, x / 3}]], Re[SiegelTheta[{{I, 1}, {1, I}}, {x, x / 2}]], Re[SiegelTheta[{{I, 1}, {1, I}}, {x, 2x}]]}, {x, -2, 2}]

Plot the real part of SiegelTheta[(ⅈ 1; 1 ⅈ),{z,1/3 (z)}]:

Wolfram Language code: ComplexContourPlot[Re[SiegelTheta[{{I, 1}, {1, I}}, {z, (z) / 3}]], {z, -1 - I, 1 + I}, Contours -> 20]

Plot the imaginary part of SiegelTheta[(ⅈ 1; 1 ⅈ),{z,1/3 (z)}]:

Wolfram Language code: ComplexContourPlot[Im[SiegelTheta[{{I, 1}, {1, I}}, {z, (z) / 3}]], {z, -1 - I, 1 + I}, Contours -> 20]

Generalizations & Extensions  (2)

SiegelTheta with characteristics and :

Wolfram Language code: SiegelTheta[{{1 / 2, 0}, {0, 1 / 2}}, {{I, 0}, {0, I}}, {0.1 + I, 0}]

SiegelTheta with characteristics simplifies symbolically for special arguments:

Wolfram Language code: SiegelTheta[{{0, 0}, {a, b}}, {{I, 1 / 2}, {1 / 2, I}}, {0, 0}]

Applications  (2)

Plot of the absolute value of SiegelTheta in the complex plane:

Wolfram Language code: Plot3D[Abs[SiegelTheta[{{I, 0.5}, {0.5, I}}, {x, y}]], {x, -1, 1}, {y, -1, 1}]

Define an Abelian function:

Wolfram Language code: m = {{1 + I, -1 / 2}, {-1 / 2, 1 + I}}; a = {1 / 3, 1 / 4}; b = {1 / 5, 1 / 6}; c = {2 / 5, 1 / 12}; d = {2 / 15, 1 / 3};
Wolfram Language code: f[s_] := (SiegelTheta[m, s + a]SiegelTheta[m, s + b]) / (SiegelTheta[m, s + c]SiegelTheta[m, s + d])

Plot of the real part:

Wolfram Language code: Plot[Re[f[x I]], {x, -1, 1}]

Properties & Relations  (2)

In one dimension, SiegelTheta coincides with the EllipticTheta functions:

Wolfram Language code: SiegelTheta[{{0.5 + I}}, {2}]
Wolfram Language code: EllipticTheta[3, 2Pi, E ^ ( I * Pi * (0.5 + I))]

SiegelTheta satisfies the equations:

Wolfram Language code: m = {{I, 1 / 2}, {1 / 2, I}}; s = {0.5`20, 0.6`20};
Wolfram Language code: SiegelTheta[m, -s] == SiegelTheta[m, s]
Wolfram Language code: SiegelTheta[m, s + 1] == SiegelTheta[m, s]
Wolfram Language code: SiegelTheta[m, s + {1, 2}. m] == E ^ (Pi I(-{1, 2}.m.{1, 2} - 2{1, 2}.s))SiegelTheta[m, s]

Possible Issues  (2)

SiegelTheta requires a symmetric matrix:

Wolfram Language code: m = {{I, 1}, {0, 2I}};
Wolfram Language code: SiegelTheta[m, {1, 2.}]

The symmetric part:

Wolfram Language code: SiegelTheta[(m + m) / 2, {1, 2.}]

Machine precision may be insufficient to obtain a correct answer:

Wolfram Language code: SiegelTheta[{{10^-3 I}}, {0.5}]

Use arbitrary precision to check the result:

Wolfram Language code: Block[{$MaxExtraPrecision = 500}, N[SiegelTheta[{{10^-3 I}}, {1 / 2}], 50]]
Wolfram Language code: N[EllipticTheta[3, π / 2, Exp[-π 10^-3]], 50]

Neat Examples  (1)

Visualize deviations from positivity in nested SiegelTheta functions:

Wolfram Language code: ContourPlot[Arg[Nest[SiegelTheta[{{I, Re[#] - Im[#]}, {Re[#] - Im[#], I}}, {Re[#], Im[#]}] &, x + y I, 5]], {x, 0, 1}, {y, 0, 1}]
Wolfram Research (2007), SiegelTheta, Wolfram Language function, https://reference.wolfram.com/language/ref/SiegelTheta.html.

Text

Wolfram Research (2007), SiegelTheta, Wolfram Language function, https://reference.wolfram.com/language/ref/SiegelTheta.html.

CMS

Wolfram Language. 2007. "SiegelTheta." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/SiegelTheta.html.

APA

Wolfram Language. (2007). SiegelTheta. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SiegelTheta.html

BibTeX

@misc{reference.wolfram_2026_siegeltheta, author="Wolfram Research", title="{SiegelTheta}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/SiegelTheta.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_siegeltheta, organization={Wolfram Research}, title={SiegelTheta}, year={2007}, url={https://reference.wolfram.com/language/ref/SiegelTheta.html}, note=[Accessed: 13-June-2026]}