WOLFRAM

Wolfram Language & System Documentation Center

SpheroidalPS[n,m,γ,z]

gives the angular spheroidal function of the first kind.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Differentiation  
Series Expansions  
Generalizations & Extensions  
Applications  
Properties & Relations  
Possible Issues  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

SpheroidalPS

SpheroidalPS[n,m,γ,z]

gives the angular spheroidal function of the first kind.

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • The angular spheroidal functions satisfy the differential equation with the spheroidal eigenvalue given by SpheroidalEigenvalue[n,m,γ].
  • SpheroidalPS[n,m,0,z] is equivalent to LegendreP[n,m,z].
  • SpheroidalPS[n,m,a,γ,z] gives spheroidal functions of type . The types are specified as for LegendreP.
  • For certain special arguments, SpheroidalPS automatically evaluates to exact values.
  • SpheroidalPS can be evaluated to arbitrary numerical precision.
  • SpheroidalPS automatically threads over lists. »

Examples

open all close all

Basic Examples  (5)

Evaluate numerically:

Wolfram Language code: SpheroidalPS[3, 2, 1, 0.5]

Expansion about the spherical case:

Wolfram Language code: Series[SpheroidalPS[n, m, γ, x], {γ, 0, 3}]

Plot over a subset of the reals:

Wolfram Language code: Plot[SpheroidalPS[2, 0, 1, x], {x, -1, 1}]

Series expansion at Infinity:

Wolfram Language code: Series[SpheroidalPS[3 / 2, 1 / 2, 1, x], {x, ∞, 2}, Assumptions -> x > 1]//Normal

Series expansion at a singular point:

Wolfram Language code: Series[SpheroidalPS[3 / 2, 1 / 2, 1, x], {x, 1, 2}]//Normal//FullSimplify

Scope  (25)

Numerical Evaluation  (6)

Evaluate numerically:

Wolfram Language code: SpheroidalPS[5, 1, 0, .3]
Wolfram Language code: SpheroidalPS[1, 0, 4, 2.]

Evaluate to high precision:

Wolfram Language code: N[SpheroidalPS[7, 5, 4, 0], 50]
Wolfram Language code: N[SpheroidalPS[2, 1, 1 / 3, 1 / 2], 20]

The precision of the output tracks the precision of the input:

Wolfram Language code: SpheroidalPS[2, 2, 1 / 6, .211111111000111111111]

Complex number inputs:

Wolfram Language code: N[SpheroidalPS[3, 5 - I, 1 / 3, I + 1]]

Evaluate efficiently at high precision:

Wolfram Language code: SpheroidalPS[31, 5, 1 / 6, 2`100]//Timing
Wolfram Language code: SpheroidalPS[7, 5, 1, 2 / 7`1000];//Timing

Compute the elementwise values of an array using automatic threading:

Wolfram Language code: SpheroidalPS[1 / 2, 1 / 2, 0, {{1 / 2, 0}, {0, 1 / 2}}]

Or compute the matrix SpheroidalPS function using MatrixFunction:

Wolfram Language code: MatrixFunction[SpheroidalPS[1 / 2, 1 / 2, 0, #]&, {{1 / 2, 0}, {0, 1 / 2}}]

Compute average-case statistical intervals using Around:

Wolfram Language code: SpheroidalPS[1 / 2, 1 / 2, 0, Around[1 / 2, 0.01]]

Specific Values  (4)

Evaluate symbolically:

Wolfram Language code: SpheroidalPS[n, m, 0, x]//FunctionExpand

Find the first positive minimum of SpheroidalPS[4,0,1/2,x]:

Wolfram Language code: xmin = x /. FindRoot[D[SpheroidalPS[4, 0, 1 / 2, x], x] == 0, {x, .5}]
Wolfram Language code: Plot[SpheroidalPS[4, 0, 1 / 2, x], {x, -1, 1.5}, Epilog -> Style[Point[{xmin, SpheroidalPS[4, 0, 1 / 2, xmin ]}], PointSize[Large], Red]]

Evaluate the SpheroidalPS function for half-integer parameters:

Wolfram Language code: SpheroidalPS[3 / 2, 1 / 2, 1, x]
Wolfram Language code: SpheroidalPS[1 / 2, 1 / 2, 0, x]

Different SpheroidalPS types give different symbolic forms:

Wolfram Language code: Table[SpheroidalPS[n, m, 0, x], {m, 0, 2}, {n, 0, 2}]

Visualization  (3)

Plot the SpheroidalPS function for various orders:

Wolfram Language code: Plot[{SpheroidalPS[1, 0, 1, x], SpheroidalPS[2, 0, 1, x], SpheroidalPS[3, 0, 1, x], SpheroidalPS[4, 0, 1, x]}, {x, -1, 1}]

Plot the real part of TemplateBox[{3, 0, 1, z}, SpheroidalPS]:

Wolfram Language code: ComplexContourPlot[Re[SpheroidalPS[3, 0, 1, z]], {z, -1 - I, 1 + I}, Contours -> 24]

Plot the imaginary part of TemplateBox[{3, 0, 1, z}, SpheroidalPS]:

Wolfram Language code: ComplexContourPlot[Im[SpheroidalPS[3, 0, 1, z]], {z, -1 - I, 1 + I}, Contours -> 24]

Types 2 and 3 of SpheroidalPS functions have different branch cut structures:

Wolfram Language code: Plot3D[Im[SpheroidalPS[2, 1, 2, x + I y]], {x, -1.5, 1.5}, {y, -0.5, 0.5}, Exclusions -> {{y == 0, Abs[x] > 1}}]
Wolfram Language code: Plot3D[Im[SpheroidalPS[2, 1, 3, x + I y]], {x, -1.5, 1.5}, {y, -0.5, 0.5}, Exclusions -> {{y == 0, -1 < x < 1}}]

Function Properties  (8)

The real domain of TemplateBox[{1, 2, 2, x}, SpheroidalPS]:

Wolfram Language code: FunctionDomain[SpheroidalPS[1, 2, 2, x], x]

The complex domain of TemplateBox[{1, 2, 2, x}, SpheroidalPS]:

Wolfram Language code: FunctionDomain[SpheroidalPS[1, 2, 2, z], z, Complexes]

TemplateBox[{1, 2, gamma, 3}, SpheroidalPS] is an even function with respect to :

Wolfram Language code: SpheroidalPS[1, 2, -γ, 3] == -SpheroidalPS[1, 2, γ, 3]

TemplateBox[{1, 2, gamma, 3}, SpheroidalPS] has the mirror property TemplateBox[{1, 2, 3, {z, }}, SpheroidalPS]=TemplateBox[{1, 2, 3, z}, SpheroidalPS]:

Wolfram Language code: SpheroidalPS[1, 2, 3, Conjugate[z]] == Conjugate[SpheroidalPS[1, 2, 3, z]]

TemplateBox[{2, 0, 1, x}, SpheroidalPS] has no singularities or discontinuities:

Wolfram Language code: FunctionSingularities[SpheroidalPS[2, 0, 1, x], x]//Quiet
Wolfram Language code: FunctionDiscontinuities[SpheroidalPS[2, 0, 1, x], x]//Quiet

TemplateBox[{2, 0, 1, x}, SpheroidalPS] is neither non-decreasing nor non-increasing:

Wolfram Language code: FunctionMonotonicity[SpheroidalPS[2, 0, 1, x], x]

TemplateBox[{2, 0, 1, x}, SpheroidalPS] is not injective:

Wolfram Language code: FunctionInjective[SpheroidalPS[2, 0, 1, x], x]
Wolfram Language code: Plot[{SpheroidalPS[2, 0, 1, x], 4}, {x, -5, 5}]

TemplateBox[{2, 0, 1, x}, SpheroidalPS] is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[SpheroidalPS[2, 0, 1, x], x]

TraditionalForm formatting:

Wolfram Language code: SpheroidalPS[n, m, c, η]//TraditionalForm

Differentiation  (2)

The first derivative with respect to z:

Wolfram Language code: D[SpheroidalPS[n, m, γ, z], z]

Higher derivatives with respect to z:

Wolfram Language code: Table[D[SpheroidalPS[n, m, γ, z], {z, k}], {k, 1, 3}]//FullSimplify

Plot the higher derivatives with respect to z when n=10, m=2 and γ=1/3:

Wolfram Language code: Plot[Evaluate[% /. { n -> 10, m -> 2, γ -> 1 / 3}], {z, -3, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Series Expansions  (2)

Find the Taylor expansion using Series:

Wolfram Language code: Series[SpheroidalPS[n, m, γ, x], {x, 0, 3}]

Plots of the first three approximations around :

Wolfram Language code: terms = Normal@Table[Series[SpheroidalPS[2, 0, 3, x], {x, 0, m}], {m, 1, 5, 2}]//N; Plot[{SpheroidalPS[2, 0, 3, x], terms}, {x, -1, 1}, PlotRange -> {-1.5, 1.5}]

The Taylor expansion at a generic point:

Wolfram Language code: Series[SpheroidalPS[n, m, γ, x], {x, x0, 2}]// FullSimplify

Generalizations & Extensions  (1)

The different types of SpheroidalPS have different branch cut structures:

Wolfram Language code: SpheroidalPS[n, m, 1, 0, x]
Wolfram Language code: SpheroidalPS[n, m, 2, 0, x]

Applications  (4)

Solve the spheroidal differential equation in terms of SpheroidalPS:

Wolfram Language code: DSolve[(1 - x ^ 2)y''[x] - 2x y'[x] + (SpheroidalEigenvalue[n, m, c] + c ^ 2(1 - x ^ 2) - (m ^ 2/1 - x ^ 2))y[x] == 0, y, x]

Plot prolate and oblate versions of the same angular function:

Wolfram Language code: Plot[{SpheroidalPS[2, 1, 3, x], SpheroidalPS[2, 1, 3I, x]}, {x, -1, 1}]

SpheroidalPS is a band-limited function with bandwidth proportional to :

Wolfram Language code: fourierCenter[f_List] := RotateLeft[f, Quotient[Length[f], 2]]

For spheroidicity parameter :

Wolfram Language code: With[{γ = 4.`20}, ListLinePlot[Abs[Fourier[Table[SpheroidalPS[2, 0, γ, x], {x, -10, 10, 1 / 10}]]]//fourierCenter, PlotRange -> All]]

For spheroidicity parameter , the bandwidth is higher:

Wolfram Language code: With[{γ = 8.`20}, ListLinePlot[Abs[Fourier[Table[SpheroidalPS[2, 0, γ, x], {x, -10, 10, 1 / 10}]]]//fourierCenter, PlotRange -> All]]

Build a near-spherical approximation to :

Wolfram Language code: nsLimitS1[n_, m_, z_, {c_, ord_Integer}] := (Normal[Series[SpheroidalPS[n1, -m1, c, x], {c, 0, ord}] /. LegendreP[k_, -m1, 2, x] :> SphericalBesselJ[k, z]](1 - c ^ 2 / z ^ 2)^m / 2 / SpheroidalRadialFactor[n, -m, c]) /. {n1 -> n, m1 -> m}

First few terms of the approximation:

Wolfram Language code: nsLimitS1[n, m, z, {c, 3}]//TraditionalForm

Compare numerically:

Wolfram Language code: (Table[nsLimitS1[3, 1, 1`30, {c, k}], {k, 2, 10, 2}] - SpheroidalS1[3, 1, c, 1 / c]) /. {c -> 1 / 100}

Properties & Relations  (1)

Spheroidal angular harmonics are eigenfunctions of the Sinc transform on the interval :

Wolfram Language code: Integrate[Sinc[c (t - x)]SpheroidalPS[2, 0, c, x], {x, -1, 1}]//TraditionalForm

Possible Issues  (2)

Spheroidal functions do not evaluate for half-integer values of n or generic values of m:

Wolfram Language code: SpheroidalPS[3 / 2, 1, 1, 0.5]

Angular spheroidal harmonics in the Wolfram Language adopt the Meixner–Schaefke normalization scheme:

Wolfram Language code: With[{c = 1}, Table[NIntegrate[SpheroidalPS[n, m, c, x] ^ 2, {x, -1, 1}], {n, 0, 2}, {m, -n, n}]]//Rationalize
Wolfram Language code: % == Table[(2/2n + 1)((n + m)!/(n - m)!), {n, 0, 2}, {m, -n, n}]

Flammer normalization is also common:

Wolfram Language code: FlammerSpheroidalS[n_Integer, m_Integer, c_, eta_] := SpheroidalPS[n, m, c, eta]If[EvenQ[n - m], LegendreP[n, m, 0] / SpheroidalPS[n, m, c, 0], Derivative[0, 0, 1][LegendreP][n, m, 0] / SpheroidalPSPrime[n, m, c, 0]]

Reconstruct table entries from Abramowitz and Stegun table 21.2:

Wolfram Language code: With[{m = 0}, Table[NumberForm[FlammerSpheroidalS[n, m, 1., Cos[th Degree]], {4, 4}], {n, m, m + 5}, {th, {0, 30, 45, 60, 90}}]]//TableForm
Wolfram Language code: With[{m = 1}, Table[NumberForm[FlammerSpheroidalS[n, m, 1., Cos[th Degree]], {4, 4}], {n, m, m + 5}, {th, {0, 30, 45, 60, 90}}]]//TableForm
Wolfram Research (2007), SpheroidalPS, Wolfram Language function, https://reference.wolfram.com/language/ref/SpheroidalPS.html.

Text

Wolfram Research (2007), SpheroidalPS, Wolfram Language function, https://reference.wolfram.com/language/ref/SpheroidalPS.html.

CMS

Wolfram Language. 2007. "SpheroidalPS." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/SpheroidalPS.html.

APA

Wolfram Language. (2007). SpheroidalPS. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SpheroidalPS.html

BibTeX

@misc{reference.wolfram_2026_spheroidalps, author="Wolfram Research", title="{SpheroidalPS}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/SpheroidalPS.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_spheroidalps, organization={Wolfram Research}, title={SpheroidalPS}, year={2007}, url={https://reference.wolfram.com/language/ref/SpheroidalPS.html}, note=[Accessed: 13-June-2026]}