WOLFRAM

Wolfram Language & System Documentation Center

EllipticTheta[a,u,q]

gives the theta function TemplateBox[{a, u, q}, EllipticTheta] .

EllipticTheta[a,q]

gives the theta constant TemplateBox[{a, q}, EllipticThetaConstant]=TemplateBox[{a, 0, q}, EllipticTheta].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Generalizations & Extensions  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

EllipticTheta

EllipticTheta[a,u,q]

gives the theta function TemplateBox[{a, u, q}, EllipticTheta] .

EllipticTheta[a,q]

gives the theta constant TemplateBox[{a, q}, EllipticThetaConstant]=TemplateBox[{a, 0, q}, EllipticTheta].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • TemplateBox[{1, u, q}, EllipticTheta]=2q^(1/4)sum_(n=0)^(infty)(-1)^nq^(n(n+1))sin((2 n+1)u).
  • TemplateBox[{2, u, q}, EllipticTheta]=2q^(1/4)sum_(n=0)^(infty)q^(n(n+1))cos((2 n+1)u).
  • TemplateBox[{3, u, q}, EllipticTheta]=1+2sum_(n=1)^(infty)q^(n^2)cos(2n u).
  • TemplateBox[{4, u, q}, EllipticTheta]=1+2sum_(n=1)^(infty)(-1)^nq^(n^2)cos(2n u).
  • The are only defined within the unit q disk, TemplateBox[{q}, Abs]<1; the unit disk forms a natural boundary of analyticity.
  • Within the unit q disk, and have branch cuts from to .
  • For certain special arguments, EllipticTheta automatically evaluates to exact values.
  • EllipticTheta can be evaluated to arbitrary numerical precision.
  • EllipticTheta automatically threads over lists.
  • EllipticTheta can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples  (3)

Evaluate numerically:

Wolfram Language code: EllipticTheta[1, 2., 1 / 3]

Plot over a subset of the reals:

Wolfram Language code: Plot[EllipticTheta[2, x, 1 / 3], {x, -6, 6}]

Series expansion at the origin with respect to q:

Wolfram Language code: Series[EllipticTheta[4, 0, q], {q, 0, 100}]

Scope  (20)

Numerical Evaluation  (5)

Evaluate numerically:

Wolfram Language code: EllipticTheta[2, 5, .5]
Wolfram Language code: EllipticTheta[3, .4, .5]

Evaluate to high precision:

Wolfram Language code: N[EllipticTheta[3, 1 / 4, 1 / 3], 25]

The precision of the output tracks the precision of the input:

Wolfram Language code: EllipticTheta[3, 4, .50005555555500055005]

Complex number inputs:

Wolfram Language code: EllipticTheta[3, .4 + I, .5I]

Evaluate efficiently at high precision:

Wolfram Language code: EllipticTheta[2, 5, .5`100]//Timing
Wolfram Language code: EllipticTheta[2, 5, .5`10000];//Timing

EllipticTheta can be used with Interval and CenteredInterval objects:

Wolfram Language code: EllipticTheta[2, 1, Interval[{0.47, 0.48}]]
Wolfram Language code: EllipticTheta[2, 1, CenteredInterval[1 / 4, 1 / 100]]

Specific Values  (3)

Value at zero:

Wolfram Language code: EllipticTheta[1, 0, 0]

EllipticTheta evaluates symbolically for special arguments:

Wolfram Language code: Table[EllipticTheta[j, z, 0], {j, 4}]
Wolfram Language code: EllipticTheta[1, Pi, 1 / 2]

Find the first positive minimum of EllipticTheta[3,x,1/2]:

Wolfram Language code: xmin = x /. FindRoot[D[EllipticTheta[3, x, 1 / 2]] == 0, {x, 2}]//Quiet
Wolfram Language code: Plot[EllipticTheta[3, x, 1 / 2], {x, -1, 4}, Epilog -> Style[Point[{xmin, EllipticTheta[3, xmin, 1 / 2]}], PointSize[Large], Red]]

Visualization  (2)

Plot the EllipticTheta function for various parameters:

Wolfram Language code: Plot[{EllipticTheta[1, x, 1 / 2], EllipticTheta[2, x, 1 / 2], EllipticTheta[3, x, 1 / 2], EllipticTheta[4, x, 1 / 2]}, {x, -6, 6}]

Plot the real part of TemplateBox[{4, z, {1, /, 3}}, EllipticTheta]:

Wolfram Language code: ComplexContourPlot[Re[EllipticTheta[4, z, 1 / 3]], {z, -4 - 4I, 4 + 4 I}, Contours -> 24]

Plot the imaginary part of TemplateBox[{4, z, {1, /, 3}}, EllipticTheta]:

Wolfram Language code: ComplexContourPlot[Im[EllipticTheta[4, z, 1 / 3]], {z, -4 - 4I, 4 + 4 I}, Contours -> 24]

Function Properties  (10)

Real and complex domains of EllipticTheta:

Wolfram Language code: Table[FunctionDomain[EllipticTheta[a, x, q], {x, q}], {a, 4}]
Wolfram Language code: Table[FunctionDomain[EllipticTheta[a, z, q], {z, q}, Complexes], {a, 4}]

EllipticTheta is a periodic function with respect to :

Wolfram Language code: Table[FunctionPeriod[EllipticTheta[a, z, q], z], {a, 4}]

EllipticTheta threads elementwise over lists:

Wolfram Language code: EllipticTheta[{1, 2, 3, 4}, z, q]
Wolfram Language code: EllipticTheta[2, {Pi / 2, Pi}, 1 / 2]

TemplateBox[{1, x, q}, EllipticTheta] is an analytic function of x:

Wolfram Language code: FunctionAnalytic[EllipticTheta[1, x, q], x, Assumptions -> 0 < q < 1]

For example, TemplateBox[{1, x, {1, /, 2}}, EllipticTheta] has no singularities or discontinuities:

Wolfram Language code: FunctionSingularities[EllipticTheta[1, x, 1 / 2], x]//Quiet
Wolfram Language code: FunctionSingularities[EllipticTheta[1, x, 1 / 2], x]//Quiet
Wolfram Language code: FunctionDiscontinuities[EllipticTheta[1, x, 1 / 2], x]//Quiet

TemplateBox[{1, x, {1, /, 2}}, EllipticTheta] is neither nondecreasing nor nonincreasing:

Wolfram Language code: FunctionMonotonicity[EllipticTheta[1, x, 1 / 2], x]

TemplateBox[{1, x, {1, /, 2}}, EllipticTheta] is not injective:

Wolfram Language code: FunctionInjective[EllipticTheta[1, x, 1 / 2], x]
Wolfram Language code: Plot[{EllipticTheta[1, x, 1 / 2], 1}, {x, -6, 6}]

TemplateBox[{1, x, {1, /, 2}}, EllipticTheta] is not surjective:

Wolfram Language code: FunctionSurjective[EllipticTheta[1, x, 1 / 2], x]
Wolfram Language code: Plot[{EllipticTheta[1, x, 1 / 2], -5}, {x, -6, 6}]

TemplateBox[{1, x, {1, /, 2}}, EllipticTheta] is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[EllipticTheta[1, x, 1 / 2], x]

TemplateBox[{1, x, {1, /, 2}}, EllipticTheta] is neither convex nor concave:

Wolfram Language code: FunctionConvexity[EllipticTheta[1, x, 1 / 2], x]

TraditionalForm formatting:

Wolfram Language code: EllipticTheta[a, z, q] // TraditionalForm
Wolfram Language code: EllipticTheta[a, q] // TraditionalForm

Generalizations & Extensions  (1)

EllipticTheta can be applied to a power series:

Wolfram Language code: EllipticTheta[2, z, q - (q^2/2) + (q^3/9) + O[q]^4]

Applications  (11)

Plot theta functions near the unit circle in the complex q plane:

Wolfram Language code: Plot[Re[EllipticTheta[1, 0.5, 0.9 Exp[I ϕ]]], {ϕ, -π, π}]
Wolfram Language code: Plot[Re[EllipticTheta[1, 0.5, 0.97 Exp[I ϕ]]], {ϕ, -π, π}]

The number of representations of as a sum of four squares:

Wolfram Language code: Table[ SeriesCoefficient[Series[EllipticTheta[3, 0, q] ^ 4, {q, 0, n}], n], {n, 10}]
Wolfram Language code: Table[SquaresR[4, n], {n, 10}]

Verify Jacobi's triple product identity through a series expansion:

Wolfram Language code: Series[EllipticThetaPrime[1, q] - EllipticTheta[2, q]EllipticTheta[3, q]EllipticTheta[4, q], {q, 0, 9}]

Conformal map from an ellipse to the unit disk:

Wolfram Language code: w[z_, {a_, b_}] := With[{q = ((a - b/a + b))^2, aze = ArcSin[(z/Sqrt[a^2 - b^2])]}, (EllipticTheta[1, aze, q]/EllipticTheta[4, aze, q])]

Visualize the map:

Wolfram Language code: ParametricPlot[ReIm[w[ρ (2 Cos[φ] + I Sin[φ]), {2, 1}]], {ρ, 0, 1}, {φ, 0, 2π}, Mesh -> 15]

Green's function for the 1D heat equation with Dirichlet boundary conditions and initial condition :

Wolfram Language code: T[{x_, t_}, x0_, L_] := (1/2L) (EllipticTheta[3, (π/2L) (x - x0), E^-((π/L))^2t] - EllipticTheta[3, (π/2L)(x + x0), E^-((π/L))^2t])

Plot the time‐dependent temperature distribution:

Wolfram Language code: Plot3D[T[{x, t}, 0.6, 1], {x, 0, 1}, {t, 0.01, 1 / 2}]

Form Bloch functions of a one‐dimensional crystal with Gaussian orbitals:

Wolfram Language code: ψ[𝓀_, x_, ϕ_] := (E^-(π ϕ x^2/2) EllipticTheta[3, π 𝓀 - (π I ϕ x/2), E^-π / 2 ϕ]/Sqrt[(2/ϕ) E^-(4 𝓀^2 π/ϕ)EllipticTheta[3, -(4 I 𝓀 π/ϕ), E^-(4 π/ϕ)]])

Plot Bloch functions as a function of the quasi‐wave vector:

Wolfram Language code: Plot3D[Re[ψ[𝓀, x, 1]], {x, -12, 12}, {𝓀, 0, 1 / 2}]

Electrostatic potential in a NaCl‐like crystal with point-like ions:

Wolfram Language code: q[x_, t_] := EllipticTheta[2, 2 π x, E^-t^2]
Wolfram Language code: φ[{x_, y_, z_}] := (16/π) NIntegrate[t q[x, t]q[y, t]q[z, t], {t, 0, ∞}]

Plot the potential in a plane through the crystal:

Wolfram Language code: ListContourPlot[Table[φ[{x, y, 0.3}], {x, -1, 1, 1 / 25}, {y, -1, 1, 1 / 25}]]

A concise form of the Poisson summation formula:

Wolfram Language code: x^1 / 4 EllipticTheta[3, 0, E^π x] == (2UnitStep[Im[x]] - 1) I x^-1 / 4 EllipticTheta[3, 0, E^π / x]
Wolfram Language code: % /. x -> -2.

An asymptotic approximation for a finite Gaussian sum:

Wolfram Language code: AsymptoticSum[E^-k^2, {k, 1, n}, {n, ∞, 2}]//FullSimplify

Compare the approximate and exact values for :

Wolfram Language code: % /. {n -> 10.}
Wolfram Language code: Underoverscript[∑, k = 1, 10]E^-k^2//N

Closed form of iterates of the arithmetic‐geometric mean:

Wolfram Language code: ArithmeticGeometricMeanIteration[n_, a_, b_] := With[{z = EllipticNomeQ[1 - ((b/a))^2]}, ArithmeticGeometricMean[a, b]{EllipticTheta[3, 0, z^2^n]^2, EllipticTheta[4, 0, z^2^n]^2}]

Compare the closed form with explicit iterations:

Wolfram Language code: Table[ArithmeticGeometricMeanIteration[n, 3., 5.], {n, 0, 4}]
Wolfram Language code: NestList[{Mean[#], GeometricMean[#]}&, {3., 5.}, 4]

Form any elliptic function with given periods, poles and zeros as a rational function of EllipticTheta:

Wolfram Language code: makeEllipticFunction[z_, {ω1_, ω3_}, zeros_List, poles_List] := Module[{c = π / (2 ω1), q = Exp[I π ω3 / ω1]}, (Product[EllipticTheta[1, c (z - r), q], {r, zeros}] / Product[EllipticTheta[1, c (z - s), q], {s, poles}]) (EllipticTheta[1, c (z - Last[poles]), q] / EllipticTheta[1, c (z - Last[poles] - (Total[zeros] - Total[poles])), q])] /; Length[zeros] == Length[poles] && Resolve[Exists[{μ, ν}, Element[{μ, ν}, Integers], Total[zeros] - Total[poles] == μ ω1 + ν ω3]]

Form an elliptic function with a single and a double zero and a triple pole:

Wolfram Language code: f[z_] = makeEllipticFunction[z, {1, I}, {1 / 3 + 1 / 3 I, 1 / 3 + 1 / 3 I, -2 / 3 - 2 / 3 I}, {0, 0, 0}]

Plot the resulting elliptic function:

Wolfram Language code: ComplexPlot[f[z], {z, -1.5 - 1.5I, 1.5 + 1.5I}, ColorFunction -> "CyclicReImLogAbs"]

Properties & Relations  (2)

Numerically find a root of a transcendental equation:

Wolfram Language code: FindRoot[EllipticTheta[1, z, 1 / 3]^3 + EllipticTheta[3, z, 1 / 3] + z == 2, {z, 2}]

Sum can generate elliptic theta functions:

Wolfram Language code: Sum[(-1) ^ n q ^ (n ^ 2), {n, Infinity}]

Possible Issues  (4)

Machine-precision input is insufficient to give a correct answer:

Wolfram Language code: EllipticTheta[1, 10. ^ 30, 1 / 2]

Use arbitrary-precision arithmetic to obtain the correct result:

Wolfram Language code: N[EllipticTheta[1, 10 ^ 30, 1 / 2], 20]

The first argument must be an explicit integer between 1 and 4:

Wolfram Language code: EllipticTheta[1 + (E + 1) ^ 2 - E ^ 2 - 2E - 1, 3., 1 / 2]
Wolfram Language code: Simplify[%]

EllipticTheta has the attribute NHoldFirst:

Wolfram Language code: Attributes[EllipticTheta]

Different argument conventions exist for theta functions:

Wolfram Language code: {Plot[EllipticTheta[1, z, (1/2)], {z, 0, 2π}], Plot[EllipticTheta[1, (z/2π), (1/2)], {z, 0, 2π}]}
Wolfram Language code: {Plot[EllipticTheta[1, 2, q], {q, 0.1, 0.8}], Plot[EllipticTheta[1, 2, Exp[I π (I τ)]], {τ, 0.1, 0.8}]}

Neat Examples  (1)

Visualize a function with a boundary of analyticity:

Wolfram Language code: Module[{f, r = 0.995}, f[z_ ? NumberQ] := If[Abs[z] > r, 0, Sin[Arg[EllipticTheta[3, 1, z]] / 2] ^ 2]; DensityPlot[f[qx + I qy], {qx, qy}∈Disk[{0, 0}, r], PlotPoints -> 90, PlotRange -> All, Frame -> False, ColorFunction -> (Hue[2.72 #]&)]]
Wolfram Language code: ParametricPlot3D[{qr Cos[qϕ], qr Sin[qϕ], Abs[EllipticTheta[2, 2, qr E^I qϕ]]}, {qϕ, -π, π}, {qr, 0, 0.99}, BoxRatios -> {1, 1, 0.66}]
Wolfram Research (1988), EllipticTheta, Wolfram Language function, https://reference.wolfram.com/language/ref/EllipticTheta.html (updated 2022).

Text

Wolfram Research (1988), EllipticTheta, Wolfram Language function, https://reference.wolfram.com/language/ref/EllipticTheta.html (updated 2022).

CMS

Wolfram Language. 1988. "EllipticTheta." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/EllipticTheta.html.

APA

Wolfram Language. (1988). EllipticTheta. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/EllipticTheta.html

BibTeX

@misc{reference.wolfram_2026_elliptictheta, author="Wolfram Research", title="{EllipticTheta}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/EllipticTheta.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_elliptictheta, organization={Wolfram Research}, title={EllipticTheta}, year={2022}, url={https://reference.wolfram.com/language/ref/EllipticTheta.html}, note=[Accessed: 12-June-2026]}