WOLFRAM

Wolfram Language & System Documentation Center

Speak[expr]

speaks a spoken representation of the expression expr.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
"ArraySizeLimit"  
"DetailedGraphics"  
"ExpressionDepthLimit"  
Show More Show More
"IncludeParentheses"  
"IntegerLimit"  
"RealPrecisionLimit"  
"StringLengthLimit"  
Properties & Relations  
Neat Examples  
See Also
Related Guides
Related Links
History
Cite this Page

Speak

Speak[expr]

speaks a spoken representation of the expression expr.

Details and Options

  • Speak["string"] speaks the text in "string".
  • Speak[expr] works with mathematical expressions, programs, graphics, and other constructs.
  • Speak[HoldForm[expr]] speaks the held form of expr, without evaluation.
  • Speak attempts to produce naturally worded speech rather than literal representations of expression structure.
  • Speak produces sound using your computer's operating system.
  • SpokenString[expr] gives text for the speech generated by Speak[expr].
  • SpeechSynthesize[expr] gives synthesized audio from expr.
  • The following options can be given:
  • "ArraySizeLimit" 10maximal number of elements of an array or arguments of a function
    "DetailedGraphics" Falsecontrols the description of graphics primitives
    "ExpressionDepthLimit" 10maximal depth of an expression allowed in the output
    "IncludeParentheses" Falsecontrols the delimiting of subexpressions
    "IntegerLimit" 10^10maximal integer that will be given with all its digits
    "RealPrecisionLimit" 3how many significant digits to include in approximate numbers
    "StringLengthLimit" 1000maximal number of characters in strings and symbol names
  • "ArraySizeLimit" and "ExpressionDepthLimit" control the size of all output expressions, including the representation of graphics.
  • The options controlling the size specify the level of complexity at which to begin eliding parts of the output rather than the exact count of elements in the output.
  • Speak["str"] sends "str" to the speech engine. Speak[HoldForm["str"]] speaks a processed version of the string, affected by the options.
  • Speak[Unevaluated[expr]] also speaks the held form of expr.
  • The text string that is sent to the speech engine on your computer system is given by SpokenString[expr,Options[Speak],"PostProcess"->False].

Examples

open all close all

Basic Examples  (3)

Speak a string of text:

Wolfram Language code: Speak["this is some text"]

Speak a mathematical expression:

Wolfram Language code: Speak[Sin[x] ^ 2 + Cos[x] ^ 2]

Speak an unevaluated expression:

Wolfram Language code: Speak[HoldForm[1 + 1]]

Scope  (6)

Speak mathematical expressions and functions:

Wolfram Language code: Speak[Sqrt[x / (y + z)]]
Wolfram Language code: Speak[Sin[x] + O[x] ^ 4]
Wolfram Language code: Speak[D[f[x, y], x, y]]
Wolfram Language code: Speak[HoldForm[Solve[{x + y == 1, x - 2y == 2}]]]

Speak programming constructs:

Wolfram Language code: Speak[x_ /; x > 0]
Wolfram Language code: Speak[HoldForm[i = 0;While[RandomReal[] < .5, Print[++i]]]]

Describe a plot:

Wolfram Language code: Speak[HoldForm[Plot[x, {x, 0, 1}]]]

Describe a graphics object:

Wolfram Language code: Speak[Graphics3D[Cylinder[]]]

Create a button that speaks when clicked:

Wolfram Language code: Button["press me", Speak["thank you"]]

Make the second bar act as a button that speaks when clicked:

Wolfram Language code: BarChart[{1, Button[2, Speak[2]], 3}]

Options  (7)

"ArraySizeLimit"  (1)

Limit the number of arguments included in the spoken text:

Wolfram Language code: Speak[HoldForm[1 2 3 4 5 6 7 8 9 10], "ArraySizeLimit" -> 4]

"DetailedGraphics"  (1)

Include a detailed description of graphics primitives:

Wolfram Language code: Speak[Graphics3D[Sphere[{{0, 0, 0}, {1, 1, 1}}]], "DetailedGraphics" -> True]

"ExpressionDepthLimit"  (1)

Limit the depth of subexpressions included in the spoken text:

Wolfram Language code: Speak[{{{x}}}, "ExpressionDepthLimit" -> 2]

"IncludeParentheses"  (1)

Use simplified delimiting of subexpressions:

Wolfram Language code: Speak[Sqrt[x / (y + z)]]

Speak left and right parentheses:

Wolfram Language code: Speak[Sqrt[x / (y + z)], "IncludeParentheses" -> True]

"IntegerLimit"  (1)

Set a threshold for exact integers and rationals:

Wolfram Language code: Speak[123457 / 234567, "IntegerLimit" -> 1000]

"RealPrecisionLimit"  (1)

Set a threshold for the number of digits in reals:

Wolfram Language code: Speak[N[Pi], "RealPrecisionLimit" -> 6]

"StringLengthLimit"  (1)

Limit the length of strings in the spoken text:

Wolfram Language code: Speak[HoldForm["string one string two string three"], "StringLengthLimit" -> 6]

Properties & Relations  (2)

Show the text string sent to the speech engine:

Wolfram Language code: SpokenString[Range[15], Options[Speak], "PostProcess" -> False]

Speak the string:

Wolfram Language code: Speak[%]

Speak the same expression directly:

Wolfram Language code: Speak[Range[15]]

Use SpeechSynthesize to synthesize an Audio object containing the spoken string:

Wolfram Language code: Speak["Hello Wolfram"]

Synthesize the string:

Wolfram Language code: SpeechSynthesize["Hello Wolfram"]

Neat Examples  (1)

Generate a string:

Wolfram Language code: str = SpokenString[Range[15], Options[Speak], "PostProcess" -> False]

Split into several substrings:

Wolfram Language code: lst = StringSplit[str, RegularExpression[" *(<|\\[\\[)[^>\\]]++(>|\\]\\]) *"]]

Highlight and speak each substring:

Wolfram Language code: Monitor[Do[Speak[lst[[i]]];Pause[1.25], {i, Length[lst]}], Row[MapAt[Style[#, Red]&, lst, If[IntegerQ[i], i, 1]], " "]]
Wolfram Research (2008), Speak, Wolfram Language function, https://reference.wolfram.com/language/ref/Speak.html (updated 2012).

Text

Wolfram Research (2008), Speak, Wolfram Language function, https://reference.wolfram.com/language/ref/Speak.html (updated 2012).

CMS

Wolfram Language. 2008. "Speak." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2012. https://reference.wolfram.com/language/ref/Speak.html.

APA

Wolfram Language. (2008). Speak. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Speak.html

BibTeX

@misc{reference.wolfram_2026_speak, author="Wolfram Research", title="{Speak}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/Speak.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_speak, organization={Wolfram Research}, title={Speak}, year={2012}, url={https://reference.wolfram.com/language/ref/Speak.html}, note=[Accessed: 13-June-2026]}